autoform.pas

Delphi高级程序开发配书源代码,可以循序渐进的学习Delphi.

{ 重要提示:

  在运行这个AutoDemo应用程序之前,
  确信MemoEdit自动化服务器程序已经用命令行"MemoEdit /regserver"注册。 }

unit AutoForm;

interface

uses
  Variants, Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Memo_TLB, ExtCtrls;

type
  TMainForm = class(TForm)
    CreateButton: TButton;
    AddTextButton: TButton;
    TileButton: TButton;
    CascadeButton: TButton;
    CloseButton: TButton;
    ExitButton: TButton;
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure CreateButtonClick(Sender: TObject);
    procedure AddTextButtonClick(Sender: TObject);
    procedure TileButtonClick(Sender: TObject);
    procedure CascadeButtonClick(Sender: TObject);
    procedure CloseButtonClick(Sender: TObject);
    procedure ExitButtonClick(Sender: TObject);
  private
    MemoEdit: IMemoApp;
    Memos: array[1..3] of OleVariant;
    procedure CloseMemos;
  end;

var
  MainForm: TMainForm;

implementation

{$R *.dfm}

uses ComObj;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  try
    MemoEdit := CoMemoApp.Create;
  except
    MessageDlg(
      '"MemoApp.Application" OLE自动化类的一个实例' +
      '不能被创建.确信MemoEdit应用程序已 ' +
      '使用命令行 "MemoEdit /regserver"注册.',
      mtError, [mbOk], 0);
    Halt;
  end;
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  CloseMemos;
end;

procedure TMainForm.CloseMemos;
var
  I: Integer;
begin
  for I := 1 to 3 do
    if not VarIsEmpty(Memos[I]) then
    begin
      Memos[I].Close;
      Memos[I] := Unassigned;
    end;
end;

procedure TMainForm.CreateButtonClick(Sender: TObject);
var
  I: Integer;
begin
  CloseMemos;
  for I := 1 to 3 do Memos[I] := MemoEdit.NewMemo;
end;

procedure TMainForm.AddTextButtonClick(Sender: TObject);
var
  I: Integer;
begin
  for I := 1 to 3 do
    if not VarIsEmpty(Memos[I]) then
      Memos[I].Insert('此文本被添加到OLE自动化服务器中！'#13#10);
end;

procedure TMainForm.TileButtonClick(Sender: TObject);
begin
  if MemoEdit <> nil then
    MemoEdit.TileWindows;
end;

procedure TMainForm.CascadeButtonClick(Sender: TObject);
begin
  if MemoEdit <> nil then
    MemoEdit.CascadeWindows;
end;

procedure TMainForm.CloseButtonClick(Sender: TObject);
begin
  CloseMemos;
end;

procedure TMainForm.ExitButtonClick(Sender: TObject);
begin
  Close;
end;

end.