f2812.cmd

自己编写的几个小程序,大家看看,希望能对大家有帮助.

/****************************************************************************/
/*   F2812.cmd - Sample linker command file for F28xx devices               */
/*                                                                          */
/*   Description: This file is a sample F2812 linker command file that can  */
/*                be used for linking programs built with the TMS320C2000   */
/*                C Compiler. Use it as a guideline; you may want to change */
/*                the allocation scheme according to the size of your       */
/*                program and the memory layout of your target system.      */
/****************************************************************************/

MEMORY
{
/* Program Memory */
/* Memory (RAM/FLASH/OTP) blocks can be moved to PAGE1 for data allocation */

   PAGE 0 : BOOT(R)     : origin = 0x3D8000, length = 0x80
   PAGE 0 : PROG(R)     : origin = 0x3D8080, length = 0x1f80
   PAGE 0 : RESET(R)    : origin = 0x0000000, length = 0x2
   PAGE 0 : BOOTROM (RW): origin = 0x03ff000, length = 0x000fc0
   
/* Data Memory */
/* Memory (RAM/FLASH/OTP) blocks can be moved to PAGE0 for program allocation */
/* Registers remain on PAGE1                                                  */

   PAGE 1 : M0RAM(RW)   : origin = 0x000000, length = 0x400
   PAGE 1 : M1RAM(RW)   : origin = 0x000400, length = 0x400
   PAGE 1 : CPU_TIMER0  : origin = 0x000C00, length = 0x000008     /* CPU Timer0 registers (CPU Timer1 and Timer2 are reserved for BIOS)*/   
   PAGE 1 : PIEVT(RW)   : origin = 0x000d00, length = 0x100
   PAGE 1 : ECANA_LAM   : origin = 0x006040, length = 0x000040     /* eCAN local acceptance masks */
   PAGE 1 : ECANA_MOTS  : origin = 0x006080, length = 0x000040     /* eCAN message object time stamps */
   PAGE 1 : ECANA_MOTO  : origin = 0x0060C0, length = 0x000040     /* eCAN object time-out registers */
   PAGE 1 : ECANA_MBOX  : origin = 0x006100, length = 0x000100     /* eCAN mailboxes */
   PAGE 1 : L0L1RAM(RW) : origin = 0x008000, length = 0x2000
   PAGE 1 : ZONE22(RW)  : origin = 0x084000, length = 0x19000
}

/* Allocate sections to memory blocks.*/

SECTIONS
{
   /* 22-bit program sections */
   .reset   : > RESET,   PAGE = 0  /*It will be not used in the user's program!*/
   .pinit   : > PROG,    PAGE = 0
   .cinit   : > PROG,    PAGE = 0
   .text    : > PROG,    PAGE = 0

   /* Initalized sections go in Flash */
   /* For SDFlash to program these, they must be allocated to page 0 */
   .econst  : > PROG,    PAGE = 0
   .const   : > PROG,    PAGE = 0
   
   /* Allocate IQ math areas: */
   IQmath              : > PROG            PAGE = 0                  /* Math Code */
   IQmathTables        : > BOOTROM         PAGE = 0, TYPE = NOLOAD   /* Math Tables In ROM */
   
   /* 16-Bit data sections */
   /* Allocate uninitalized data sections: */
   /*.const   : > M0RAM, PAGE = 1*/
   .sysmem  : > M0RAM, PAGE = 1
   .bss     : > M0RAM, PAGE = 1
   .stack   : > M1RAM, PAGE = 1
   
   /* Allocate PIE Interrupts sections: */
   PieVectTable : > PIEVT,   PAGE = 1
   
   /* 32-bit data sections */
   .ebss    : > L0L1RAM, PAGE = 1
   .esysmem : > L0L1RAM, PAGE = 1
   /* Peripheral Frame 0 Register Structures */
   CpuTimer0RegsFile : > CPU_TIMER0,  PAGE = 1  
   /* Peripheral Frame 2 Register Structures (for Ecan-a)*/
/* ECanaRegsFile     : > ECANA,       PAGE = 1 */
   ECanaLAMRegsFile  : > ECANA_LAM    PAGE = 1   
   ECanaMboxesFile   : > ECANA_MBOX   PAGE = 1
   ECanaMOTSRegsFile : > ECANA_MOTS   PAGE = 1
   ECanaMOTORegsFile : > ECANA_MOTO   PAGE = 1
      
   /* ALlocate extern data sections for sample data */
   SampleDataTableFile     : > ZONE22, PAGE = 1
       
   .boot > BOOT
   {
      -lrts2800_ml.lib<boot.obj> (.text)
   }
}