autoexec.bat

来自「WinCE 3.0 BSP, 包含Inter SA1110, Intel_815」· Batch 代码 · 共 146 行

@echo off
verify off
PROMPT $p$g

REM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
REM !!                                               !!
REM !! MAKE SURE YOU SET THE RIGHT IRQ & IOBASE      !!
REM !! FOR YOUR NETCARD BELOW.                       !!
REM !!                                               !!
REM !! NET_IRQ can be specified in either hex or     !!
REM !! decimal digits (ie either as IRQ=E or IRQ=14).!!
REM !!                                               !!
REM !! NET_IOBASE must be specified in Hex digits.   !!
REM !! A value of 0 for NET_IOBASE means to auto     !!
REM !! searchfor the PCI net card using the 	        !!
REM !! specified IRQ value.                          !!
REM !!                                               !!
REM !! NET_IP can be set to specify a static IP      !!
REM !! address or left blank to use DHCP to obtain   !!
REM !! an IP address.  Format of set should be:      !!
REM !!      set NET_IP=:10.0.0.1                     !!
REM !!                                               !!
REM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

set NET_IRQ=9
set NET_IOBASE=0
set NET_IP=


if "%CONFIG%" == "CEPC_LOCAL" goto CEPC_LOCAL
if "%CONFIG%" == "CEPC_PARALLEL" goto CEPC_PARALLEL
if "%CONFIG%" == "CEPC_1024" goto CEPC_1024
if "%CONFIG%" == "CE800_16" goto CE800_16
if "%CONFIG%" == "CE800_8" goto CE800_8
if "%CONFIG%" == "CE640_16" goto CE640_16
if "%CONFIG%" == "CE640_8" goto CE640_8
if "%CONFIG%" == "VESATEST" goto VESATEST
if "%CONFIG%" == "CLEAN" goto CLEAN


:CEPC_LOCAL
REM #################################################################
REM     Launch LOADCEPC using a local NK.BIN image.

loadcepc /b:38400 /v nk.bin
goto END


:CEPC_1024
REM #################################################################
REM     Set RES=/L:1024x768x8 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:1024x768x8:1024x768
goto WITHRES


:CE800_16
REM #################################################################
REM     Set RES=/L:800x600x16 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:800x600x16:800x600
goto WITHRES


:CE800_8
REM #################################################################
REM     Set RES=/L:800x600x8 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:800x600x8:800x600
goto WITHRES


:CE640_16
REM #################################################################
REM     Set RES=/L:640x480x16 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:640x480x16:640x480
goto WITHRES


:CE640_8
REM #################################################################
REM     Set RES=/L:640x480x8 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:640x480x8:640x480
goto WITHRES


:CEPC_PARALLEL
REM #################################################################
REM     Launch LOADCEPC for a parallel port download.

loadcepc /b:38400 /v /p /L:640x480x8:640x480
goto END


:VESATEST
REM #################################################################
REM     Launch VESATEST program.  VESATEST will display the
REM     VESA BIOS Version number and list all of the available
REM     video modes that are supported by the FLAT driver.
REM
REM	Note: VESATEST.EXE is an internal tool that is provided AS-IS
REM	with no testing or support, hence use at your own risk. We do
REM	not provide any redistribution rights either.

vesatest
goto END


:WITHRES
REM #################################################################
REM     Here we actually Launch LOADCEPC using the RES, NET_IOBASE,
REM     and NET_IRQ env vars we just set above based on menu
REM     selections.


loadcepc /b:38400 /v %RES% /e:1:%NET_IOBASE%:%NET_IRQ%%NET_IP%  eboot.bin
goto END


:CLEAN

:END