sg11.asm

基于PROTERUS仿真的AVR例子

.device AT90S8535
.equ    sph    	=$3E
.equ    spl    	=$3D
.equ	PORTB	=$18
.equ	DDRB	=$17
.equ    PINB    =$16
.equ	PORTD	=$12
.equ	DDRD	=$11
.equ    PIND    =$10
.equ    TIMSK   =$39
.equ    ICR1H   =$27
.equ    ICR1L   =$26
.equ    TCCR1B  =$2E
.equ    TIFR  	=$38
.equ    SREG	=$3F
.def 	ZH     	=r31
.def 	ZL     	=r30

	.org	$0000
	rjmp	main
	.org	$005
	rjmp	t1_ct
	
tab:	.db	$3f,$06,$5b,$4f,$66,$6d,$7d,$07,$7f,$6f

main:	ldi	r16,$02			;栈指针置初值
	out	sph,r16
	ldi	r16,$5f
	out	spl,r16
	ldi	r16,$ff			;定义B口为输出口
	out	DDRB,r16
	ldi	r16,0b10111111		;定义PD6为输入，其余引脚为输出
	out	DDRD,r16
	clr	r12			;清上次捕获值
	clr	r13
	ldi	r16,$20			;允许TIM1_CAPT
	out	TIMSK,r16
	ldi	r16,$c2
	out	TCCR1B,r16		;上升沿捕获，8分频
	clr	r16			;清中断标志寄存器
	out	TIFR,r16
	sei				;CPU开中断
	
aa:	mov	r17,r11			;捕获偏差值送r17、r16
	mov	r16,r10
	rcall	btd			;调二转十子程序
	mov	r22,r20			;送显示缓冲区
	mov	r21,r19
	mov	r20,r18
	mov	r19,r17
	mov	r18,r16
	rcall	smiao			;调动态扫描子程序
	rjmp	aa
	
t1_ct:	in	r1,SREG			;标志入栈
	in	r10,ICR1L		;读输入捕获寄存器且将其入栈保护
	in	r11,ICR1H
	push	r10
	push	r11
	sub	r10,r12
	sbc	r11,r13
	pop	r13
	pop	r12
	out	SREG,r1
	reti
	
btd:	ser	r20			;r20先送-1
btd_1:	inc	r20			;r20增1
	subi	r16,low(10000)		;(r17:r16)-10000
	sbci	r17,high(10000)
	brcc	btd_1			;够减则返回btd_1
	subi	r16,low(-10000)		;不够减+10000，恢复余数
	sbci	r17,high(-10000)
	ser	r19			;r19先送-1
btd_2:	inc	r19			;r19增1
	subi	r16,low(1000)		;(r17:r16)-1000
	sbci	r17,high(1000)
	brcc	btd_2			;够减则返回btd_2
	subi	r16,low(-1000)		;不够减+1000，恢复余数
	sbci	r17,high(-1000)
	ser	r18			;r18先送-1
btd_3:	inc	r18			;r18增1
	subi	r16,low(100)		;(r17:r16)-100
	sbci	r17,high(100)
	brcc	btd_3			;够减则返回btd_3
	subi	r16,low(-100)		;不够减+100，恢复余数
	sbci	r17,high(-100)
	ser	r17			;r17先送-1
btd_4:	inc	r17			;r17增1
	subi	r16,10			;(r17:r16)-10
	brcc	btd_4			;够减则返回btd_4
	subi	r16,-10			;不够减+10，恢复余数
	ret
	
smiao:	ldi	r16,$fe			;送个位位线
	out	PORTD,r16
	mov	r23,r18			;将个位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$fd			;送十位位线
	out	PORTD,r16
	mov	r23,r19			;将十位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$fb			;送百位位线
	out	PORTD,r16
	mov	r23,r20			;将百位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$f7			;送千位位线
	out	PORTD,r16
	mov	r23,r21			;将千位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$ef			;送万位位线
	out	PORTD,r16
	mov	r23,r22			;将万位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ret
	
cqb:	ldi	ZH,high(tab*2)		;7段码的首址给Z
	ldi	ZL,low(tab*2)
	add	ZL,r23			;首地址+偏移量
	lpm				;查表送B口输出
	out	PORTB,r0
	ret
	
t1ms:	ldi	r24,101			;延时1ms子程序
	push	r24
del2:	push	r24
del3:	dec	r24
	brne	del3
	pop	r24
	dec	r24
	brne	del2
	pop	r24
	ret