sg15.asm

基于PROTERUS仿真的AVR例子

.device AT90S8535
.equ    sph    	=$3E
.equ    spl    	=$3D
.equ	PORTA	=$1B
.equ	DDRA	=$1A
.equ    PINA    =$19
.equ	PORTB	=$18
.equ	DDRB	=$17
.equ    PINB    =$16
.equ	PORTD	=$12
.equ	DDRD	=$11
.equ    PIND    =$10
.equ    ADMUX   =$07
.equ    ADCSR   =$06
.equ    ADCH    =$05
.equ    ADCL    =$04
.def 	ZH     	=r31
.def 	ZL     	=r30

	.org	$0000
	rjmp	reset
	
tab:	.db	$3f,$06,$5b,$4f,$66,$6d,$7d,$07,$7f,$6f

reset:	ldi	r16,$02			;栈指针置初值
	out	sph,r16
	ldi	r16,$5f
	out	spl,r16
	ldi	r16,$ff			;定义PB、PD为输出口
	out	DDRB,r16
	out	DDRD,r16
	ldi	r16,$00			;定义PA口为输入口，不带内部上拉电阻
	out	DDRA,r16
	ldi	r16,$00
	out	PORTA,r16
	ldi	r16,$07			;先第7路ADC
	out	ADMUX,r16
	ldi	r18,$e5			;允许ADC，启动ADC，自由模式
	out	ADCSR,r18		;64分频作A/D时钟
	rcall	t1ms
	
aa:	in	r16,ADCL		;读A/D结果放入r17、r16中
	in	r17,ADCH
	ldi	r18,$06			;改变ADMUX为第6路
	out	ADMUX,r18
	rcall	btd			;调二转十子程序
	ldi	r22,7			;万位显示路号7
	mov	r21,r19			;4位ADC结果送显示缓冲区
	mov	r20,r18
	mov	r19,r17
	mov	r18,r16
	ldi	r17,200			;每一路A/D扫描200次，恰好1s
	
bb:	rcall	smiao			;调动态扫描子程序
	dec	r17
	brne	bb
	in	r16,ADCL		;读A/D结果放入r17、r16中
	in	r17,ADCH
	ldi	r18,$07			;改变ADMUX为第7路
	out	ADMUX,r18
	rcall	btd
	ldi	r22,6			;万位显示路号6
	mov	r21,r19			;4位ADC结果送显示缓冲区
	mov	r20,r18
	mov	r19,r17
	mov	r18,r16
	ldi	r17,200			;每一路A/D扫描200次，恰好1s
	
cc:	rcall	smiao			;调动态扫描子程序
	dec	r17
	brne	cc
	rjmp	aa
	
btd:	ser	r20			;r20先送-1
btd_1:	inc	r20			;r20增1
	subi	r16,low(10000)		;(r17:r16)-10000
	sbci	r17,high(10000)
	brcc	btd_1			;够减则返回btd_1
	subi	r16,low(-10000)		;不够减+10000，恢复余数
	sbci	r17,high(-10000)
	ser	r19			;r19先送-1
btd_2:	inc	r19			;r19增1
	subi	r16,low(1000)		;(r17:r16)-1000
	sbci	r17,high(1000)
	brcc	btd_2			;够减则返回btd_2
	subi	r16,low(-1000)		;不够减+1000，恢复余数
	sbci	r17,high(-1000)
	ser	r18			;r18先送-1
btd_3:	inc	r18			;r18增1
	subi	r16,low(100)		;(r17:r16)-100
	sbci	r17,high(100)
	brcc	btd_3			;够减则返回btd_3
	subi	r16,low(-100)		;不够减+100，恢复余数
	sbci	r17,high(-100)
	ser	r17			;r17先送-1
btd_4:	inc	r17			;r17增1
	subi	r16,10			;(r17:r16)-10
	brcc	btd_4			;够减则返回btd_4
	subi	r16,-10			;不够减+10，恢复余数
	ret
	
smiao:	ldi	r16,$fe			;送个位位线
	out	PORTD,r16
	mov	r23,r18			;将个位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$fd			;送十位位线
	out	PORTD,r16
	mov	r23,r19			;将十位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$fb			;送百位位线
	out	PORTD,r16
	mov	r23,r20			;将百位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$f7			;送千位位线
	out	PORTD,r16
	mov	r23,r21			;将千位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$ef			;送万位位线
	out	PORTD,r16
	mov	r23,r22			;将万位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ret
	
cqb:	ldi	ZH,high(tab*2)		;7段码的首址给Z
	ldi	ZL,low(tab*2)
	add	ZL,r23			;首地址+偏移量
	lpm				;查表送B口输出
	out	PORTB,r0
	ret
	
t1ms:	ldi	r24,101			;延时1ms子程序
	push	r24
del2:	push	r24
del3:	dec	r24
	brne	del3
	pop	r24
	dec	r24
	brne	del2
	pop	r24
	ret