zh3.asm

the practice of proteus and avr

.device AT90S8535
.equ    SREG	=$3F
.equ    sph    	=$3E
.equ    spl    	=$3D
.equ    TIMSK   =$39
.equ    TIFR  	=$38
.equ    TCCR2   =$25
.equ    ASSR    =$22
.equ	PORTA	=$1B
.equ	DDRA	=$1A
.equ    PINA    =$19
.equ	PORTB	=$18
.equ	DDRB	=$17
.equ    PINB    =$16
.equ	PORTD	=$12
.equ	DDRD	=$11
.equ    PIND    =$10
.def 	ZH     	=r31
.def 	ZL     	=r30

	.org	$0000
	rjmp	reset
	.org	$004
	rjmp	t2_ovf

tab:	.db	$3f,$06,$5b,$4f,$66,$6d,$7d,$07,$7f,$6f

reset:	ldi	r16,$02			;栈指针置初值
	out	sph,r16
	ldi	r16,$5f
	out	spl,r16
	ldi	r25,$ff
	ldi	r28,$ff
	ldi	r16,$ff			;定义PA、PB、PD为输出口
	out	DDRA,r16
	out	DDRB,r16
	out	DDRD,r16
	ldi	r26,25			;东西寄存器、南北寄存器初值为25、25
	ldi	r27,25
	ldi	r16,$08			;使用异步时钟
	out	ASSR,r16
	ldi	r16,$40			;允许T2溢出中断
	out	TIMSK,r16
	ldi	r16,$05			;128分频，1s中断1次
	out	TCCR2,r16
	ldi	r16,$00			;T/C2置初值0
	out	TIFR,r16
	sei
	
aa:	cpi	r28,$ff
	brne	nn
	cpi	r27,6			;计时到最后5秒？
	brlo	tt			;到，转最后5秒分支，否则顺序执行
	ldi	r16,$2e			;东西路口红灯亮，南北路口绿灯亮
	out	PORTA,r16
	rjmp	zz
tt:	cpi	r27,3
	brlo	ww
	cpi	r25,$ff
	brne	tta
	ldi	r16,$3e
	out	PORTA,r16
	com	r25
	rjmp	zz
tta:	ldi	r16,$2e
	out	PORTA,r16
	com	r25
	rjmp	zz
ww:	ldi	r16,$1e
	out	PORTA,r16
	rjmp	zz
nn:	cpi	r26,6			;计时到最后5秒？
	brlo	tt1			;到，转最后5秒分支，否则顺序执行
	ldi	r16,$35			;南北路口红灯亮，东西路口绿灯亮
	out	PORTA,r16
	rjmp	zz
tt1:	cpi	r26,3
	brlo	ww1
	cpi	r25,$ff
	brne	tt1a
	ldi	r16,$37
	out	PORTA,r16
	com	r25
	rjmp	zz
tt1a:	ldi	r16,$35
	out	PORTA,r16
	com	r25
	rjmp	zz
ww1:	ldi	r16,$33
	out	PORTA,r16
zz:	mov	r16,r26			;东西寄存器中数二转十，送r19、r18
	rcall	b8td
	mov	r19,r17
	mov	r18,r16
	mov	r16,r27			;南北寄存器中数二转十，送r21、r20
	rcall	b8td
	mov	r21,r17
	mov	r20,r16
	rcall	smiao
	rjmp	aa
	
t2_ovf:	dec	r26			;东西寄存器减1
	dec	r27			;南北寄存器减1
	brne	vv
	ldi	r26,25
	ldi	r27,25
	com	r28
vv:	reti
	
b8td:	clr	r17			;将r16中的二进制数转换为十进制数，十位、个位分别送r17、r16
b8td1:	subi	r16,10
	brcs	b8td2
	inc	r17
	rjmp	b8td1
b8td2:	subi	r16,(-10)
	ret
	
smiao:	ldi	r16,$fe			;送个位位线
	out	PORTD,r16
	mov	r23,r18			;将个位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$fd			;送十位位线
	out	PORTD,r16
	mov	r23,r19			;将十位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$fb			;送百位位线
	out	PORTD,r16
	mov	r23,r20			;将百位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ldi	r16,$f7			;送千位位线
	out	PORTD,r16
	mov	r23,r21			;将千位的BCD码送r23
	rcall	cqb			;查7段码，送B口输出
	rcall	t1ms			;延时1ms
	ret
	
cqb:	ldi	ZH,high(tab*2)		;7段码的首址给Z
	ldi	ZL,low(tab*2)
	add	ZL,r23			;首地址+偏移量
	lpm				;查表送B口输出
	out	PORTB,r0
	ret
	
t1ms:	ldi	r24,101			;延时1ms子程序
	push	r24
del2:	push	r24
del3:	dec	r24
	brne	del3
	pop	r24
	dec	r24
	brne	del2
	pop	r24
	ret