a64363.s

mips架构的bootloader,99左右的版本 但源代码现在没人更新了

/*************************************************************
 * File: lib/a64363.s
 * Purpose: Part of C runtime library
 * Author: Phil Bunce ([e-mail])
 * Revision History:
 *	970304	Start of revision history
 */

#ifndef LR64363
#define LR64363
#endif

#include <mips.h>

	############# ATMizer-II (LR64363) #################
	.globl a64363init
	.ent a64363init
a64363init:
	beq	a0,zero,1f
	j	c64363init
    1:
	# setup the CCC configuration register
	# enable: CMP, IIE, DIE, MUL, MAD, IPWE(1K), WB
	# Icache: 2 way set assoc, 4K set size
	# Dcache: 2 way set assoc, 2K set size
	# CCC <- 0000 0001 1111 0011 1011 0110 0010 0000
	#li	t0, 0x01f3b620
	li	t0, 0x01f3b600		# without write-back
	.set noreorder
	mtc0	t0, C0_CCC		# load the CP0 configuration register
	.set reorder

	# setup the wait states of local memory page 0, 1, 2 */
        li	t1,0xf8000888 
	#li	t1,0xf8000000		# Quickturn - 1MHz
	li	t2,M_SBCR
	sw	t1,(t2)

	# setup the AddrMap Register to direct exceptions
	# to the SDRAM.
	li	t1,(0<<ADRM_EXCMAP_SHFT)
	li	t2,M_APU_AddrMap
	sw	t1,(t2)

	# setup the SDRAM config info
	li	t2, SBC_BASE 		/* Load base address */

	/* Precharge command */
	li	t0, 0x4033b753
	sw	t0, 4(t2)		# control reg

	/* Mode register */
	li	t0, 0x20228530
	sw	t0, 4(t2)		# control reg

	/* Set Mode */
	li	t0, 0x0000eeee
	li	t3, 0x80810000
	sw	t0, (t3)

	/* Set Control */
    	li	t0, 0x10228530
	sw	t0, 4(t2)		# control reg

	/* Load refresh register */
	li	t0, 0x00000300
	#li	t0, 0x0000000c		# Quickturn - 1MHz
	sw	t0, 8(t2)		# refresh reg

	# select the correct cache flushing routines
	la	s0,r4010_flush

	j	ra
	.end a64363init