ant.bat

这是一个mvc模式

@echo off

rem Slurp the command line arguments.  This loop allows for an unlimited number of 
rem agruments (up to the command line limit, anyway).

set ANT_CMD_LINE_ARGS=

:setupArgs
if %1a==a goto doneArgs
set ANT_CMD_LINE_ARGS=%ANT_CMD_LINE_ARGS% %1
shift
goto setupArgs

:doneArgs
rem The doneArgs label is here just to provide a place for the argument list loop
rem to break out to.

rem find ANT_HOME
if not "%ANT_HOME%"=="" goto checkJava

rem check for ant in Program Files on system drive
if not exist "%SystemDrive%\Program Files\ant" goto checkSystemDrive
set ANT_HOME=%SystemDrive%\Program Files\ant
goto checkJava

:checkSystemDrive
rem check for ant in root directory of system drive
if not exist "%SystemDrive%\ant" goto noAntHome
set ANT_HOME=%SystemDrive%\ant
goto checkJava

:noAntHome
echo ANT_HOME is not set and ant could not be located. Please set ANT_HOME.
goto end

:checkJava
if "%JAVACMD%" == "" set JAVACMD=java

set LOCALCLASSPATH="%CLASSPATH%"
rem for %%i in ("%ANT_HOME%\lib\*.jar") do call "%ANT_HOME%\bin\lcp.bat" "%%i"
if exist "%ANT_HOME%\lib\ant.jar" call "%ANT_HOME%\bin\lcp.bat" "%ANT_HOME%\lib\ant.jar"
if exist "%ANT_HOME%\lib\jaxp.jar" call "%ANT_HOME%\bin\lcp.bat" "%ANT_HOME%\lib\jaxp.jar"
if exist "%ANT_HOME%\lib\parser.jar" call "%ANT_HOME%\bin\lcp.bat" "%ANT_HOME%\lib\parser.jar"

if "%JAVA_HOME%" == "" goto noJavaHome
if exist "%JAVA_HOME%\lib\tools.jar" call "%ANT_HOME%\bin\lcp.bat" "%JAVA_HOME%\lib\tools.jar"
if exist "%JAVA_HOME%\lib\classes.zip" call "%ANT_HOME%\bin\lcp.bat" "%JAVA_HOME%\lib\classes.zip"
goto find_TOMCAT_HOME

:noJavaHome
echo.
echo Warning: JAVA_HOME environment variable is not set.
echo   If build fails because sun.* classes could not be found
echo   you will need to set the JAVA_HOME environment variable
echo   to the installation directory of java.
echo.

:find_TOMCAT_HOME
if not "%TOMCAT_HOME%"=="" goto checkJikes

rem check for Tomcat in Program Files on system drive
if not exist "%SystemDrive%\Program Files\jakarta-tomcat" goto TOMCAT_checkSystemDrive
set TOMCAT_HOME=%SystemDrive%\Program Files\jakarta-tomcat
goto checkJikes

:TOMCAT_checkSystemDrive
rem check for Tomcat in root directory of system drive
if not exist "%SystemDrive%\jakarta-tomcat" goto noTomcatHome
set TOMCAT_HOME=%SystemDrive%\jakarta-tomcat
goto checkJikes

:noTomcatHome
echo TOMCAT_HOME is not set and could not be located. Please set TOMCAT_HOME.
goto end

:checkJikes
if exist "%TOMCAT_HOME%\lib\servlet.jar" call "%ANT_HOME%\bin\lcp.bat" "%TOMCAT_HOME%\lib\servlet.jar"
if exist "%TOMCAT_HOME%\lib\jasper.jar" call "%ANT_HOME%\bin\lcp.bat" "%TOMCAT_HOME%\lib\jasper.jar"

if not "%JIKESPATH%" == "" goto runAntWithJikes

:runAnt
echo Classpath: %LOCALCLASSPATH%
%JAVACMD% -classpath %LOCALCLASSPATH% -Dant.home="%ANT_HOME%" -Dtomcat.home="%TOMCAT_HOME%" %ANT_OPTS% org.apache.tools.ant.Main %ANT_CMD_LINE_ARGS%
goto end

:runAntWithJikes
%JAVACMD% -classpath %LOCALCLASSPATH% -Dant.home="%ANT_HOME%" -Dtomcat.home="%TOMCAT_HOME%" -Djikes.class.path=%JIKESPATH% %ANT_OPTS% org.apache.tools.ant.Main %ANT_CMD_LINE_ARGS%

:end
set LOCALCLASSPATH=
set ANT_CMD_LINE_ARGS=