555_int_flash.lcf

适用于MPC555的uCOS接口程序

/* 555_int_flash.lcf */
/* REV Jan 28, 2003 SM, AP */
/* This linker command file places the executable image into */
/* internal MPC555 flash. Exception table defaults to low and */
/* non-relocated. For relocated exception tables, use */
/* Int. Flash - Reloc Exc Table build target. */

_flash_source	= 0x00;		// **NOTE: MUST match RAM buffer address
							// setting in linker preference panel


MEMORY {
/* Allocate memory for desired exception table(s) */	
	exception_table_low					:	org = 0x00000000, len = 0x1fff
/*	exception_table_high				:	org = 0xfff00000, len = 0x1fff */

/* Allocate remaining flash based on exception table(s) used */
	internal_rom 		:	org = 0x002000, len = 0xfe000 /* (555, excp'n table low) */
	
	
	internal_ram 		:	org = 0x3f9800, len = 0x6800

}
 
/* We use FORCEFILES so that the linker will not deadstrip the file reset.s. The function
	reset would be deadstripped since it is not ever called by anything */

FORCEACTIVE { ExceptionVectorTable, __reset }

SECTIONS {
	
	GROUP : {
		.reset : {}
		. = 0x2000;
	} > exception_table_low
	.init  : {} > internal_rom

	GROUP : {
		.text (TEXT) ALIGN(0x1000) : {}
		.rodata (CONST) : {
			*(.rdata)
			*(.rodata)
		}
		.ctors : {}
		.dtors : {}
		extab : {}
		extabindex : {}
	} > internal_rom 	
	
	GROUP : {
		.data : {}
		.sdata : {}
		.sbss : {}
		.sdata2 : {}
		.sbss2 : {}
		.bss : {}
		.PPC.EMB.sdata0 : {} 
		.PPC.EMB.sbss0 : {}		
	} > internal_ram

	// The dummy section is just a placeholder.  The linker automatically
	// generates an address for it in the ROM image, which tells us
	// where the end of the ROM image is.

	.dummy ALIGN(64): {}
	
	_flash_dest = _f_reset;			// true flash address starts w/.init section
	_flash_size = _f_dummy_rom - _flash_dest;

	// The .fcopy section contains a small piece of code that copies the
	// ROM image to flash.  We don't copy the .fcopy section itself to flash
	// because it could erase the flash if it were accidentally executed
	// at a later time.
	//
	// Bind it to the address it will occupy in the RAM buffer so we can
	// execute it directly from the RAM buffer.

	.fcopy BIND(_flash_source + _flash_size) ALIGN(64) : {
		*(.fcopy)
	}

	.fcopy_data : {} 

	// The internal flash algorithms provided by Motorola are
	// packaged in a binary file.  The linker includes the contents
	// in the .BINARY section.
	.BINARY : {}
}