link.ld

来自「Jazmyn is a 32-bit, protected mode, mult」· LD 代码 · 共 48 行

OUTPUT_FORMAT("binary")
ENTRY(start)
SECTIONS
{
        .text 0x00000000 :
        {
                __code_start = .;
                LONG(0xDEADBEEF)
                LONG(24)
                LONG(24)
                LONG(__code_end - __code_start)
                LONG(__data_end - __data_start)
                LONG(4096)

                *(.text)
                . = ALIGN(4096);
                __code_end = .;           
        }
        .data :
        {
                __data_start = .;

                __CTOR_LIST__ = .;
                LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
                *(.ctors)
                LONG(0)
                __CTOR_END__ = .;

                __DTOR_LIST__ = .;
                LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
                *(.dtors)
                LONG(0)
                __DTOR_END__ = .;

                *(.data)
                . = ALIGN(4096);
                __data_end = .;
         }
         .bss :
         {
                __bss_start = .;
                *(.bss)
                . = ALIGN(8192);
                __bss_end = .;
         }
         __end = .;
}