pds-pipe-loop.mac

采用ANSYS软件的APDL语言编写的两个命令流文件

!/FILNAME,OIL_PIPE_STRESS_ANALYSIS
!/TITLE,STRESS ANALYSIS TO AN UNDERGROUND OIL PIPELINE

!定义APDL参数：尺寸、材料和载荷参数
DIAMETER=420                !管道外径，单位为mm
THICKNESS=10                !管道壁厚，单位为mm
!RADIUS1=210                !管道外半径，单位为mm
!RADIUS2=200                !管道内半径，单位为mm
YOUNG=2.1E5                 !管道材料弹性模量，单位为MPa
TANG=0.81E5                 !管道材料剪切模量，单位为MPa
POSONG=0.3                  !泊松比
DENSITY=7.8E-9              !管道材料密度，单位为吨/立方毫米
DEPTH=3.02                  !腐蚀缺陷深度，    单位为mm
PRESSURE=7.64               !管道内压，        单位为MPa
YIELDSTRESS=312             !管道材料屈服应力，单位为MPa
RESISTANCE=450              !管道材料抗拉强度，单位为MPa
RADIUS1=DIAMETER/2          !管道外半径，单位为mm
RADIUS2=RADIUS1-THICKNESS   !管道内半径，单位为mm
LIMITSTATUSFUN=0            !管道的极限状态函数值

!参数化定义有限元模型
/PREP7
!定义单元类型
ET,1,PLANE82
KEYOPT,1,3,2
KEYOPT,1,5,0
KEYOPT,1,6,0

!定义材料属性 
MP,EX,1,YOUNG              !输入弹性模量
MP,PRXY,1,POSONG           !输入泊松比
MP,DENS,1,DENSITY          !输入密度
TB,BKIN,1,1,2              !动力学硬化
TBDATA,,YIELDSTRESS,TANG   !输入屈服强度和剪切模量

!创建几何模型 
CYL4,,,RADIUS2,0,RADIUS1,90
WPROT,-45
CYL4,0,RADIUS1,DEPTH
ASBA,1,2
WPROT,45 
/RGB,INDEX,100,100,100,0
/RGB,INDEX,80,80,80,13
/RGB,INDEX,60,60,60,14
/RGB,INDEX,0,0,0,15
!APLOT
!/TITLE,GEOMETRIC MODEL
!/REPLOT

!对面进行网格划分
!APLOT
SMRT,1  
MSHAPE,0,2D 
MSHKEY,0
CM,_Y,AREA  
ASEL, , , ,3 
CM,_Y1,AREA 
CHKMSH,'AREA'   
CMSEL,S,_Y  
AMESH,_Y1   
CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2
ALLSEL
!/TITLE,ELEMENTS IN MODEL
!EPLOT
FINISH

!施加载荷和边界条件并执行求解
/SOLU
!结构非线性分析
ANTYPE,0
NLGEOM,ON
PRED,ON
TIME,1
NSUBST,100,1000,1
AUTOTS,1
OUTRES,ALL,1
   
!弧长法
!ARCLEN,1,25,0.001   
!AUTOTS,-1.0 
!RESCONTRL,DEFINE,ALL,1,1

!选择内表面节点并施加压力载荷
!LPLOT
LSEL,S,,,3
NSLL,S,1
SF,ALL,PRES,PRESSURE

!选择两个端面并施加位移约束
LSEL,S,,,2
NSLL,S,1
D,ALL,UX
LSEL,S,,,4
NSLL,S,1
D,ALL,UY
ALLSEL

!执行求解
SOLVE
SAVE
FINISH

!结果后处理
/POST1
SET,LAST
!显示管道变形和未变形形状
!/TITLE,DEFORMED SHAPE AND UNDEFORMED SHAPE
!PLDISP,1

!绘制X方向位移等值线图
!/TITLE,CONTOUR OF DISPLACEMENT IN X DIRECTION
!PLNSOL,U,X

!绘制Y方向位移等值线图
!/TITLE,CONTOUR OF DISPLACEMENT IN Y DIRECTION
!PLNSOL,U,Y

!绘制合位移等值线图
!/TITLE,CONTOUR OF SUM DISPLACEMENTS
!PLNSOL,U,SUM

!绘制X方向应力等值线图
!/TITLE,STRESS CONTOUR IN X DIRECTION
!PLNSOL,S,X

!绘制Y方向应力等值线图
!/TITLE,STRESS CONTOUR IN Y DIRECTION
!PLNSOL,S,Y

!绘制等效应力等值线图
!/TITLE,CONTOUR OF EQUIVALENT STRESS
!PLNSOL,S,EQV

!绘制等效应变等值线图
!/TITLE,CONTOUR OF EQUIVALENT STRAIN
!PLNSOL,EPTO,EQV

!提取管道的最大应力值
NSEL,ALL                             !选中所有节点
NSORT,S,EQV,1,1                      !按照应力绝对值的升序进行节点排序
*GET,MAXSTRESS,SORT,0,MAX            !提取最大绝对值应力值并赋值给MAXSTRESS
LIMITSTATUSFUN=RESISTANCE-MAXSTRESS     !计算管道的极限状态函数值并赋值给LIMITSTATUSFUN
!/TITLE,
FINISH