静态分析.txt

是用apdl语言编的

h=180				!大坝高度
fini_days=30			!完成大坝浇筑的总的天数
ht=h/fini_days			!每天完成的大坝高度
h1=100				!上游水位高度
h2=80				!下游水位高度
h3=100				!坝体不同混凝土材料的分界线，为100m
gm=1000				!gm为水的容重
fia1=90-atan(0.75)*180/3.1415926	!计算下游斜面夹角
fia2=90-fia1			!计算坐标旋转角度
/prep7
et,1,plane42			!辅助划分网格之用
et,2,solid65			!混凝土单元
et,3,solid45			!岩石单元	
keyopt,2,5,2			!输出solid65单元的节点应力

!1号材料
mp,ex,1,2.85e10			!100m以下混凝土的材料特性 
MP,PRXY,1,0.167 
TB,CONC,1,1,9, 
TBDATA,,0.3,1,1.96e6,22e6 	!张开剪切传递系数为0.3，抗拉强度fc=1.96e6pa,抗压强度fs=22e6pa,
mp,dens,1,2400

!2号材料
mp,ex,2,2.6e10			!100m以上混凝土的材料特性 
MP,PRXY,2,0.167 
TB,CONC,2,1,9, 
TBDATA,,0.3,1,1.2e6,17.5e6 	!张开剪切传递系数为0.3，抗拉强度fc=1.2e6pa,抗压强度fs=17.5e6pa,
mp,dens,2,2400

!3号材料
mp,ex,3,2.9e10
mp,PRXY,3,0.3
mp,dens,3,2600

!创建几何模型
!创建关键点
k,1
k,2,0.9*0.75*h+0.1*h
k,3,0.1*h,0.9*h
k,4,0,0.9*h
!创建线
l,1,2
l,2,3
l,3,4
l,4,1
!创建面
al,1,2,3,4
RECTNG,0,0.1*h,0.9*h,h				!画坝顶矩形
RECTNG,-1.5*h,0,-2*h,0				!坝基左面矩形
RECTNG,0,0.9*0.75*h+0.1*h,-2*h,0		!坝基正下方矩形
RECTNG,0.9*0.75*h+0.1*h,(2+0.9*0.75)*h,-2*h,0	!坝基右面矩形
RECTNG,-1.5*h,(2+0.9*0.75)*h,-2*h,h		!总矩形
AOVLAP,all					!将面单元进行粘贴布尔操作
/pnum,line,1					!打开面，线的号码开关
/pnum,area,1
nummrg,all					!合并重复元素
numcmp,all
aplot

!划分3号面的网格,坝体的顶部
lsel,s,,,3,5,2
lesize,all,,,5
lsel,s,,,12,13,1
lesize,all,,,2
amesh,3

!划分1号面的网格，坝体的下部
lsel,s,,,2,4,2
lesize,all,,,18
lsel,s,,,1
lesize,all,,,5
amesh,1
eplot

!划分2号面的网格，坝体的正下方基岩
lsel,s,,,11
lesize,all,,,5
lsel,s,,,9,10,1
lesize,all,,,8,4
amesh,2

!划分4号面的网格
lsel,s,,,14
lesize,all,,,5,4
lsel,s,,,7
lesize,all,,,8,4
lsel,s,,,6
lesize,all,,,5,0.25
amesh,4
eplot

!划分5号面的网格
lsel,s,,,15,16,1
lesize,all,,,8,4
lsel,s,,,8
lesize,all,,,8,0.25
amesh,5
eplot

!连接4号线和13号线，并划分7号面的网格
lsel,s,,,4,13,9
LCCAT,all
lsel,s,,,19
lesize,all,,,5,4
lsel,s,,,20,21,1
lesize,all,,,20
amesh,7
eplot

!连接2号线和12号线，并划分6号面的网格
lsel,s,,,2,12,10
lccat,all
lsel,s,,,17
lesize,all,,,8,4
lsel,s,,,18,22,4
lesize,all,,,20
amesh,6
eplot

!删除前面连接的线元素
allsel
lsel,r,lcca
ldele,all

!拉伸成坝体单元，采用solid65单元和1号材料，随后改变h3以上坝体的材料属性
EXTOPT,ESIZE,8,0,   			!拉伸的份数     
type,2
mat,1
VEXT,1,3,2,,,-0.75*h			!将1号和3号面拉伸成一半的模型
/view,1,1,1,1         
vplot
eplot

!坝体底部单元，拉伸成岩土单元，采用solid45号单元和3号材料
EXTOPT,ESIZE,8,0,        
type,3
mat,3
VEXT,2,,,,,-0.75*h
VEXT,4,5,1,,,-0.75*h
eplot

!拉伸生成大坝两侧的岩石单元
allsel
EXTOPT,ESIZE,5,4,        
EXTOPT,ACLEAR,1				!删除面单元
type,3
mat,3
VEXT,1,7,1,,,h		
/pnum,mat,1
eplot

!利用对称方法完成整个有限元模型
local,11,0,,,-0.75*h			!定义局部坐标系
csys,11					!激活局部坐标系
/PSYMB,CS,1				!显示不同的局部坐标系符号
DSYS,11					!显示局部坐标系
NSYM,Z,20000,all
ENSYM,30000, ,20000,all
nummrg,all			!合并重复节点和单元
numcmp,all
eplot

!改变材料属性
esel,s,mat,,1			!选择材料编号为1的单元
eplot
nsle,s				!选择单元上的节点
nplot
nsel,r,loc,y,h3+1,h+1		!选择h3以上的单元，以便转换材料属性
nsel,r,loc,z,-0.75*h+0.1,0.75*h-0.1
nplot
esln,s
eplot
MPCHG,2,all,			!改变材料属性为2号材料
/REPLOT 
allsel
eplot
save,dam_model,db		!保存模型文件
finish

/solu
!施加边界条件
csys,0
dsys,0
nsel,s,loc,x,(2+0.9*0.75)*h
nsel,a,loc,x,-1.5*h
nplot
d,all,ux
allsel

nsel,s,loc,z,h
nsel,a,loc,z,-(1+1.5)*h
nplot
d,all,uz
allsel

nsel,s,loc,y,-2*h
nplot
d,all,uy
allsel
gplot

!施加重力
ACEL,0,9.8,0,

!选择上游坝面单元，施加水平静水压力
ESEL,S,TYPE,,2
eplot
nsel,s,loc,x,0
nsel,r,loc,z,-1.5*h+0.1,-0.1
nsel,r,loc,y,0.1,h1-5		!若采用(h1-0.1)将导致选择过多的单元,
				!使得施加的面分布荷载出现负数的情况
esln,s
nplot
eplot
/PSF,PRES,NORM,2,0,1		!设定将显示压力的方向
sfgrad,pres,0,y,0,-gm		!给定载荷梯度为-gm
sfe,all,2,pres,,gm*h1
/replot

!下游坝面单元，施加水平静水压力
allsel
ESEL,S,TYPE,,2
nsle,s
eplot
local,12,0,0.9*0.75*h+0.1*h,,,fia2
csys,12
/PSYMB,CS,1
DSYS,12

nsel,s,loc,y,0.1,h2/sin(0.75)-25	!若采用(h2/sin(0.75)-1)将导致选择过多的单元,
					!使得施加的面分布荷载出现负数的情况
nsel,r,loc,z,-1.5*h+0.1,-0.1
nsel,u,loc,x,-1000,-2
esln,s
nplot
eplot
/PSF,PRES,NORM,2,0,1		!设定将显示压力的方向
sfgrad,pres,0,y,0,-gm		!给定载荷梯度为-gm
sfe,all,4,pres,,gm*h2
/replot

!施加上游水位h1产生的渗透压力
!同时施加下游水位h2产生的浮托力
!选择第一部分坝底单元
csys,0
dsys,0
/psymb,cs,1
allsel
nsel,s,loc,y,0
nsel,r,loc,z,-135+0.1,0.1
esln,s
esel,r,type,,2
eplot
SFCUM,PRES,ADD			!设置载荷是叠加的
sfe,all,5,pres,,gm*h2		!下游水位产生的浮托力
p0=gm*h1/(0.9*0.75*h+0.1*h)
sfgrad,pres,0,x,0,-p0
sfe,all,5,pres,,gm*h1
/replot
!选择第二部分坝底单元
allsel
nsel,s,loc,y,0
nsel,r,loc,z,-270+0.1,-135-0.1
esln,s
esel,r,type,,2
eplot
p0=0
sfgrad,pres,0,x,0,-p0		!令斜率为0
sfe,all,3,pres,,gm*h2		!下游水位产生的浮托力
p0=gm*h1/(0.9*0.75*h+0.1*h)
sfgrad,pres,0,x,0,-p0
sfe,all,3,pres,,gm*h1
SFCUM,PRES,repl			!设置载荷是替代的

!检查坝底的载荷是否正确
nsel,s,loc,y,0
esln,s
esel,r,type,,2
/replot
save,dam_static_solu,db
allsel
outres,all,all
autots,on
nsubst,20
solve
save,dam_static_rst,db

/post1
esel,s,type,,2

set,1,last			!获取第一载荷步，最后子步的结果
PLNSOL,U,X
PLNSOL,U,Y
PLNSOL,EPTO,1,0,1		!画第一主应变
PLNSOL,S,1,0,1			!画第一主应力
PLNSOL,S,3,0,1			!画第三主应力
/DEVICE,VECTOR,1
PLCRACK,0,0			!显示开裂位置
!察看在各个积分点上的开裂情况
ETABLE,11,NMISC,53		!显示开裂的情况，包括裂缝的张开，闭合，压碎
ETABLE,22,NMISC,60
ETABLE,33,NMISC,67
ETABLE,44,NMISC,74
ETABLE,55,NMISC,81
ETABLE,66,NMISC,88
ETABLE,77,NMISC,95
ETABLE,88,NMISC,102
PLETAB,33,AVG   
PLETAB,44,AVG   
finish