5-4-2.txt

是用apdl语言编的

!注意：两个常力产生的最大位移比一个常力产生的两倍还要大。
!当单元数目为50，100，200时计算得到的跨中最大位移是一样的，所以单元数目对位移响应没有多大的影响。

/config,nres,2000
/PREP7                          !建模
ET,1,BEAM3                      !梁单元
MP,EX,1,207E9                    !弹性模量
MP,DENS,1,2000                 !密度
MP,NUXY,1,0.3
R,1,0.1,0.0001/12,0.1        !横截面积、惯性距、截面高
NELEM=100
LBEAM=32                      !梁长度
deltL=LBEAM/NELEM
f=1000
V=120                          !移动荷载速度
NNODE=NELEM+1
deltt=deltL/V*3.6
*do,i,1,NNODE,1
N,i,(i-1)*deltL                  !节点点矩为0.3
*enddo
*do,i,1,NELEM
E,i,i+1
*enddo
finish


/solu
d,1,all
d,NNODE,all
antype,trans 

*do,ii,1,nnode+8,1
outres,all,all 					!输出所有加载子步的所有结果
time,ii*deltt               		!每个荷载步的最终求解时间
nsubst,5                    	!每个荷载步包含五个荷载子步
*if,ii,lt,8,then
  fdele,all,all               		!删除所有的集中力荷载
  nsel,s,loc,x,(ii-1)*deltl       		!选择集中力作用节点
  f,all,FY,-f				 	!施加集中荷载
  allsel                        	!选择所有
  solve

*elseif,ii,lt,nnode
  fdele,all,all
  nsel,s,loc,x,(ii-1)*deltl
  nsel,a,loc,x,(ii-7-1)*deltl
  f,all,fy,-f
  allsel
  solve

*else
  fdele,all,all
  nsel,s,loc,x,(ii-7-1)*deltl
  f,all,fy,-f
  allsel
  solve

*endif
*enddo
finish

/post26
NSOL,2,nelem/2+1,U,Y,UY_2       !定义第二个变量为UY_2,其值为101号节点的Y方向的位移
xvar,1                   !定义时间变量为坐标横轴
plvar,2                  !输出位移图
deriv,3,2,1,,,,,1        !将位移对时间求导，得到速度，存为变量3
plvar,3                  !输出速度图
fini