网壳非线性屈曲final.txt

是用apdl语言编的

!先施加一个初始扰动，然后再用弧长法计算至完成


/prep7
et,1,beam188

mp,ex,1,2.1e11
mp,prxy,1,0.3
mp,gxy,1,8e10

!环杆与径杆的界面
sectype,1,beam,ctube,,0
secdata,0.09,0.0925,36
!斜杆截面
sectype,2,beam,ctube,,0
secdata,0.08,0.083,36

!建立模型
csys,2
fi=5
r=50
theta=15

!一半模型节点
*do,i,1,6
 *do,j,1,24,1
 n,24*(i-1)+j,r,(j-1)*theta,(i-1)*fi+60
 *enddo
*enddo
n,2000,100,0,90

type,1
mat,1
secnum,1
!环杆
*do,i,1,6
 *do,j,1,23,1
 e,24*(i-1)+j,24*(i-1)+j+1,2000
 *enddo
e,i*24,i*24-23,2000
*enddo

!径杆
*do,i,1,5
 *do,j,1,24,1
 e,24*(i-1)+j,24*(i-1)+j+24,2000
 *enddo
*enddo
n,1000,50,0,90
*do,i,121,144,1
e,i,1000,2000
*enddo
!/pnum,node,1
eplot

type,1
real,1
mat,1
secnum,2
!斜杆
*do,i,1,5
 *do,j,1,23,1
 e,24*(i-1)+j,24*(i-1)+j+25,2000
 *enddo
e,i*24,i*24+1,2000
*enddo
nummrg,all
numcmp,all
finish

/solu
csys,2
nsel,s,loc,z,60
nplot
d,all,ux
d,all,uy
d,all,uz
allsel

nlgeom,on
f,145,fy,-1000    !施加初始扰动
allsel
/OUT,SCRATCH,
solve
/OUT
nsel,u,loc,z,60
f,all,fz,-100000
outres,all,all
arclen,on
nsubst,10
allsel
/OUT,SCRATCH,
solve
/OUT
finish

/post1
pldisp,1

/post26
nsol,2,145,u,z
nsol,3,121,u,z
nsol,4,97,u,z
nsol,5,73,u,z
prod,6,1,,,load,,,12000
prod,7,2,,,,,,-1
prod,8,3,,,,,,-1
prod,9,4,,,,,,-1
prod,10,5,,,,,,-1
!prvar,2,3,4
/axlab,x,deflection
/axlab,y,load
/grid,1
xvar,7
plvar,6