隧道.txt

是用apdl语言编的

!隧道模拟开挖命令流!希望能够得到加分! 
!土体的弹性摸量增加

/com 
fini 
/cle 
*set,x1,-12 
*set,y1,-12 
*set,w1,28.9
*set,h1,30.15

*set,x2,-25 
*set,y2,-12 
*set,w2,13
*set,h2,30.15

*set,x3,16.9
*set,y3,-12 
*set,w3,13
*set,h3,30.15

*set,x4,-25
*set,y4,-30 
*set,w4,54.9
*set,h4,18

*set,th,0.4 		!厚度
*set,length_z,50	!洞的进深
/prep7 
et,1,mesh200,2		!用于3-D的2节点线
et,2,mesh200,6		!用于3-D的4节点四边形
et,3,shell63
et,4,solid45 
 
r,1,th 			!壳的厚度

mp,ex,1,3.0e10 		!壳的材料,C30混凝土
mp,prxy,1,0.2 
mp,dens,1,2500 
mp,ex,2,4.5e8 		!保留岩石的材料
mp,prxy,2,0.32 
!tb,dp,2 
!tbdata,1,20,30, 
mp,dens,2,2700 
mp,ex,3,4.51e8 		!挖去岩石的材料
mp,prxy,3,0.32 
!tb,dp,3 
!tbdata,1,20,30, 
mp,dens,3,2700 

k,,0,0 
k,,0,3.85 
k,,0.88,5.5 
k,,2.45,6.15 
k,,4.02,5.5 
k,,4.9,3.85 
k,,4.9,0 

larc,1,2,6,8.13 !定义两点之间的圆弧线，larc,p1,p2,pc,rad
larc,2,3,6,3.21 
larc,3,4,6,2.22 
larc,4,5,2,2.22 
larc,5,6,2,3.21 
larc,6,7,2,8.13 
larc,7,1,4,6 

a,1,2,3,4,5,6,7 		!产生面1

!blc4,x1,y1,w,h1 !block4,xcorner,ycorner,width,height,depth 
!blc4,x2,y2,w,h2 !block4,xcorner,ycorner,width,height,depth 产生面3

blc4,x1,y1,w1,h1		!产生面2
blc4,x2,y2,w2,h2		!产生面3
blc4,x3,y3,w3,h3		!产生面4
blc4,x4,y4,w4,h4			!产生面5
/pnum,area,1

aovl,1,2,3,4,5 	!布尔操作重叠，得到面3
nummrg,all,,,,low
numcmp,all

l,1,8			!从四个角点上连接出四条线
l,7,9
l,6,10
l,2,11

lsel,s,line,,21,22,1	!用线分割面
lsel,a,line,,7
asbl,5,all

lsel,s,line,,21,24,3
lsel,a,line,,1
asbl,7,all

lsel,s,line,,22,23,1
lsel,a,line,,6
asbl,8,all

nummrg,all,,,,low
numcmp,all

lsel,s,line,,2,5,1
LCCAT,all
lesize,all,,,3

lsel,s,line,,9,11,2
lsel,a,line,,6
lsel,a,line,,1
lesize,all,,,8

lsel,s,line,,8,10,2
lsel,a,line,,7
lesize,all,,,12


lsel,s,line,,21,24,1
lesize,all,,,10,2

type,2
asel,s,area,,5,8,1
amesh,all

!mopt,split,on 		!指定网格划分选项，四边形单元如果违背了单元形状则将其分解为三角形单元
!mopt,split,err 
!mopt,split,warn 
!mopt,qmesh,main 	!选用四边形网格划分器，当这种操作失败时，不调用备用的网格划分器

asel,s,area,,1
amesh,1

lsel,s,line,,12,13,1
lesize,all,,,8
lsel,s,line,,15,18,1
lesize,all,,,6,2
asel,s,area,,2,3,1
amesh,all

lsel,s,line,,14
lesize,all,,,24
lsel,s,line,,19,20,1
lesize,all,,,6,2
lsel,s,line,,15,17,2
lsel,a,line,,8
LCCAT,all
asel,s,area,,4
amesh,all
LSEL,s,LCCA
LDELE,all
nummrg,all,,,,low
numcmp,all
allsel


!以下开始拉伸成实体单元
!首先拉伸成壳单元
k,1000,,,-length_z
l,1,1000
/view,1,1,1,1
/replot
EXTOPT,ESIZE,10,0,
LSEL,S,LINE,,1,7,1
ADRAG,all,,,,,,25
gplot
type,3
real,1
mat,1
ASEL,S,loc,z,-25
APLOT
lsel,s,loc,z,-25
lesize,all,,,10
MSHAPE,0,2D 
MSHKEY,1
amesh,all

!拉伸岩石的实体
ASEL,invert
aplot
EXTOPT,ESIZE,10,0,  
EXTOPT,ACLEAR,1
TYPE,4
MAT,2
asel,r,area,,2,8,1
VDRAG,all,,,,,,25
allsel

!挖去部分岩石的实体
MAT,3
VDRAG,1,,,,,,25
EPLOT

nummrg,all,,,,low
numcmp,all

!约束两侧面的X方向的约束
asel,s,loc,x,x2 
asel,a,loc,x,x2+w4 
da,all,ux,0 
alls 

!约束地面的Y方向的约束
asel,s,loc,y,y4
da,all,uy,0 
alls 

asel,s,loc,z,-length_z
asel,a,loc,z,0
da,all,uz,0
allsel
acel,,10 
fini 

/solu 
antype,static 

deltim,0.1,0.05,0.2 
autots,on 		!使用自动时间步 
pred,on 		!打开时间步长预测器 
lnsrch,on 		!打开线性搜索 
nlgeom,on 		!打开大位移效果 
nropt,full 		!设定牛顿-拉普森选项 
cnvtol,f,,0.02,2,0.5 

esel,s,type,,3 		!选择梁单元，杀死
ekill,all 
esel,all 
esel,s,live 		!选择活的单元
nsle,s 			!选择活单元上的节点
nsel,invert 		!反向选择，即选择了死单元上的节点
d,all,all,0 		!将死单元上的节点约束所有位移，使其不参与矩阵运算
nsel,all 
esel,all 
/PBC,ALL,,1
gplot
solve 


*do,ii,1,10,1     
    esel,s,mat,,3 		!选择挖去的岩石，杀死
    nsle,s
    nsel,r,loc,z,0.1-(ii-1)*5,-(5.1+(ii-1)*5)
    esln,r,1    
    ekill,all     
    
    esel,s,type,,3 		!激活挖去的岩石对应的壳单元,并将其节点上的约束删除
    nsle,s
    nsel,r,loc,z,0.1-(ii-1)*5,-(5.1+(ii-1)*5)
    esln,r,1
    ealive,all 

    nsle,s 
    ddele,all,all 
    esel,all 
    esel,s,live		!选择活单元，此时应该包含两部份，一是梁单元，二是未挖去的岩石单元 
    nsle,s 
    nsel,invert 		!反向选择，将死单元上的节点约束所有自由度
    d,all,all,0 
    nsel,all 
    esel,all
solve
*enddo 
/post1 
/DEVICE,VECTOR,1
ESEL,S,type,,3
SET,1,LAST,1, 
PLNSOL,U,Y,0,1
SET,2,LAST,1, 
PLNSOL,U,Y,0,1
SET,6,LAST,1, 
PLNSOL,U,Y,0,1
SET,11,LAST,1, 
PLNSOL,U,Y,0,1



 
!*dim ,VUY_1
!*dim ,VUY_2
!*dim ,VUY_6
!*dim ,VUY_11
!SET,1,LAST,1, 
!PLNSOL,U,Y,0,1
!PLNSOL,U,SUM,0,1
!ETABLE,EUY_1,U,Y
!PLETAB,EUY_1,AVG
!PRETAB,EUY_1
!*vget,VUY_1,node,387,U,Y

!SET,2,LAST,1, 
!PLNSOL,U,Y,0,1
!PLNSOL,U,SUM,0,1
!ETABLE,EUY_2,U,Y
!PLETAB,EUY_2,AVG
!PRETAB,EUY_2
!*vget,VUY_2,node,387,U,Y

!SET,6,LAST,1, 
!PLNSOL,U,Y,0,1
!PLNSOL,U,SUM,0,1
!ETABLE,EUY_6,U,Y
!PLETAB,EUY_6,AVG
!PRETAB,EUY_6
!*vget,VUY_6,node,323,U,Y



!SET,3,LAST,1, 
!PLNSOL,U,Y,0,1
!PLESOL,SMISC,4		!MX
!PLESOL,SMISC,5		!MY
!PLESOL,SMISC,6		!MXY

!ETABLE,p_i,SMISC, 13
!ETABLE,p_j,SMISC, 14
!ETABLE,p_k,SMISC, 15
!ETABLE,p_l,SMISC, 16

!ETABLE,p_i_3,SMISC, 17
!ETABLE,p_j_3,SMISC, 18

!ETABLE,p_k_4,SMISC, 20
!ETABLE,p_l_4,SMISC, 19

!ETABLE,p_k_5,SMISC, 21
!ETABLE,p_l_5,SMISC, 22
!fini 
!/post1 
!etable,if,smisc,1 
!etable,jf,smisc,7 
!etable,im,smisc,6 
!etable,jm,smisc,12 

大家可以在这个的基础上进一步发掘