VB开发的ERP系统

'*    备        注:
'******************************************************************

Dim ReportTitle As String                '报表主标题
Dim Card_Str As String                   '用户录入查询条件
Dim rstemp As ADODB.Recordset            '临时打开数据集变量
Dim Period As String                     '会计期间
Dim Year As String                       '会计年度

'以下为固定使用变量
Dim Dyymctbl As New DY_Dyymsz            '打印页面窗体变量
Dim GridCode As String                   '显示网格网格代码
Dim GridInf() As Variant                 '整个网格设置信息
Dim Tsxx As String                       '系统提示信息
Dim Qslz As Long                         '网格隐藏(非操作显示)列数
Dim Sjhgd As Double                      '网格数据行高度
Dim Sfxshjwg As Boolean                  '是否显示合计网格
Dim GridBoolean() As Boolean             '网格列信息(布尔型)
Dim GridStr()  As String                 '网格列信息(字符型)
Dim GridInt() As Integer                 '网格列信息(整型)
Dim Szzls As Integer                     '数组总列数(网格列数-1)

Private Sub Form_Resize()                '根据窗体大小来调整网格,标题栏大小
    
    On Error Resume Next
    
    With CxbbGrid
        .Width = Me.Width - 160
        .Height = Me.Height - .Top - 400
    End With
    
    With Pic_Title
        .Width = Me.Width - 160
    End With
    
    GsToolbar.Left = Me.Width - GsToolbar.Width - 160

End Sub

Private Sub Form_Load()                                                   '窗体装入
     
    '调入打印页面设置窗体
    ReportTitle = "固定统计报表"
    XtReportCode = "Gdzc_Book_Total"
    Load Dyymctbl
     
    '调整标题栏及网格、格式工具条位置
    Pic_Title.Left = 40
    Pic_Title.Top = SzToolbar.Top + SzToolbar.Height - 10
    CxbbGrid.Left = Pic_Title.Left
    CxbbGrid.Top = Pic_Title.Top + Pic_Title.Height + 20
    
    '调 入 网 格
    GridCode = "Gdzc_Book_Total"
    Call BzWgcsh(CxbbGrid, GridCode, GridInf(), GridBoolean(), GridInt(), GridStr())
     
    Qslz = GridInf(1)
    Sjhgd = GridInf(2)
    Sfxshjwg = GridInf(7)
    Szzls = CxbbGrid.Cols - 1

End Sub

Private Sub Form_Unload(Cancel As Integer)                                  '窗体卸载
    
    '卸载条件窗体
    Book_Total_Search.UnloadCheck.Value = 1
    Unload Book_Total_Search
    '卸载打印页面设置窗体
    Unload Dyymctbl

End Sub

Private Sub GsToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)       '网格格式调整
    
    Select Case Button.Key
        Case "bcgs"                                          '保存表格格式
          Call Bcwggs(CxbbGrid, GridCode, GridStr)
        Case "hfmrgs"                                        '恢复默认格式
          Call Hfmrgs(CxbbGrid, GridCode, GridStr)
    End Select

End Sub

Private Sub SzToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)
    
    Select Case Button.Key
        Case "ymsz"                                          '页面设置
            Dyymctbl.Show 1
        Case "yl"                                            '预 览
            Call bbyl(True)
        Case "dy"                                            '打 印
            Call bbyl(False)
        Case "cx"                                            '查 询
            Book_Total_Search.Show 1
        Case "xc"                                            '详查
            Book_Total_Detail.Year_Text = LeftChar(Book_Total_Search.Com_Year(1).Text)
            Book_Total_Detail.Period_Text = RightChar(Book_Total_Search.Com_Year(1).Text)
            Book_Total_Detail.Timer1.Enabled = True
            Book_Total_Detail.Show
        Case "fh"                                            '退 出
            Unload Me
        Case "bz"
            SendKeys "{F1}"
     End Select
     
End Sub

Private Sub Timer1_Timer()                                 '在窗体激活后调入查询程序
    
    Timer1.Enabled = False
    Xt_Wait.Show
    Xt_Wait.Refresh
    
    '加快显示速度
    CxbbGrid.Redraw = False
    
    '生成查询结果
    Call Sub_Query
    
    CxbbGrid.Redraw = True
     
    Xt_Wait.Hide
    
End Sub

Private Sub Sub_Query()                                    '生成查询结果
    
    Dim Rec_Query As New ADODB.Recordset        '查询结果动态集
    Dim Sqlstr As String                        '查询字符串
    Dim Coljsq As Long                          '网格列计数器
    Dim Jsqte As Integer                        '临时动态计数器
    Dim SqlStr1 As String                       '查询字符串
    
    '根据查询条件，为查询语句赋值
    With Book_Total_Search
        Year = LeftChar(.Com_Year(1).Text)              '最大会计年度
        Period = RightChar(.Com_Year(1).Text)           '最大会计期间
        If Trim(.Com_Year(0).Text) <> "" And Trim(.Com_Year(1).Text) <> "" Then
            Lbl_Year.Caption = Trim(.Com_Year(0).Text) & "——" & Trim(.Com_Year(1).Text)       '显示会计期间
        End If
        Card_Str = "where 1=1"
        For Jsqte = 1 To 3
            Select Case Jsqte
                Case 1          '起始会计期间
                    Card_Str = Card_Str & " and Gdzc_Total.year>=" & Val(LeftChar(Trim(.Com_Year(0).Text))) & " and Gdzc_Total.Period>=" & Val(RightChar(Trim(.Com_Year(0).Text)))
                Case 2          '终止会计期间
                    Card_Str = Card_Str & " and Gdzc_Total.year<=" & Val(LeftChar(.Com_Year(1).Text)) & " and Gdzc_Total.Period<=" & Val(RightChar(.Com_Year(1).Text))
                Case 3
                    If .CxOption(0).Value = True Then                  '按部门和资产类别
                        CxbbGrid.ColHidden(0) = False
                        CxbbGrid.ColHidden(1) = False
                        Sqlstr = "SELECT Gy_Department.DeptName AS DeptName, Gdzc_Sort.FASortName AS FASortName, " _
                            & "SUM(Gdzc_Total.FAValueInM) AS FAValueInM, SUM(Gdzc_Total.FAValueOutM) " _
                            & "AS FAValueOutM, SUM(Gdzc_DetailedForm.DeprValue) AS DeprValue " _
                            & "FROM Gdzc_Card RIGHT OUTER JOIN Gdzc_Total ON Gdzc_Card.DeptCode = Gdzc_Total.DeptCode LEFT OUTER JOIN " _
                            & "Gdzc_Sort ON Gdzc_Total.FASortCode = Gdzc_Sort.FASortCode LEFT OUTER JOIN " _
                            & "Gy_Department ON Gdzc_Total.DeptCode = Gy_Department.DeptCode RIGHT OUTER JOIN " _
                            & "Gdzc_DetailedForm ON Gdzc_Card.CardCode = Gdzc_DetailedForm.CardCode AND " _
                            & "Gdzc_Total.Period = Gdzc_DetailedForm.Period AND " _
                            & "Gdzc_Total.[Year] = Gdzc_DetailedForm.[Year] AND " _
                            & "Gdzc_Total.FASortCode = Gdzc_DetailedForm.FASortCode "
                        Sqlstr = Sqlstr & Card_Str & " GROUP BY Gy_Department.DeptName, Gdzc_Sort.FASortName "
                    ElseIf .CxOption(1).Value = True Then              '按部门
                        CxbbGrid.ColHidden(1) = True
                        CxbbGrid.ColHidden(0) = False
                        Sqlstr = "SELECT SUM(Gdzc_Total.FAValueInM) AS FAValueInM, SUM(Gdzc_Total.FAValueOutM) " _
                            & "AS FAValueOutM, Gy_Department.DeptName " _
                            & "FROM Gdzc_Total INNER JOIN Gy_Department ON Gdzc_Total.DeptCode = Gy_Department.DeptCode "
                        
                        Sqlstr = Sqlstr & Card_Str & " GROUP BY Gy_Department.DeptName"
                    Else                                               '按资产类别
                        CxbbGrid.ColHidden(1) = False
                        CxbbGrid.ColHidden(0) = True
                        Sqlstr = "SELECT Gdzc_Sort.FASortName, SUM(Gdzc_Total.FAValueInM) AS FAValueInM, " _
                            & "SUM(Gdzc_Total.FAValueOutM) As FAValueOutM " _
                            & "FROM Gdzc_Sort RIGHT OUTER JOIN Gdzc_Total ON Gdzc_Sort.FASortCode = Gdzc_Total.FASortCode "
                        
                        Sqlstr = Sqlstr & Card_Str & " GROUP BY Gdzc_Sort.FASortName"
                    End If
            End Select
        Next Jsqte
    End With
    
    Set Rec_Query = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    With Rec_Query
    CxbbGrid.Rows = CxbbGrid.FixedRows
    CxbbGrid.Rows = CxbbGrid.FixedRows + .RecordCount
    Jsqte = CxbbGrid.FixedRows
   
    Do While Not .EOF
        If Jsqte >= CxbbGrid.Rows Then
            CxbbGrid.AddItem ""
        End If
        
        If Book_Total_Search.CxOption(0).Value = True Or Book_Total_Search.CxOption(1).Value = True Then
            CxbbGrid.TextMatrix(Jsqte, Sydz("001", GridStr(), Szzls)) = Trim(!DeptName & "")                                            '部门名称
        End If
        If Book_Total_Search.CxOption(0).Value = True Or Book_Total_Search.CxOption(2).Value = True Then
            CxbbGrid.TextMatrix(Jsqte, Sydz("002", GridStr(), Szzls)) = Trim(!FASortName & "")                                          '资产类别
        End If
        
        If Book_Total_Search.CxOption(0).Value = True Then                                                                              '按部门和资产类别
            If Val(!DeprValue) <> 0 Then CxbbGrid.TextMatrix(Jsqte, Sydz("008", GridStr(), Szzls)) = Trim(!DeprValue & "")              '期间折旧
            SqlStr1 = "SELECT Gdzc_Total.FAValueEndM, Gdzc_Total.DeprSumEndM, Gy_Department.DeptName, " _
                & "Gdzc_Sort.FASortName FROM Gdzc_Total INNER JOIN " _
                & "Gdzc_Sort ON Gdzc_Total.FASortCode = Gdzc_Sort.FASortCode INNER JOIN Gy_Department ON Gdzc_Total.DeptCode = Gy_Department.DeptCode " _
                & "Where Gdzc_Total.Year =" & Val(Year) & " And Gdzc_Total.Period = " & Val(Period) & " and Gy_DepartMent.deptname='" & Trim(!DeptName & "") & "'" _
                & " and Gdzc_Sort.FASortName='" & Trim(!FASortName) & "'"
        ElseIf Book_Total_Search.CxOption(1).Value = True Then                                                                          '按部门
            SqlStr1 = "SELECT SUM(Gdzc_Variation.SumDeprNew) - SUM(Gdzc_Variation.SumDeprOld) " _
                & "AS Depr FROM Gdzc_Variation LEFT OUTER JOIN Gy_Department ON Gdzc_Variation.DeptNew = Gy_Department.DeptCode " _
                & "WHERE Gdzc_Variation.FAVariCode = '00501' and Gy_department.deptName='" & Trim(!DeptName) & "' and Gdzc_Variation.year>=" & Val(LeftChar(Book_Total_Search.Com_Year(0).Text)) & " and " _
                & "gdzc_variation.period>=" & Val(RightChar(Book_Total_Search.Com_Year(0).Text)) & " and Gdzc_Variation.year<=" & Val(LeftChar(Book_Total_Search.Com_Year(1).Text)) & " and " _
                & "gdzc_variation.period<=" & Val(RightChar(Book_Total_Search.Com_Year(1).Text))
            Set rstemp = Cw_DataEnvi.DataConnect.Execute(SqlStr1)
            If Not rstemp.EOF Then
                If Val(rstemp!Depr & "") <> 0 Then CxbbGrid.TextMatrix(Jsqte, Sydz("008", GridStr(), Szzls)) = Trim(rstemp!Depr & "")   '期间折旧
            End If
            rstemp.Close
            Set rstemp = Nothing
            SqlStr1 = "SELECT SUM(Gdzc_Total.FAValueEndM) AS FAValueEndM, " _
                & "SUM(Gdzc_Total.DeprSumEndM) AS DeprSumEndM, Gy_Department.DeptName " _
                & "FROM Gy_Department RIGHT OUTER JOIN Gdzc_Total ON Gy_Department.DeptCode = Gdzc_Total.DeptCode " _
                & "Where Gdzc_Total.Year =" & Val(Year) & " And Gdzc_Total.Period = " & Val(Period) & " and Gy_department.deptName='" & Trim(!DeptName) & "' GROUP BY Gy_Department.DeptName"
        Else
            SqlStr1 = "SELECT SUM(Gdzc_DetailedForm.DeprValue) AS DeprValue, Gdzc_Sort.FASortName FROM Gdzc_Sort INNER JOIN " _
                & "Gdzc_DetailedForm ON Gdzc_Sort.FASortCode = Gdzc_DetailedForm.FASortCode " _
                & "where Gdzc_Sort.FASortName='" & Trim(!FASortName & "") & "' and Gdzc_DetailedForm.year>=" & Val(LeftChar(Book_Total_Search.Com_Year(0).Text)) & " and " _
                & "Gdzc_DetailedForm.period>=" & Val(RightChar(Book_Total_Search.Com_Year(0).Text)) & " and Gdzc_DetailedForm.year<=" & Val(LeftChar(Book_Total_Search.Com_Year(1).Text)) & " and " _
                & "Gdzc_DetailedForm.period<=" & Val(RightChar(Book_Total_Search.Com_Year(1).Text)) _
                & "GROUP BY Gdzc_Sort.FASortName"
            Set rstemp = Cw_DataEnvi.DataConnect.Execute(SqlStr1)
            If Not rstemp.EOF Then
                If Val(rstemp!DeprValue & "") <> 0 Then CxbbGrid.TextMatrix(Jsqte, Sydz("008", GridStr(), Szzls)) = Trim(rstemp!DeprValue & "") '期间折旧
            End If
            rstemp.Close
            Set rstemp = Nothing
            SqlStr1 = "SELECT SUM(Gdzc_Total.FAValueEndM) AS FAValueEndM,SUM(Gdzc_Total.DeprSumEndM) AS DeprSumEndM, Gdzc_Sort.FASortName " _
                & "FROM Gdzc_Sort RIGHT OUTER JOIN Gdzc_Total ON Gdzc_Sort.FASortCode = Gdzc_Total.FASortCode " _
                & "Where Gdzc_Total.Year =" & Val(Year) & " And Gdzc_Total.Period = " & Val(Period) & " and Gdzc_sort.FASortName='" & Trim(!FASortName) & "' " _
                & "GROUP BY Gdzc_Sort.FASortName"
        End If
        Set rstemp = Cw_DataEnvi.DataConnect.Execute(SqlStr1)
        If Not rstemp.EOF Then
            CxbbGrid.TextMatrix(Jsqte, Sydz("003", GridStr(), Szzls)) = Trim(rstemp.Fields("FAValueEndM") & "")                                 '资产原值
            CxbbGrid.TextMatrix(Jsqte, Sydz("004", GridStr(), Szzls)) = Trim(rstemp.Fields("DeprSumEndM") & "")                                 '累计折旧
            CxbbGrid.TextMatrix(Jsqte, Sydz("007", GridStr(), Szzls)) = Trim(rstemp.Fields("FAValueEndM") & "")                                 '计提原值
            CxbbGrid.TextMatrix(Jsqte, Sydz("009", GridStr(), Szzls)) = Trim(Val(Val(rstemp!FAvalueEndM) - Val(rstemp!DeprSumEndM)) & "")       '资产净值
        End If
        rstemp.Close
        Set rstemp = Nothing
        CxbbGrid.TextMatrix(Jsqte, Sydz("005", GridStr(), Szzls)) = Trim(!FAValueInM & "")                                                      '原值增加
        CxbbGrid.TextMatrix(Jsqte, Sydz("006", GridStr(), Szzls)) = Trim(!FAValueOutM & "")                                                     '原值减少
        CxbbGrid.RowHeight(Jsqte) = Sjhgd
        .MoveNext
        Jsqte = Jsqte + 1
    Loop
   
    End With
    
    '为零时清空单元格
    Call Txt_Clear
    
End Sub

Private Sub bbyl(bbylte As Boolean)                    '报表打印预览
    
    Dim Bbzbt$, Bbxbt() As String, bbxbtzzxs() As Integer, Bbxbtgs As Integer
    Dim Bbbwh() As String, Bbbwhzzxs() As Integer, Bbbwhgs As Integer
    Bbxbtgs = 1                                          '报 表 小 标 题 行 数
    Bbbwhgs = 0                                          '报 表 表 尾 行 数
    ReDim Bbxbt(1 To Bbxbtgs)
    ReDim bbxbtzzxs(1 To Bbxbtgs)
    
    If Bbbwhgs <> 0 Then
        ReDim Bbbwh(1 To Bbbwhgs)
        ReDim Bbbwhzzxs(1 To Bbbwhgs)
    End If
    
    Bbzbt = ReportTitle
    Bbxbt(1) = " "
    bbxbtzzxs(1) = 1                                     '报表行组织形式(0-居左 1-居中 2-居右)
    
    Bbxbt(1) = Trim(Trim(Label1.Caption) & Trim(Lbl_Year.Caption))
    Call Scyxsjb(CxbbGrid)                               '生成报表数据
    Call Scdybb(Dyymctbl, Bbzbt, Bbxbt(), bbxbtzzxs(), Bbxbtgs, Bbbwh(), Bbbwhzzxs(), Bbbwhgs, bbylte)
  
    If Not bbylte Then
        Unload DY_Tybbyldy
    End If

End Sub

'*****************************************************
'[>>自定义函数
'取右字符串
Function RightChar(str As String) As String

    If str = "" Then Exit Function
    
    Dim i As Integer
    
    i = InStrRev(str, ".")
    RightChar = Mid(str, i + 1)
    
End Function

'取左字符串
Function LeftChar(str As String) As String

    If str = "" Then Exit Function
    
    Dim i As Integer
    
    i = InStr(str, ".")
    LeftChar = Mid(str, 1, i - 1)
    
End Function

'为零时清空单元格
Function Txt_Clear()

    Dim Row_Integer, Col_Integer As Integer         '行数和列数变量
    
    For Row_Integer = CxbbGrid.FixedRows To CxbbGrid.Rows - 1
        For Col_Integer = 2 To CxbbGrid.Cols - 1
            If Val(CxbbGrid.TextMatrix(Row_Integer, Col_Integer)) = 0 Then
                CxbbGrid.TextMatrix(Row_Integer, Col_Integer) = ""
            End If
        Next Col_Integer
    Next Row_Integer
    
End Function
'<<]
'****************************************************