-

VB开发的ERP系统

         Index           =   0
         Left            =   930
         TabIndex        =   4
         Top             =   900
         Width           =   360
      End
   End
End
Attribute VB_Name = "Tjfx_Diff"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'**************************************************************************
'*    模 块 名 称 :差异分摊
'*    功 能 描 述 :
'*    程序员姓名  :白凤英
'*    最后修改人  :白凤英
'*    最后修改时间:2001/12/18
'*    备        注:程序中所有依实际情况自定义部分均用[>>  <<]括起
'**************************************************************************

Dim ReportTitle As String                '报表主标题
Dim Str_QueryCondi As String             '用户录入查询条件
Dim Rec_BillID As New ADODB.Recordset    '用户查询单据ID动态集

'以下为固定使用变量
Dim Dyymctbl As New DY_Dyymsz            '打印页面窗体变量
Dim GridCode As String                   '显示网格网格代码
Dim GridInf() As Variant                 '整个网格设置信息
Dim Tsxx As String                       '系统提示信息
Dim Qslz As Long                         '网格隐藏(非操作显示)列数
Dim Sjhgd As Double                      '网格数据行高度
Dim Sfxshjwg As Boolean                  '是否显示合计网格
Dim GridBoolean() As Boolean             '网格列信息(布尔型)
Dim GridStr()  As String                 '网格列信息(字符型)
Dim GridInt() As Integer                 '网格列信息(整型)
Dim Szzls As Integer                     '数组总列数(网格列数-1)


Private Sub Form_Resize()                '根据窗体大小来调整网格,标题栏大小(Fixed)
    On Error Resume Next
    With CxbbGrid
        .Width = Me.Width - 160
        .Height = Me.Height - .Top - 400
    End With
    With Pic_Title
        .Width = Me.Width - 160
    End With
    
    GsToolbar.Left = Me.Width - GsToolbar.Width - 140

End Sub

Private Sub Form_Load()                                                   '窗体装入
  
    '调入打印页面设置窗体
    ReportTitle = "差异分摊表"
    XtReportCode = "Chhs_Diff"
    Load Dyymctbl
      
    '调整标题栏及网格、格式工具条位置(Fixed)
    Pic_Title.Left = 40
    Pic_Title.Top = SzToolbar.Top + SzToolbar.Height - 10
    CxbbGrid.Left = Pic_Title.Left
    CxbbGrid.Top = Pic_Title.Top + Pic_Title.Height + 20
     
    '调 入 网 格(Fixed)
    GridCode = "Chhs_Diff"
    Call BzWgcsh(CxbbGrid, GridCode, GridInf(), GridBoolean(), GridInt(), GridStr())
      
    Qslz = GridInf(1)
    Sjhgd = GridInf(2)
    Sfxshjwg = GridInf(7)
    Szzls = CxbbGrid.Cols - 1
        
    '清除表头内容
    Lbl_TitleMess(0) = ""
    Lbl_TitleText(0) = ""

End Sub

Private Sub Form_Unload(Cancel As Integer)                                  '窗体卸载

    '卸载条件窗体
    Tjfx_DiffCond.UnloadCheck.Value = 1
    Unload Tjfx_DiffCond
    
    '卸载打印页面设置窗体
    Unload Dyymctbl

End Sub

Private Sub CxbbGrid_BeforeMoveColumn(ByVal Col As Long, Position As Long)           '网格列发生移动时自动交换网格索引信息
    Call FnBln_RefreshArray(Col, Position, GridStr(), GridInf())
End Sub

Private Sub GsToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)                '网格格式调整(Fixed)
  
    Select Case Button.Key
        Case "bcgs"                                          '保存表格格式
            Call Bcwggs(CxbbGrid, GridCode, GridStr())
        Case "hfmrgs"                                        '恢复默认格式
            Call Hfmrgs(CxbbGrid, GridCode, GridStr())
        Case "szxsxm"                                        '设置显示项目
            Call Szxsxm(CxbbGrid, GridCode)
    End Select

End Sub


Private Sub SzToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)
    
    Select Case Button.Key
        Case "ymsz"                                          '页面设置
            Dyymctbl.Show 1
        Case "yl"                                            '预 览
            Call bbyl(True)
        Case "dy"                                            '打 印
            Call bbyl(False)
        Case "cx"                                            '查 询
            Tjfx_DiffCond.Show 1
        Case "bz"                                            '帮 助
            Call F1bz
        Case "fh"                                            '退 出
           Unload Me
    End Select

End Sub

Private Sub Timer1_Timer()                                 '在窗体激活后调入查询程序
    
    Timer1.Enabled = False
    Xt_Wait.Show
    Xt_Wait.Refresh
   
    '加快显示速度
    CxbbGrid.Redraw = False

    '生成查询结果
    Call Sub_Query
   
    CxbbGrid.Redraw = True
    
    Xt_Wait.Hide

End Sub

Private Sub Sub_Query()                              '生成查询结果(Define)
    
    Dim Rec_Query As Recordset                  '查询结果动态集
    Dim Coljsq As Long                          '网格列计数器
    Dim Jsqte As Long                        '临时动态计数器
    Dim Str1 As String
    
    '以下为自定义部分[
 
    With Tjfx_DiffCond
     
        '生成查询条件
        Str_QueryCondi = " where " & .WhCode & " and  kjyear= " & Xtyear
        For Jsqte = 0 To 3
            Select Case Jsqte
                Case 0  '月份
                    Str_QueryCondi = Str_QueryCondi & " And a.period= '" & .Com_Mon.ItemData(.Com_Mon.ListIndex) & "'"
                Case 1  '存货分类(Like)
                    If Trim(.LrText(0).Text) <> "" Then
                        Str_QueryCondi = Str_QueryCondi & " And a.invsortcode like '" & Trim(.LrText(0).Tag) & "%'"
                    End If
                Case 2  '查询存货范围(起始)
                    If Trim(.LrText(1).Text) <> "" Then
                        Str_QueryCondi = Str_QueryCondi & " And a.mnumber>='" & Trim(.LrText(1).Text) & "'"
                    End If
                Case 3  '查询存货范围(终止)
                    If Trim(.LrText(2).Text) <> "" Then
                        Str_QueryCondi = Str_QueryCondi & " And a.mnumber<= '" & Trim(.LrText(2).Text) & "'"
                    End If
            End Select
        Next Jsqte
    End With
     
    '分摊类型
    Select Case Tjfx_DiffCond.Com_FtCond.ListIndex
        Case 0  '按仓库分摊
            SqlStr = "SELECT WhCode, WhName, SUM(OutQuan) AS SumQuan,  " & _
                    " SUM(OutMoney) AS SumMoney,SUM(mDiffMoney) AS SumDiff  " & _
                    " From Chhs_V_Diff a " & Trim(Str_QueryCondi) & _
                      "GROUP BY WhCode, WhName  Order By a.Whcode"
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("001", GridStr(), Szzls)) = "仓库编码 "
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("002", GridStr(), Szzls)) = "仓库名称 "
        Case 1  '按存货分摊
            SqlStr = "SELECT Mnumber, MName, SUM(OutQuan) AS SumQuan,  " & _
                    " SUM(OutMoney) AS SumMoney,SUM(mDiffMoney) AS SumDiff  " & _
                    " From Chhs_V_Diff a " & Trim(Str_QueryCondi) & _
                      "GROUP BY Mnumber, MName  Order By a.Mnumber"
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("001", GridStr(), Szzls)) = "存货编码 "
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("002", GridStr(), Szzls)) = "存货名称 "
        Case 2  '按部门分摊
            SqlStr = "SELECT DeptCode, DeptName, SUM(OutQuan) AS SumQuan,  " & _
                    " SUM(OutMoney) AS SumMoney,SUM(mDiffMoney) AS SumDiff  " & _
                    " From Chhs_V_Diff a " & Trim(Str_QueryCondi) & _
                      "GROUP BY DeptCode, DeptName Order By a.DeptCode"
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("001", GridStr(), Szzls)) = "部门编码 "
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("002", GridStr(), Szzls)) = "部门名称 "
        Case 3  '按出库类别分摊
            SqlStr = "SELECT InOutClassCode, InOutClassName, SUM(OutQuan) AS SumQuan,  " & _
                    " SUM(OutMoney) AS SumMoney,SUM(mDiffMoney) AS SumDiff  " & _
                    " From Chhs_V_Diff a " & Trim(Str_QueryCondi) & _
                      "GROUP BY InOutClassCode, InOutClassName Order By a.InOutClassCode"
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("001", GridStr(), Szzls)) = "出库类别编码 "
            CxbbGrid.TextMatrix(CxbbGrid.FixedRows - 1, Sydz("002", GridStr(), Szzls)) = "出库类别"
    End Select
    
    CxbbGrid.Rows = CxbbGrid.FixedRows
    
    Set Rec_Query = Cw_DataEnvi.DataConnect.Execute(SqlStr)
    With Rec_Query
        
        Do While Not .EOF
    
            CxbbGrid.AddItem ""
            Jsqte = CxbbGrid.Rows - 1
            '[>>自定义填充内容
            CxbbGrid.TextMatrix(Jsqte, Sydz("001", GridStr(), Szzls)) = Trim(.Fields(0) & "")
            CxbbGrid.TextMatrix(Jsqte, Sydz("002", GridStr(), Szzls)) = Trim(.Fields(1) & "")
            If .Fields("sumquan") <> 0 Then                                                                           '数量
                CxbbGrid.TextMatrix(Jsqte, Sydz("003", GridStr(), Szzls)) = .Fields("sumquan") + 0
            End If
            If .Fields("summoney") <> 0 Then                                                                      '计划单价
                CxbbGrid.TextMatrix(Jsqte, Sydz("004", GridStr(), Szzls)) = .Fields("summoney") + 0
            End If
            If .Fields("sumdiff") <> 0 Then                                                                      '计划金额
                CxbbGrid.TextMatrix(Jsqte, Sydz("005", GridStr(), Szzls)) = .Fields("sumdiff") + 0
            End If
            
            '<<]
            '设置数据行高度(Fixed)
            CxbbGrid.RowHeight(Jsqte) = Sjhgd
     
            '动态集指针加1,同时将计数器加1(Fixed)
            .MoveNext
            Jsqte = Jsqte + 1
        Loop
    End With
    
    
    '输入合计
    With CxbbGrid
        If .Rows = .FixedRows Then Exit Sub
        
        .SubtotalPosition = flexSTBelow
        For Jsqte = Qslz To .Cols - 1
             If GridBoolean(Jsqte, 4) Then
                  .Subtotal flexSTSum, -1, Jsqte, , &HF7F3EC, , , , , True
             End If
        Next
        Jsqte = .Rows - 1
        .RowHeight(Jsqte) = Sjhgd
        .TextMatrix(Jsqte, Sydz("001", GridStr(), Szzls)) = ""
        .TextMatrix(Jsqte, Sydz("002", GridStr(), Szzls)) = "合计 "
           
        For Coljsq = Qslz To .Cols - 1
            If Val(.TextMatrix(Jsqte, Coljsq)) = 0 And GridBoolean(Coljsq, 4) Then
                .TextMatrix(Jsqte, Coljsq) = ""
            End If
        Next
    End With
    
    ']以上为用户自定义部分
    
    Set Rec_Query = Nothing

End Sub

Private Sub bbyl(bbylte As Boolean)                    '报表打印预览
    
    Dim Bbzbt$, Bbxbt() As String, bbxbtzzxs() As Integer, Bbxbtgs As Integer
    Dim Bbbwh() As String, Bbbwhzzxs() As Integer, Bbbwhgs As Integer
    Bbxbtgs = 1                                          '报 表 小 标 题 行 数
    Bbbwhgs = 0                                          '报 表 表 尾 行 数
    ReDim Bbxbt(1 To Bbxbtgs)
    ReDim bbxbtzzxs(1 To Bbxbtgs)
    If Bbbwhgs <> 0 Then
        ReDim Bbbwh(1 To Bbbwhgs)
        ReDim Bbbwhzzxs(1 To Bbbwhgs)
    End If
    Bbzbt = Lab_Title(0)
    Bbxbt(1) = Fun_FormatOutPut("月份:" + Trim(Lbl_TitleText(0)), 50)
    Bbxbt(1) = Bbxbt(1) + Fun_FormatOutPut(Trim(Lbl_TitleMess(0)), 30)
    bbxbtzzxs(1) = 0                                     '报表行组织形式(0-居左 1-居中 2-居右)
    Call Scyxsjb(CxbbGrid)                               '生成报表数据
    Call Scdybb(Dyymctbl, Bbzbt, Bbxbt(), bbxbtzzxs(), Bbxbtgs, Bbbwh(), Bbbwhzzxs(), Bbbwhgs, bbylte)
    If Not bbylte Then
        Unload DY_Tybbyldy
    End If

End Sub