i-

VB开发的ERP系统

            EndProperty
            BeginProperty Button2 {66833FEA-8583-11D1-B16A-00C0F0283628} 
               Caption         =   "默认列宽"
               Key             =   "hfmrgs"
               ImageKey        =   "mrlk"
            EndProperty
         EndProperty
      End
   End
End
Attribute VB_Name = "ZB_Frmkmmxzjg"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'*************************************************************************
'*    模 块 名 称 :科目明细帐
'*    功 能 描 述 :本功能用于查询某科目在某月或某几月的明细帐情况
'*                 并且能够进行立体联查凭证及总帐数据。
'*    程序员姓名  : 张建忠
'*    最后修改人  : 奚俊峰
'*    最后修改时间:2001-12-23
'*    备        注:查询科目明细帐时应从建帐启用月份查询，否则本年累计数据
'*                 有问题,有的软件控制不能小于启用月份查询.
'************************************************************************
Dim ReportTitle As String                '报表主标题
Dim Bln_ClassSum As Boolean              '是否进行科目类别合计
Dim Bln_ConVertFlag As Boolean           '外币折算方式
Dim Int_Wbhlxsws As Integer              '外币汇率小数位数
Dim Bln_CancelPrint As Boolean           '用户是否取消打印
Dim Bln_Printing As Boolean              '用户是否正在打印

'以下为固定使用变量
Dim Dyymctbl As New DY_Dyymsz            '打印页面窗体变量
Dim GridCode As String                   '显示网格网格代码
Dim GridInf() As Variant                 '整个网格设置信息
Dim Tsxx As String                       '系统提示信息
Dim Qslz As Long                         '网格隐藏(非操作显示)列数
Dim Sjhgd As Double                      '网格数据行高度
Dim Sfxshjwg As Boolean                  '是否显示合计网格
Dim GridBoolean() As Boolean             '网格列信息(布尔型)
Dim GridStr()  As String                 '网格列信息(字符型)
Dim GridInt() As Integer                 '网格列信息(整型)
Dim Szzls As Integer                     '数组总列数(网格列数-1)
Dim Bln_Stop As Boolean                  '停止输出查询结果

Private Sub Form_Activate()
    Me.HelpContextID = "0116003"
End Sub

Private Sub Form_Resize()                '根据窗体大小来调整网格,标题栏大小
    On Error Resume Next
    With CxbbGrid
        .Width = Me.Width - 160
        .Height = Me.Height - .Top - 400
    End With
    With Pic_Title
        .Width = Me.Width - 160
    End With
    
    GsToolbar.Left = Me.Width - GsToolbar.Width - 140
End Sub

Private Sub Form_Load()                                                   '窗体装入
    Me.HelpContextID = "0116003"
    
    '调入打印页面设置窗体
    XtReportCode = "Cwzz_mxzcx"
    Load Dyymctbl
    ReportTitle = "明  细  帐"
    
    '调整标题栏及网格、格式工具条位置
    Pic_Title.Left = 40
    Pic_Title.Top = SzToolbar.Top + SzToolbar.Height - 10
    CxbbGrid.Left = Pic_Title.Left
    CxbbGrid.Top = Pic_Title.Top + Pic_Title.Height + 20
    
    '调 入 网 格
    GridCode = "Cwzz_mxzcx"
    Call BzWgcsh(CxbbGrid, GridCode, GridInf(), GridBoolean(), GridInt(), GridStr())
    
    Qslz = GridInf(1)
    Sjhgd = GridInf(2)
    Sfxshjwg = GridInf(7)
    Szzls = CxbbGrid.Cols - 1
    
    '帐页格式
    Call FillCombo(Combo_AccFormat, "Cwzz_zygs", "", 0)
    
    '调整标题位置
    SetTitlePos tsLabel(4)
    
End Sub

Private Sub Form_Unload(Cancel As Integer)                                  '窗体卸载
    '如果用户正在连续打印帐页,则不能关闭窗体
    If Bln_Printing Then
        Cancel = 1
    End If
    '卸载条件窗体
    ZB_Frmkmmxztj.UnloadCheck.Value = 1
    Unload ZB_Frmkmmxztj
    '卸载打印页面设置窗体
    Unload Dyymctbl
End Sub

Private Sub GsToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)       '网格格式调整
    Select Case Button.Key
    Case "bcgs"                                          '保存表格格式
        Call Bcwggs(CxbbGrid, GridCode, GridStr)
    Case "hfmrgs"                                        '恢复默认格式
        Call Hfmrgs(CxbbGrid, GridCode, GridStr)
    Case "szxsxm"                                        '设置显示项目
        Call Szxsxm(CxbbGrid, GridCode)
    End Select
End Sub

Private Sub SzToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)
    '如果用户正在连续打印帐页,则不能执行其他功能
    If Bln_Printing Then
        Exit Sub
    End If
    
    Select Case Button.Key
    Case "ymsz"                                          '页面设置
        Dyymctbl.Show 1
    Case "yl"                                            '预 览
        Call bbyl(True)
    Case "dy"                                            '打 印
        Call bbyl(False)
    Case "lxdy"                                          '连 打
        Call Sub_Lxdy
    Case "cx"                                            '查 询
        If Trim(Combo_QueryCcode.Text) <> "" Then
            ZB_Frmkmmxztj.LrText(0).Text = Trim(Mid(Combo_QueryCcode.Text, 1, InStr(1, Combo_QueryCcode.Text, " ") - 1))
        End If
        ZB_Frmkmmxztj.Show 1
    Case "pz"                                            '凭 证
        Call CxbbGrid_DblClick
    Case "zz"                                            '总 帐
        Call Sub_LcZflz
    Case "bz"                                            '帮 助
        Call F1bz
    Case "fh"                                            '退 出
        Unload Me
    End Select
End Sub

Private Sub Timer1_Timer()                                 '在窗体激活后调入查询程序
    Dim RecTemp As New ADODB.Recordset          '临时使用动态集
    Dim Str_QueryCondi As String                '用户录入查询条件
    
    Timer1.Enabled = False
    
    With ZB_Frmkmmxztj
        
        Str_QueryCondi = " where 1=1 "
        
        Str_QueryCondi = Str_QueryCondi & " and CCode>='" & Trim(.LrText(0).Text) & "'"
        
        If Trim(.LrText(1).Text) <> "" Then
            Str_QueryCondi = Str_QueryCondi & " and CCode<='" & Trim(.LrText(1).Text) & "'"
        End If
        
        
        '判断是否仅限于末级科目查询
        If .Chk_EndFlag.Value = 1 Then
            Str_QueryCondi = Str_QueryCondi & " and EndFlag='1'"
        End If
        
    End With
    
    '根据查询科目范围填充科目列表框
    Sqlstr = "SELECT Ccode,Cname From Cwzz_AccCode" & Str_QueryCondi & " Order By Ccode"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    
    Combo_QueryCcode.Clear
    Do While Not RecTemp.EOF
        Combo_QueryCcode.AddItem Trim(RecTemp.Fields("Ccode")) + " " + Trim(RecTemp.Fields("Cname") & "")
        RecTemp.MoveNext
    Loop
    
    If Combo_QueryCcode.ListCount <> 0 Then
        Combo_QueryCcode.Text = Combo_QueryCcode.List(0)
    End If
    Lab_TitleText(0).Caption = ZB_Frmkmmxztj.Combo_Kjqj(0).Text & "—" & ZB_Frmkmmxztj.Combo_Kjqj(1).Text
End Sub

Private Sub Combo_QueryCcode_Click()                                      '用户点击科目列表框
    Timer1.Enabled = False
    Xt_Wait.Show
    Xt_Wait.Refresh
    
    '加快显示速度
    CxbbGrid.Redraw = False
    
    '生成查询结果
    Call Sub_Query
    
    CxbbGrid.Redraw = True
    
    Xt_Wait.Hide
End Sub

Private Sub Sub_Query()                                    '生成查询结果
    Dim RecTemp As New ADODB.Recordset          '临时使用动态集
    Dim Sqlstr As String                        '查询字符串
    Dim Coljsq As Long                          '网格列计数器
    Dim Jsqte As Long                           '临时动态计数器
    Dim Str_Ccode As String                     '查询会计科目
    Dim Int_BPeriod As Integer                  '查询起始会计期间
    Dim Int_EPeriod As Integer                  '查询终止会计期间
    Dim Int_Year As Integer                     '查询会计年度
    Dim Bln_IncluNotBook As Boolean             '是否包含未记帐凭证
    Dim Bln_QcZeroShow As Boolean               '查询会计期间期初数据如果为零是否显示
    Dim Bln_CqGcShow As Boolean                 '是否显示承前过次
    Dim Int_Zdzyhs As Integer                   '正式帐页指定报表行数
    Dim Bln_EndFlag As Boolean                  '判断当前科目是否为末级科目
    Dim Int_DqPeriod As Integer                 '查询进行当前会计期间
    Dim Bln_NotFirst As Boolean                 '是否为首次循环
    Dim Bln_ForeignFlag As Boolean              '判断此科目是否外币核算
    Dim Lng_MonthCount As Long                  '本月明细帐记录条数
    Dim Lng_YearCount As Long                   '本年明细帐记录条数
    
    Dim Dbl_Qcyete#, Dbl_Qcslte#, Dbl_Qcwbte#   '期初金额,数量,外币
    Dim Dbl_Jejfhj#, Dbl_Jedfhj#, Dbl_Sljfhj#, Dbl_Sldfhj#, Dbl_Wbjfhj#, Dbl_Wbdfhj# '本期合计(金额,数量,外币)
    Dim Dbl_Jejflj#, Dbl_Jedflj#, Dbl_Sljflj#, Dbl_Sldflj#, Dbl_Wbjflj#, Dbl_Wbdflj# '截止累计(金额,数量,外币)
    Dim Dbl_Qmyete#, Dbl_Qmslte#, Dbl_Qmwbte#   '期末金额,数量,外币
    '以下为用户自定义部分[
    
    '清除原查询数据
    CxbbGrid.Rows = CxbbGrid.FixedRows
    
    '得到当前查询科目,并判断是否为末级科目
    Str_Ccode = Trim(Mid(Combo_QueryCcode.Text, 1, InStr(1, Combo_QueryCcode.Text, " ") - 1))
    Sqlstr = "SELECT EndFlag,AccFormat,ForeignFlag,ForeignCurrName,IDec,ConVertFlag From Cwzz_AccCode Left JOIN Gy_ForeignCurrency ON" & _
    " Cwzz_AccCode.ForeignCurrCode = Gy_ForeignCurrency.ForeignCurrCode Where Ccode='" & Str_Ccode & "'"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    If Not RecTemp.EOF Then
        Bln_EndFlag = RecTemp.Fields("EndFlag")
        Combo_AccFormat.Text = Trim(RecTemp.Fields("AccFormat") & "")
        If RecTemp.Fields("ForeignFlag") Then
            Lab_TitleMess(2).Visible = True
            Lab_TitleText(1).Caption = Trim(RecTemp.Fields("ForeignCurrName") & "")
            Bln_ForeignFlag = True
            Bln_ConVertFlag = IIf(IsNull(RecTemp.Fields("ConVertFlag")), False, RecTemp.Fields("ConVertFlag"))
            Int_Wbhlxsws = IIf(IsNull(RecTemp.Fields("IDec")), 0, RecTemp.Fields("IDec"))
        Else
            Bln_ForeignFlag = False
            Lab_TitleMess(2).Visible = True
            Lab_TitleText(1).Caption = ""
        End If
    End If
    
    '得到查询起始和截止会计期间,并判断是否包含未记帐凭证
    With ZB_Frmkmmxztj
        Int_Year = Int(Mid(.Combo_Kjqj(0).Text, 1, 4))
        Int_BPeriod = Int(Mid(.Combo_Kjqj(0).Text, 6, 2))
        Int_EPeriod = Int(Mid(.Combo_Kjqj(1).Text, 6, 2))
        
        '是否包含未记帐凭证
        If .Chk_NotBook.Value = 1 Then
            Bln_IncluNotBook = True
        Else
            Bln_IncluNotBook = False
        End If
        
        '查询会计期间期初数据如果为零是否显示
        If .Chk_QcZeroShow = 1 Then
            Bln_QcZeroShow = True
        Else
            Bln_QcZeroShow = False
        End If
        
        '是否显示承前过次,如显示则将页面设置指定行数控制为>1且必须指定报表行数打印输出
        If .Chk_CqGcShow = 1 Then
            Bln_CqGcShow = True
            Dyymctbl.ZdhsCheck.Enabled = False
            Dyymctbl.ZdhsCheck.Value = 1
            Dyymctbl.BbhsText.Enabled = False