-i+

VB开发的ERP系统

    '设置操作状态为修改
    Lab_OperStatus.Caption = "3"
    
    '设置工具条状态
    Call Sub_OperStatus("30")
    
    '显示制单人
    LrText(13).Text = Xtczy
    
End Sub

Private Sub Sub_DeleteBill()                                               '删除当前单据
    
    Dim YAnswer As Integer               '确认是否删除当前单据
    Dim jsqte As Long                    '临时使用计数器
    
    '判断用户是否有此功能执行权限,如有则写上机日志(进入)
    If Not Security_Log("Ar_GatheringBill_Edit", Xtczybm, 1, True) Then
        Exit Sub
    End If
    
    '非有效单据不予进行删除动作
    If Val(Lab_BillId.Caption) = 0 Then
        Exit Sub
    End If
    
    Tsxx = "请确认是否删除当前单据?"
    YAnswer = Xtxxts(Tsxx, 2, 2)
    
    If YAnswer = 1 Then
        
        '判断当前单据是否允许删除
        If Not Fun_AllowEdit Then
            Exit Sub
        End If
        
        '进行事务处理
        On Error GoTo Swcwcl
        Cw_DataEnvi.DataConnect.BeginTrans
        
        '1.删除单据所有内容
        Cw_DataEnvi.DataConnect.Execute ("Delete RP_CloseBill Where CloseBillID=" & Val(Lab_BillId.Caption))
        Cw_DataEnvi.DataConnect.CommitTrans
        
        '标识单据发生改动
        Bln_BillChange = True
        
        '单据ID置0
        Lab_BillId.Caption = 0
    Else
        Exit Sub
    End If
    
    '删除单据后重置状态
    
    '1.显示下一张单据
    Call Sub_next
    
    '2.如果无下一张单据则搜索上一张单据
    If Val(Lab_BillId.Caption) = 0 Then
        Call Sub_Prev
    End If
    
    '3.如无单据则置单据为空状态
    If Val(Lab_BillId.Caption) = 0 Then
        '清除录入文本框
        For jsqte = Max_Text_Index To 0 Step -1
            LrText(jsqte).Tag = ""
            LrText(jsqte).Text = ""
        Next jsqte
        
        '设置操作状态为浏览
        Lab_OperStatus = "1"
        Call Sub_OperStatus("10")
    End If
    
    Rec_Query.Requery
    Rec_Query.Find "CloseBillID=" & Val(Lab_BillId.Caption)
    Exit Sub
Swcwcl:          '单据删除时出现错误
    Cw_DataEnvi.DataConnect.RollbackTrans
    Tsxx = "单据删除过程中出现未知错误,程序自动恢复保存前状态!"
    Call Xtxxts(Tsxx, 0, 1)
    Exit Sub
End Sub

Private Sub Sub_AbandonBill()                                              '放弃对当前单据的操作
    
    Dim jsqte As Long                    '临时使用计数器
    
    '如果单据有效则重新显示当前单据,置单据为空状态
    If Not Rec_Query.EOF Then
        Lab_BillId.Caption = Rec_Query.Fields("CloseBillID")
        Call Sub_ShowBill
    Else
        '单据ID置为0
        Lab_BillId.Caption = 0
        
        '清除录入文本框
        For jsqte = Max_Text_Index To 0 Step -1
            LrText(jsqte).Tag = ""
            LrText(jsqte).Text = ""
        Next jsqte
    End If
    
    '设置操作状态为浏览
    Lab_OperStatus = "1"
    Call Sub_OperStatus("10")
    
End Sub

Private Function Sub_SaveBill() As Boolean                                   '保 存 单 据
    
    Dim RecTemp As New ADODB.Recordset                    '临时使用动态集
    Dim Rec_Bill As New ADODB.Recordset                   '单据表动态集
    Dim jsqte As Integer                                  '临时计数器
    
    Dim Int_Kjyear As Integer                             '会计年度
    Dim Int_Period As Integer                             '会计期间
    Dim Bln_ConVertFlag As Boolean                        '币种折算方式
    Dim Dbl_AccRate As Double                             '币种记帐汇率
    Dim Dbl_Bbje As Double                                '本币金额
    Dim Int_Modulus As Integer                            '金额系数(针对退款单)
    
    Sub_SaveBill = False
    
    '一.============先对单据内容进行有效性判断==============='
    
    '先进行字段不能为空或不能为零有效性判断(Fixed)
    For jsqte = 0 To Max_Text_Index
        If Textint(jsqte, 8) = 1 Then     '字段不能为空
            If Len(Trim(LrText(jsqte).Text)) = 0 Then
                Tsxx = Textstr(jsqte, 7) & "不能为空!"
                Call Xtxxts(Tsxx, 0, 1)
                LrText(jsqte).SetFocus
                Exit Function
            End If
        Else
            If Textint(jsqte, 8) = 2 Then   '字段不能为零
                If Val(Trim(LrText(jsqte).Text)) = 0 Then
                    Tsxx = Textstr(jsqte, 7) & "不能为零!"
                    Call Xtxxts(Tsxx, 0, 1)
                    LrText(jsqte).SetFocus
                    Exit Function
                End If
            End If
        End If
    Next jsqte
    
    '对需要进行事后判断的文本框录入内容进行有效性判断 (Fixed)
    For jsqte = 0 To Max_Text_Index
        If Textint(jsqte, 9) = 0 Or Textint(jsqte, 9) = 2 Then
            If Not TextYxxpd(jsqte) Then
                Exit Function
            End If
        End If
    Next jsqte
    
    '[>>
    
    '可在此区域写入其他对单据表头内容的有效性判断,具体格式参照如下
    
    '1.判断单据日期是否有效,如有效同时记录会计年度和会计期间
    If Not Fun_GetPeriod(Trim(LrText(1).Text), Int_Kjyear, Int_Period) Then
        LrText(1).SetFocus
        Exit Function
    End If
    
     '2.如果用户选择币种为本位币则汇率必须为1，否则汇率不能为零
    If Trim(LrText(5).Tag) <> XtSCurrCode Then
       If Val(LrText(6).Text) = 0 Then
          Tsxx = "汇率不能为零!"
          Call Xtxxts(Tsxx, 0, 1)
          LrText(6).SetFocus
          Exit Function
       End If
    Else
       LrText(6).Text = 1
    End If
    
    '计算本币金额
    Call Sub_GetAccRate(LrText(5).Tag, Bln_ConVertFlag, Dbl_AccRate)
    
    If Bln_ConVertFlag Then
       Dbl_Bbje = Val(Format(Val(LrText(7).Text) / Val(LrText(6).Text), "##." + String(Xtjexsws, "0")))
    Else
       Dbl_Bbje = Val(Format(Val(LrText(7).Text) * Val(LrText(6).Text), "##." + String(Xtjexsws, "0")))
    End If
    
    '<<]
    
    '二.=============如果以上有效性检查均顺利通过,则执行存盘动作============'
    
    '对存盘进行事务处理(Fixed)
    On Error GoTo Swcwcl
    Cw_DataEnvi.DataConnect.BeginTrans
    
    '判断单据状态以进行不同处理
    
    '1.先对单据主表进行处理
    If Trim(Lab_OperStatus) = "2" Then
        '新增单据
        
        '1.对于某些单据号自动生成的单据则可在此处自动生成
        LrText(0).Text = CreatBillCode(BillCode, True)
        
        '2.开始存盘
        
        '打开单据表动态集
        If Rec_Bill.State = 1 Then Rec_Bill.Close
        Rec_Bill.Open "Select * From RP_CloseBill Where 1=2", Cw_DataEnvi.DataConnect, adOpenDynamic, adLockOptimistic
        With Rec_Bill
            .AddNew
            .Fields("RPFlag") = "AR"                                                                     '应收帐标识
            .Fields("CloseBillId") = CreatBillID(BillCode)                                               '单据ID
             Select Case Combo_Skdlx.ListIndex                                                           '结算单类型
               Case 0      '到款
                 Int_Modulus = 1
                 .Fields("BillItemCode") = "30"
               Case 1      '预收款
                 Int_Modulus = 1
                 .Fields("BillItemCode") = "31"
               Case 2      '退款单
                 Int_Modulus = -1
                 .Fields("BillItemCode") = "32"
             End Select
            .Fields("BillCode") = Trim(LrText(0).Text)                                                   '单据号
            .Fields("BillDate") = CDate(LrText(1).Text)                                                  '单据日期
            .Fields("Kjyear") = Int_Kjyear                                                               '会计年度
            .Fields("Period") = Int_Period                                                               '会计期间
            .Fields("PSCode") = Trim(LrText(2).Tag)                                                      '客户编码
            .Fields("SScode") = Trim(LrText(3).Tag)                                                      '结算方式
            .Fields("AccCode") = Trim(LrText(4).Text)                                                    '结算科目
            If Combo_Skdlx.ListIndex = 1 Then
                .Fields("AccCodeArAp") = Fun_InputCodeCustomer(LrText(2).Tag, 1)                         '预收帐款科目
            Else
                .Fields("AccCodeArAp") = Fun_InputCodeCustomer(LrText(2).Tag, 0)                         '应收帐款科目
            End If
            .Fields("ForeignCurrCode") = Trim(LrText(5).Tag)                                             '原币编码
            .Fields("AccRate") = Val(LrText(6).Text)                                                     '记帐汇率
            .Fields("YbSsJe") = Val(LrText(7).Text) * Int_Modulus                                        '原币金额
            .Fields("BbSsje") = Dbl_Bbje * Int_Modulus                                                   '本币金额
            .Fields("BankBillNo") = Trim(LrText(8).Text)                                                 '银行票号
            .Fields("BankCode") = Trim(LrText(9).Tag)                                                    '银行帐号
            .Fields("DeptCode") = Trim(LrText(10).Tag)                                                   '部门
            .Fields("PersonCode") = Trim(LrText(11).Tag)                                                 '经办人
            .Fields("Digest") = Trim(LrText(12).Text)                                                    '摘要
            .Fields("Maker") = Trim(LrText(13).Text)                                                     '制单人
            .Update
            
            '系统读出单据ID写入Lab_BillID
            Lab_BillId.Caption = .Fields("CloseBillID")
        End With
    Else
        '修改单据
        
        '打开单据表动态集
        If Rec_Bill.State = 1 Then Rec_Bill.Close
        Rec_Bill.Open "Select * From RP_CloseBill  Where CloseBillID=" & Val(Lab_BillId.Caption), Cw_DataEnvi.DataConnect, adOpenDynamic, adLockOptimistic
        With Rec_Bill
            .Fields("BillDate") = CDate(LrText(1).Text)                                                  '单据日期
            .Fields("Kjyear") = Int_Kjyear                                                               '会计年度
            .Fields("Period") = Int_Period                                                               '会计期间
            Select Case Combo_Skdlx.ListIndex                                                           '结算单类型
               Case 0      '到款
                 Int_Modulus = 1
                 .Fields("BillItemCode") = "30"
               Case 1      '预收款
                 Int_Modulus = 1
                 .Fields("BillItemCode") = "31"
               Case 2      '退款单
                 Int_Modulus = -1
                 .Fields("BillItemCode") = "32"
             End Select
            .Fields("PSCode") = Trim(LrText(2).Tag)                                                      '客户编码
            .Fields("SScode") = Trim(LrText(3).Tag)                                                      '结算方式
            .Fields("AccCode") = Trim(LrText(4).Text)                                                    '结算科目
            If Combo_Skdlx.ListIndex = 1 Then
                .Fields("AccCodeArAp") = Fun_InputCodeCustomer(LrText(2).Tag, 1)                         '预收帐款科目
            Else
                .Fields("AccCodeArAp") = Fun_InputCodeCustomer(LrText(2).Tag, 0)                         '应收帐款科目
            End If
            .Fields("ForeignCurrCode") = Trim(LrText(5).Tag)                                             '原币编码
            .Fields("AccRate") = Val(LrText(6).Text)                                                     '记帐汇率
            .Fields("YbSsJe") = Val(LrText(7).Text) * Int_Modulus                                        '原币金额
            .Fields("BbSsje") = Dbl_Bbje * Int_Modulus                                                   '本币金额
            .Fields("BankBillNo") = Trim(LrText(8).Text)                                                 '银行票号
            .Fields("BankCode") = Trim(LrText(9).Tag)                                                    '银行帐号
            .Fields("DeptCode") = Trim(LrText(10).Tag)                                                   '部门
            .Fields("PersonCode") = Trim(LrText(11).Tag)                                                 '经办人
            .Fields("Digest") = Trim(LrText(12).Text)                                                    '摘要
            .Fields("Maker") = Trim(LrText(13).Text)                                                     '制单人
            .Update
        End With
    End If
    
    Cw_DataEnvi.DataConnect.CommitTrans
    
    Sub_SaveBill = True
    Tsxx = "单据存盘完毕! 单据号:" & Trim(LrText(0).Text)
    Call Xtxxts(Tsxx, 0, 4)
    
    '标识单据发生改动
    Bln_BillChange = True
    
    '设置单据改变后的状态
    Lab_OperStatus = "1"
    Call Sub_OperStatus("10")
    Rec_Query.Requery
    Rec_Query.Find "CloseBillID=" & Val(Lab_BillId.Caption)
    Exit Function
Swcwcl:       '数据存盘时出现错误
    Cw_DataEnvi.DataConnect.RollbackTrans
    Tsxx = "存盘过程中出现未知错误,程序自动恢复保存前状态!"
    Call Xtxxts(Tsxx, 0, 1)
    Exit Function
    
End Function

'选择首张,上张,下张,末张(此4个过程只需用您的单据ID字段名替换"CloseBillID"即可)
Private Sub Sub_First()             '首 张
    
    With Rec_Query
        If .RecordCount = 0 Then
            Exit Sub
        End If
        .MoveFirst