+

VB开发的ERP系统

   End
End
Attribute VB_Name = "JC_FrmCuseAcc"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'**************************************************************************************
'*    模 块 名 称 :客户科目设置
'*    功 能 描 述 :用来设置客户对应总帐中记帐会计科目
'*    程序员姓名  :张建忠
'*    最后修改人  :张建忠
'*    最后修改时间:2001/12/04
'*    备        注:程序中所有依实际情况自定义部分均用[>> <<]括起
'*
'*    1.每次调入外部功能窗体，均要加锁ChangeLock=True,窗体关闭后解锁ChangeLock=false
'*
'*    3.Lab_OperStatus 用此标签来标识单据录入状态(默认值为1) 1-浏览 2-修改
'*
'***************************************************************************************
 
'以下为自定义变量
 
'其它固定使用变量
Dim Tsxx As String                              '系统信息提示(Fixed)
Dim ReportTitle As String                       '报表主标题(Fixed)
   
'以下为固定使用变量(网格)
Dim Cxnrrec As New ADODB.Recordset              '显示查询内容动态集
Dim Dyymctbl As New DY_Dyymsz                   '打印页面窗体变量
Dim GridCode As String                          '显示网格网格代码
Dim GridInf() As Variant                        '整个网格设置信息
Dim Pmbcsjhs As Long                            '屏幕网格保持数据行数(大于等于1)
Dim Fzxwghs As Integer                          '辅助项网格行数(包括合计行)
Dim Sfxshjwg As Boolean                         '是否显示合计网格
Dim Qslz As Long                                '网格隐藏(非操作显示)列数
Dim Sjhgd As Double                             '网格数据行高度
Dim GridBoolean() As Boolean                    '网格列信息(布尔型)
Dim GridStr()  As String                        '网格列信息(字符型)
Dim GridInt() As Integer                        '网格列信息(整型)
Dim Sfblbzkd As Boolean                         '是否保留帮助宽度(字段提供帮助时,是否为按钮保留空间)
Dim Dqlrwgh As Long                             '当前录入数据网格行
Dim Dqlrwgl As Long                             '当前录入数据网格列
Dim Dqlkwgh As Long                             '刚刚离开网格行(不一定为录入行)
Dim Dqlkwgl As Long                             '刚刚离开网格列
Dim Dqtoprow As Long                            '当前录入状态时最上端可视行
Dim Dqleftcol As Long                           '当前录入状态时最左端可视列
Dim Zdlrqnr As String                           '字段录入修改前内容(用来判断内容是否修改)
Dim Wbkbhlock As Boolean                        '文本框改变值锁
Dim changelock As Boolean                       '网格行列改变控制锁(用来区别用户改变.程序改变)
Dim Gdtlock As Boolean                          '滚动条滚动控制(用来区别用户改变.程序改变)
Dim Yxxpdlock As Boolean                        '字段有效性判断锁(内容不修改不需进行字段有效性判断)
Dim Hyxxpdlock As Boolean                       '行有效性判断锁(字段内容不修改不需进行行有效性判断)
Dim Valilock As Boolean                         '文本框失去焦点是否进行有效性控制(TRUE 为锁定*限用网格录入)
Dim Shsfts As Boolean                           '删除记录行是否提示
Dim Szzls As Integer                            '网格信息数组最大下标值(网格列数-1)

Private Sub Form_KeyPress(KeyAscii As Integer)      '限制录入字符"'"
    
    Select Case KeyAscii
    Case 39           '屏蔽字符"'"
        KeyAscii = 0
    End Select
    
End Sub

Private Sub Form_Load()                              '窗 体 装 入
    
    '初始化各种锁值(Fixed)
    changelock = False             '网格行列改变控制锁
    Gdtlock = False                '滚动条滚动控制
    Yxxpdlock = True               '字段有效性判断锁
    Hyxxpdlock = True              '行有效性判断锁
    Wbkbhlock = False              '文本框内容改变锁
    
    '报表主标题及报表编码(Fixed)
    ReportTitle = "客户科目设置"
    XtReportCode = "Ar_CuseAcc"
    Load Dyymctbl
    
    '调 入 网 格(Fixed)
    GridCode = "Ar_CuseAcc"      '网格属性编码
    Call BzWgcsh(WglrGrid, GridCode, GridInf(), GridBoolean(), GridInt(), GridStr())
    
    Qslz = GridInf(1)
    Sjhgd = GridInf(2)
    Pmbcsjhs = GridInf(3)
    Fzxwghs = GridInf(4)
    Sfblbzkd = GridInf(5)
    Shsfts = GridInf(6)
    Sfxshjwg = GridInf(7)
    Szzls = WglrGrid.Cols - 1
    
    '设置标题栏宽度、网格宽度高度(Fixed)
    Pic_Title.Move 50, Pic_Title.Top, Me.Width - 150, Pic_Title.Height
    WglrGrid.Move 50, Pic_Title.Top + Pic_Title.Height, Me.Width - 150
    WglrGrid.Height = Me.Height - WglrGrid.Top - 380
    
    '生成查询结果
    Call Sub_Query
    
    '设置状态为修改状态
    Lab_OperStatus = "2"
    
End Sub

Private Sub Form_Unload(Cancel As Integer)           '窗体卸载
    If Not Fun_Drfrmyxxpd Then
        Cancel = True
        Exit Sub
    End If
    
    '卸载打印页面窗体
    Unload Dyymctbl
    
End Sub

Private Sub Sub_Query()                              '生成查询结果
    
    Dim Sqlstr As String                           '临时使用字符串
    Dim RecTemp As New ADODB.Recordset             '临时使用动态集
    Dim jsqte As Long                              '临时计数器
    
    '禁止网格刷新动作,为加快网格显示速度(Fixed)
    WglrGrid.Redraw = False
    
    '本张单据查询字符串
    Sqlstr = "SELECT CusCode, CusName, ARAccCode, PRAccCode FROM Gy_Customer ORDER BY CusCode"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    
    With RecTemp
        
        WglrGrid.Rows = WglrGrid.FixedRows
        
        If .EOF Then
            WglrGrid.Redraw = True
            Exit Sub
        End If
        
        jsqte = WglrGrid.FixedRows
        
        Do While Not .EOF
            WglrGrid.AddItem ""
            
            '[>>显示查询内容
            WglrGrid.TextMatrix(jsqte, Sydz("001", GridStr(), Szzls)) = Trim(.Fields("CusCode") & "")       '客户编码
            WglrGrid.TextMatrix(jsqte, Sydz("002", GridStr(), Szzls)) = Trim(.Fields("CusName") & "")       '客户名称
            WglrGrid.TextMatrix(jsqte, Sydz("003", GridStr(), Szzls)) = Trim(.Fields("ARAccCode") & "")       '应收科目
            WglrGrid.TextMatrix(jsqte, Sydz("004", GridStr(), Szzls)) = Trim(.Fields("PRAccCode") & "")       '预收科目
            '<<]
            
            WglrGrid.RowHeight(jsqte) = Sjhgd
            .MoveNext
            jsqte = jsqte + 1
        Loop
        
    End With
    
    '将网格刷新解禁(Fixed)
    WglrGrid.Redraw = True
    
End Sub

Private Sub Tlb_Action_ButtonClick(ByVal Button As MSComctlLib.Button)             '用户点击工具条
    
    '屏蔽文本框,下拉组合框有效性判断
    
    Valilock = True
    
    '屏蔽网格失去焦点产生的有效性判断
    
    changelock = True
    
    Select Case Button.Key
    Case "ymsz"                                          '页面设置
        Dyymctbl.Show 1
    Case "yl"                                            '预 览
        If Fun_Drfrmyxxpd Then
            Call bbyl(True)
        End If
    Case "dy"                                            '打 印
        If Fun_Drfrmyxxpd Then
            Call bbyl(False)
        End If
    Case "pl"
        '判断用户是否有此功能执行权限,如有则写上机日志(进入)
        If Not Security_Log("Ar_CuseAcc_Edit", Xtczybm, 1, True) Then
            Exit Sub
        End If
        JC_FrmCuseAccPl.Show 1
        
        '重新刷新查询结果
        Call Sub_Query
    Case "bz"                                            '帮 助
        Call F1bz
    Case "fh"                                            '退 出
        Unload Me
        
    End Select
    
    '解 锁
    Valilock = False
    changelock = False
    
End Sub

Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)        '支持热键操作
    
    If Shift = 2 Then
        Select Case UCase(Chr(KeyCode))
        Case "P"                   'Ctrl+P 打印
            If Tlb_Action.Buttons("dy").Enabled Then
                Call bbyl(False)
            End If
        End Select
    End If
    
End Sub

Private Sub Wbkcl()                                                 '文本框录入之前处理(根据实际情况)
    
    Dim xswbrr As String
    
    With WglrGrid
        Zdlrqnr = Trim(.Text)
        xswbrr = Trim(.Text)
        
        If GridBoolean(.Col, 3) Then   '列表框录入
            
            '填充列表框程序
            Call FillCombo(YdCombo, GridStr(.Col, 5), xswbrr, 0)
        Else
            Wbkbhlock = True
            
            '====以下为用户自定义
            Ydtext.Text = xswbrr
            '====以上为用户自定义
            
            Wbkbhlock = False
            Ydtext.SelStart = Len(Ydtext.Text)
        End If
    End With
    
End Sub

Private Function sjzdyxxpd(Dqpdwgh As Long, Dqpdwgl As Long)        '录入数据字段有效性判断,同时进行字段录入事后处理
    
    Dim Str_JudgeText As String            '临时有效性判断字段内容
    Dim Coljsq As Long                     '临时列计数器
    Dim RecTemp As New ADODB.Recordset     '临时使用动态集
    Dim Dbl_Qcye As Double                 '临时期初余额
    
    With WglrGrid
        
        '非录入状态有效性为合法
        If Yxxpdlock Or .Row < .FixedRows Then
            sjzdyxxpd = True
            Exit Function
        End If
        
        Str_JudgeText = Trim(.TextMatrix(Dqpdwgh, Dqpdwgl))
        Select Case GridStr(Dqpdwgl, 1)
            
            '以下为自定义部分[
            '1.放置字段有效性判断程序
        Case "003", "004"  '会计科目
            
            If Len(Str_JudgeText) <> 0 Then
                Sqlstr = "Select Ccode,EndFlag,CusFlag,StopFlag FROM  Cwzz_AccCode  Where Ccode='" & Str_JudgeText & "'"
                Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
                With RecTemp
                    If .EOF Then
                        Tsxx = "此科目不存在!"
                        GoTo Lrcwcl
                    Else
                        If Not .Fields("CusFlag") Then
                            Tsxx = "此科目非客户往来科目!"
                            GoTo Lrcwcl
                        End If
                        If Not .Fields("EndFlag") Then
                            Tsxx = "此科目非末级科目!"
                            GoTo Lrcwcl
                        End If
                        If .Fields("StopFlag") Then
                            Tsxx = "此科目已停用!"
                            GoTo Lrcwcl
                        End If
                    End If
                End With
            End If
            
            '2.放置字段事后处理程序
            
            '以上为自定义部分]
            
        End Select
        
        '字段录入正确后为零字段清空
        Call Qkwlzd(Dqpdwgh, Dqpdwgl)
        
        sjzdyxxpd = True
        Yxxpdlock = True
        Exit Function
        
    End With
    
Lrcwcl:    '录入错误处理
    
    With WglrGrid
        Call Xtxxts(Tsxx, 0, 1)
        changelock = True
        .Select Dqpdwgh, Dqpdwgl
        changelock = False
        Call xswbk
        sjzdyxxpd = False
        Exit Function
    End With
    
End Function

Private Function Sjhzyxxpd(ByVal Yxxpdh As Long) As Boolean                  '录入数据行有效性判断,同时进行行处理
    
    Dim Lrywlz As Long                     '录入错误列值(Fixed)
    Dim RecTemp As New ADODB.Recordset     '临时使用动态集
    Dim Sqlstr As String                   '临时查询字符串
    Dim Str_Ccode As String                '临时索引编码
    
    With WglrGrid
        
        '行没有发生变化则不进行有效性判断
        If Hyxxpdlock Then
            Sjhzyxxpd = True
            Exit Function
        End If
        
        '以下为自定义部分[
        
        '1.1首先进行单个不能为空或不能为零判断(Fixed)
        For jsqte = Qslz To .Cols - 1
            '字段不能为空
            If GridInt(jsqte, 5) = 1 Then
                If Len(Trim(.TextMatrix(Yxxpdh, jsqte))) = 0 Then
                    Tsxx = GridStr(jsqte, 2)
                    Lrywlz = jsqte
                    GoTo Lrcwcl
                    Exit For
                End If
            End If
            
            '字段不能为零
            If GridInt(jsqte, 5) = 2 Then
                If Val(Trim(.TextMatrix(Yxxpdh, jsqte))) = 0 Then
                    Tsxx = GridStr(jsqte, 2)
                    Lrywlz = jsqte
                    GoTo Lrcwcl
                    Exit For
                End If
            End If
        Next jsqte
        
        
        '1.2进行其他有效性判断,编写格式同1.1
        
        '2.放置行处理程序(当数据行通过有效性判断)
        
        Str_Ccode = Trim(.TextMatrix(Yxxpdh, Sydz("001", GridStr(), Szzls)))
        
        On Error GoTo Swcwcl
        
        Cw_DataEnvi.DataConnect.BeginTrans
        
        With RecTemp
            If .State = 1 Then .Close
            .Open "SELECT * FROM Gy_Customer WHERE CusCode='" & Str_Ccode & "'", Cw_DataEnvi.DataConnect, adOpenDynamic, adLockOptimistic
            
            If Not RecTemp.EOF Then
                .Fields("ArAccCode") = WglrGrid.TextMatrix(Yxxpdh, Sydz("003", GridStr(), Szzls))      '应收帐款科目
                .Fields("PrAccCode") = WglrGrid.TextMatrix(Yxxpdh, Sydz("004", GridStr(), Szzls))      '预收帐款科目
                .Update
            End If
        End With
        
        Cw_DataEnvi.DataConnect.CommitTrans
        
    End With
    
    '以上为自定义部分]
    
    
    Sjhzyxxpd = True
    Hyxxpdlock = True
    Exit Function
    
Swcwcl:
    
    Cw_DataEnvi.DataConnect.RollbackTrans
    Tsxx = "存盘过程中出现未知错误,程序自动恢复保存前状态!"
    Call Xtxxts(Tsxx, 0, 1)
    Exit Function
    
Lrcwcl:      '录入错误处理
    
    With WglrGrid
        Call Xtxxts(Tsxx, 0, 1)
        changelock = True
        .Select Yxxpdh, Lrywlz
        changelock = False
        Call xswbk
        Sjhzyxxpd = False
        Exit Function
    End With
    
End Function

'===================以 下 程 序 为 通 用 部 分 ,一 般 不 需 更 改(程序动作部分)======================='