usersynchro.asp

动易的系统

        AddUser = True
    End If
End Function

Function UpdateUser(UserName,UserPassword,UserEmail,UserQuestion,UserAnswer,SysType,DbType)
    On Error Resume Next
    If IsNull(UserPassword) Or IsNull(UserName) Then
        UpdateUser = False
        Exit Function
    End If
    If IsNull(UserEmail) Then UserEmail = ""
    If IsNull(UserQuestion) Then UserQuestion = ""
    If IsNull(UserAnswer) Then UserAnswer = ""
    UserName = Replace(UserName,"'","''")
    UserQuestion = Replace(UserQuestion,"'","''")
    Dim tempSqlStr
    Select Case SysType
        Case "powereasy"
            tempSqlStr = "UPDATE PE_User SET UserPassword='" & UserPassword & "',Email='" & UserEmail & "',Question='" & UserQuestion & "',Answer='" & UserAnswer & "' WHERE UserName='" & UserName & "'"
        Case "dvbbs"
            tempSqlStr = "UPDATE Dv_User SET UserPassword='" & UserPassword & "',UserEmail='" & UserEmail & "',UserQuesion='" & UserQuestion & "',UserAnswer='" & UserAnswer & "' WHERE UserName='" & UserName & "'"
        Case "oblog"
            tempSqlStr = "UPDATE oblog_user SET PassWord='" & UserPassword & "',userEMail='" & UserEmail & "',Question='" & UserQuestion & "',Answer='" & UserAnswer & "' WHERE UserName='" & UserName & "'"
    End Select
    Conn_Remote.Execute(tempSqlStr)
    If Err Then
        Err.Clear
        UpdateUser = False
    Else
        UpdateUser = True
    End If
End Function

Function GetTrueString(DbType)
    If DbType = "access" Then
        GetTrueString = "True"
    Else
        GetTrueString = 1
    End If
End Function

Function GetFalseString(DbType)
    If DbType = "access" Then
        GetFalseString = "False"
    Else
        GetFalseString = "0"
    End If
End Function

Function GetNowString(DbType)
    If DbType = "access" Then
        GetNowString = "Now()"
    Else
        GetNowString = "GetDate()"
    End If
End Function

Sub GetSourceInfo()
    SysType_Source = Trim(Request.Form("source_systype"))
    DbType_Source = Trim(Request.Form("source_dbtype"))
    AcFile_Source = Trim(Request.Form("source_dbpath"))
    SqlServer_Source = Trim(Request.Form("source_servername"))
    SqlDbName_Source = Trim(Request.Form("source_dbname"))
    SqlUser_Source = Trim(Request.Form("source_username"))
    SqlPass_Source = Trim(Request.Form("source_password"))
End Sub

Sub GetRemoteInfo()
    SysType_Remote = Trim(Request.Form("remote_systype"))
    DbType_Remote = Trim(Request.Form("remote_dbtype"))
    AcFile_Remote = Trim(Request.Form("remote_dbpath"))
    SqlServer_Remote = Trim(Request.Form("remote_servername"))
    SqlDbName_Remote = Trim(Request.Form("remote_dbname"))
    SqlUser_Remote = Trim(Request.Form("remote_username"))
    SqlPass_Remote = Trim(Request.Form("remote_password"))
	If SysType_Remote = "oblog3" Then
		SysType_Remote = "oblog"
		isOblog4 = False
	ElseIf SysType_Remote = "oblog4" Then
		SysType_Remote = "oblog"
		isOblog4 = True
	End If
End Sub

Sub GetOptionInfo()
    NeedOverwrite = Trim(Request.Form("overwrite"))
    NeedBatch = Trim(Request.Form("batch"))
    BatchNum = Trim(Request.Form("batchnum"))
    If NeedOverwrite = "True" Then
        NeedOverwrite = True
    Else
        NeedOverwrite = False
    End If
    If NeedBatch = "True" Then
        NeedBatch = True
    Else
        NeedBatch = False
    End If
    If BatchNum = "" Or IsNumeric(BatchNum) = False Then
        BatchNum = 0
    End If
End Sub

Function GetUserTable(strSysType)
    Select Case strSysType
        Case "powereasy"
            GetUserTable = "PE_User"
        Case "dvbbs"
            GetUserTable = "Dv_User"
        Case "oblog"
            GetUserTable = "oblog_user"
    End Select
End Function

Function GetSqlString()
    Select Case SysType_Source
        Case "powereasy"
            GetSqlString = "SELECT UserName,UserPassword,Email,Question,Answer FROM PE_User ORDER BY UserID"
        Case "dvbbs"
            GetSqlString = "SELECT UserName,UserPassword,UserEmail,UserQuesion,UserAnswer FROM Dv_User ORDER BY UserID"
        Case "oblog"
            GetSqlString = "SELECT username,password,useremail,question,answer FROM oblog_user ORDER BY userid"
    End Select
End Function

Sub CheckParam
    Dim FoundErr,ServerMsg
    If DbType_Source = "" Or DbType_Remote = "" Then
        FoundErr = True
        ServerMsg = "缺少关键参数，程序无法继续运行"
        WriteMsg
    End If

    If DbType_Source = "access" And AcFile_Source = "" Then
        FoundErr = True
        ServerMsg = "源数据库选择为Access数据库，则数据库文件路径不能为空"
        WriteMsg
    End If

    If DbType_Source = "sql" And (SqlServer_Source = "" Or SqlDbName_Source = "" Or SqlUser_Source = "") Then
        FoundErr = True
        ServerMsg = "源数据库选择为SQL数据库，SQL服务器的相关信息不能为空"
        WriteMsg
    End If

    If DbType_Remote = "access" And AcFile_Remote = "" Then
        FoundErr = True
        ServerMsg = "目标数据库选择为Access数据库，则数据库文件路径不能为空"
        WriteMsg
    End If

    If DbType_Remote = "sql" And (SqlServer_Remote = "" Or SqlDbName_Remote = "" Or SqlUser_Remote = "") Then
        FoundErr = True
        ServerMsg = "目标数据库选择为SQL数据库，SQL服务器的相关信息不能为空"
        WriteMsg
    End If
End Sub

Sub InitHTML()
%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<title>PDO_API统一接口数据同步程序</title>
<link href="Code/style.css" rel="stylesheet" type="text/css" />
</head>
<body>
<div class="border" id="outbox">
    <div class="topbg center bold head">PDO_API统一接口数据同步程序</div>
    <div id="intro"> <span id="subtitle" class="bold">操作说明</span>：
        <p id="introcontent">正在进行用户数据同步操作，此过程视数据量大小、服务器性能和网络状况需要较长时间来完成，此过程中切勿刷新或者关闭当前浏览器窗口。</p>
        <hr style="width:100%;height:1px;color:#666" />
        <div id="body4">
            <div class="tdbg" id="bodymain">
                <div class="line">
					<strong>用户总数：</strong>&nbsp;共 <span id="totalnum">...</span> 条 分为 <span id="batchs">...</span> 批处理<br/>
				</div>
				<div class="line">
					<strong>当前处理：</strong>&nbsp;第 <span id="currentbatch">...</span> 批 <span id="processnum">...</span> 条
				</div>
				<div class="line">
					<strong>处理进度：</strong>&nbsp;新增 <span id="successnum">...</span> 条/覆盖 <span id="overwritenum">...</span> 条/跳过 <span id="skipnum">...</span> 条/失败 <span id="failnum">...</span> 条
				</div>
            </div>
        </div>
        <div id="wait" style="width:100%;color:red;font-weight:bold;line-height:18px;text-align:center;">正在处理您的请求，请稍候...</div>
        <hr style="width:100%;height:1px;color:#666" />
        <div class="center"><input type="button" id="btn_back" value="上一步" onclick="GoPreview()" disabled="disabled" />&nbsp;&nbsp;<input type="button" id="btn_go" value="完 成" onclick="window.close()" disabled="disabled" /></div>
		<div id="formdiv" style="display:none">
            <form name="myform" id="myform" action="UserSynchro.asp?action=start&batch=2" method="post">
                <input type="hidden" name="source_systype" id="source_systype" value="<%=SysType_Source%>" />
                <input name="source_dbtype" type="hidden" id="source_dbtype" value="<%=DbType_Source%>" />
                <input name="source_dbpath" type="hidden" id="source_dbpath" value="<%=AcFile_Source%>" />
                <input name="source_servername" type="hidden" id="source_servername" value="<%=SqlServer_Source%>" />
                <input name="source_dbname" type="hidden" id="source_dbname" value="<%=SqlDbName_Source%>" />
                <input name="source_username" type="hidden" id="source_username" value="<%=SqlUser_Source%>" />
                <input name="source_password" type="hidden" id="source_password" value="<%=SqlPass_Source%>" />
                <input name="remote_systype" type="hidden" id="remote_systype" value="<%=SysType_Remote%>" />
                <input name="remote_dbtype" type="hidden" id="remote_dbtype" value="<%=DbType_Remote%>" />
                <input name="remote_dbpath" type="hidden" id="remote_dbpath" value="<%=AcFile_Remote%>" />
                <input name="remote_servername" type="hidden" id="remote_servername" value="<%=SqlServer_Remote%>" />
                <input name="remote_dbname" type="hidden" id="remote_dbname" value="<%=SqlDbName_Remote%>" />
                <input name="remote_username" type="hidden" id="remote_username" value="<%=SqlUser_Remote%>" />
                <input name="remote_password" type="hidden" id="remote_password" value="<%=SqlPass_Remote%>" />
				<input name="overwrite" type="hidden" id="overwrite" value="<%=NeedOverwrite%>" />
                <input name="batch" type="hidden" id="batch" value="<%=NeedBatch%>" />
                <input name="batchnum" type="hidden" id="batchnum" value="<%=BatchNum%>" />
                <input name="SucNum" type="hidden" id="SucNum" value="0" />
                <input name="SkipNum" type="hidden" id="SkipNum" value="0" />
                <input name="OverNum" type="hidden" id="OverNum" value="0" />
                <input name="FailNum" type="hidden" id="FailNum" value="0" />
            </form>
        </div>
    </div>
</div>
<br/>
<div class="border center" id="copyright">Copyright &copy; 2004 - 2006 PowerEasy Inc. All Rights Reserved<br/>
    Powered By UserSynchro 2.0 Build 0514</div>
</body>
</html>
<%
Response.Flush
End Sub

Sub RefreshHTMLStart(iTotal,iBatchs,iBatch,iStart,iEnd)
    Response.Write "<script type=""text/javascript"" language=""javascript"">" & vbNewLine
    Response.Write vbTab & "document.getElementById(""totalnum"").innerHTML = """ & iTotal & """;" & vbNewLine
    Response.Write vbTab & "document.getElementById(""batchs"").innerHTML = """ & iBatchs & """;" & vbNewLine
    Response.Write vbTab & "document.getElementById(""currentbatch"").innerHTML = """ & iBatch & """;" & vbNewLine
    Response.Write vbTab & "document.getElementById(""processnum"").innerHTML = """ & iStart & " - " & iEnd & """;" & vbNewLine
    Response.Write "</script>" & vbNewLine
    Response.Flush
End Sub

Sub RefreshHTMLEnd(iSuccess,iSkip,iOverwrite,iFailed)
    Response.Write "<script type=""text/javascript"" language=""javascript"">" & vbNewLine
    Response.Write vbTab & "document.getElementById(""successnum"").innerHTML = """ & iSuccess & """;" & vbNewLine
    Response.Write vbTab & "document.getElementById(""overwritenum"").innerHTML = """ & iOverwrite & """;" & vbNewLine
    Response.Write vbTab & "document.getElementById(""skipnum"").innerHTML = """ & iSkip & """;" & vbNewLine
    Response.Write vbTab & "document.getElementById(""failnum"").innerHTML = """ & iFailed & """;" & vbNewLine
    Response.Write "</script>" & vbNewLine
    Response.Flush
End Sub

Sub OutputSubmit(blnFinished, Batch)
    CleanConns
    Response.Write "<script type=""text/javascript"" language=""javascript"">" & vbNewLine
    If blnFinished Then
        Response.Write vbTab & "document.getElementById(""wait"").innerHTML = ""操作已完成，感谢您对动易的信任与支持！"";" & vbNewLine
        Response.Write vbTab & "document.getElementById(""btn_go"").removeAttribute(""disabled"");" & vbNewLine
    Else
        Response.Write vbTab & "document.forms[0].SucNum.value = """ & SuccessRecord & """;" & vbNewLine
        Response.Write vbTab & "document.forms[0].SkipNum.value = """ & SkipRecord & """;" & vbNewLine
        Response.Write vbTab & "document.forms[0].OverNum.value = """ & OverwriteRecord & """;" & vbNewLine
        Response.Write vbTab & "document.forms[0].FailNum.value = """ & FailedRecord & """;" & vbNewLine
        Response.Write vbTab & "document.forms[0].action = ""UserSynchro.asp?action=start&batch=" & Batch+1 & """;" & vbNewLine
        Response.Write vbTab & "document.forms[0].submit();" & vbNewLine
    End If
    Response.Write "</script>" & vbNewLine
    Response.Flush
End Sub

Sub WriteMsg
    If action = "TestConn" Then
        Response.contentType = "text/html"
        Response.charset = "gb2312"
        Response.Write ServerMsg
        Response.End
    Else
        Response.Write "<script type=""text/javascript"" language=""javascript"">" & vbNewLine
        Response.Write vbTab & "document.getElementById(""wait"").innerHTML = """ & ServerMsg & """;" & vbNewLine
        Response.Write "</script>" & vbNewLine
        Response.End
    End If
End Sub

Sub CleanConns
    On Error Resume Next
    Conn_Source.Close
    Conn_Remote.Close
    Set Conn_Source = Nothing
    Set Conn_Remote = Nothing
End Sub

Sub OpenDatabase(OpenType)
    Dim strNameOfDb
    On Error Resume Next
    If OpenType = "Source" Then
        strNameOfDb = "源数据库"
        Set Conn_Source = Server.CreateObject("ADODB.Connection")
        If DbType_Source = "access" Then
            ConnStr = "Provider = Microsoft.JET.OleDb.4.0; Data Source = " & Server.MapPath(AcFile_Source) & ";"
        Else
            ConnStr = "Provider = Sqloledb; User ID = " & SqlUser_Source & "; Password = " & SqlPass_Source & "; Initial Catalog = " & SqlDbName_Source & "; Data Source = " & SqlServer_Source & ";"
        End If
        Conn_Source.Open ConnStr
    Else
        strNameOfDb = "目标数据库"
        Set Conn_Remote = Server.CreateObject("ADODB.Connection")
        If DbType_Remote = "access" Then
            ConnStr = "Provider = Microsoft.JET.OleDb.4.0; Data Source = " & Server.MapPath(AcFile_Remote) & ";"
        Else
            ConnStr = "Provider = Sqloledb; User ID = " & SqlUser_Remote & "; Password = " & SqlPass_Remote & "; Initial Catalog = " & SqlDbName_Remote & "; Data Source = " & SqlServer_Remote & ";"
        End If
        Conn_Remote.Open ConnStr
    End If
    If Err Then
        FoundErr = True
        ServerMsg = "创建" & strNameOfDb & "的连接失败，请检查所提交的信息。以下信息供参考： 连接代码：[" & ConnStr & "]"
        Err.Clear
        WriteMsg
    End If
End Sub

Sub MyExecute(ExecuteType,strToExecute,strErr)
    On Error Resume Next
    If ExecuteType = "Source" Then
        Conn_Source.Execute(strToExecute)
    Else
        Conn_Remote.Execute(strToExecute)
    End If
    If Err Then
        FoundErr = True
        ServerMsg = strErr & "以下信息供参考： SQL语句：[" & strToExecute & "]"
        Err.Clear
        WriteMsg
    End If
End Sub
%>