📄 collect_itemfilteradd.asp

📁 SK信息采集2.0功能介绍: 1.可针对任何静态网页,动态网页进行采集。包括htm,html,shtml,ASP,ASPX,JSP,PHP等。 2.增加自定文件采集.用户可采集网页中的所有文件.
💻 ASP
字号:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%option explicit%>
<!--#include file="../../Conn.asp"-->
<!--#include file="../../SysCls/KS_CommonCls.asp"-->
<!--#include file="../../SysCls/KS_CollectCommonCls.asp"-->
<!--#include file="../Inc/Session.asp"-->
<%
'===================================================================================================================
'软件名称：科汛网站管理系统
'当前版本：科汛网站管理系统 V2.2 0628个人Access版
'Copyright (C) 2006-2008 Kesion.Com  All rights reserved.
'产品咨询QQ：9537636,41904294
'技术支持QQ：111394,54004407 
'程序版权：科汛网络
'程序开发：科汛网络开发组（总策划：林文仲）
'E-Mail  :kesioncms@hotmail.com webmaster@kesion.com
'官方网站：http://www.kesion.com  
'演示站点：http://test.kesion.com 
'郑重声明:
'    ①、免费版本请在程序首页保留版权信息，并做上本站LOGO友情连接,商业版本无此要求;
'    ②、任何个人或组织不得在授权允许的情况下删除、修改、拷贝本软件及其他副本上一切关于版权的信息；
'    ③、科汛网络保留此软件的法律追究权利
'===================================================================================================================
Dim KSCls
Set KSCls = New Collect_ItemFilterAdd
KSCls.Execute()
Set KSCls = Nothing

Class Collect_ItemFilterAdd
        Private KSCMS
		Private KMCObj
		Private ConnItem
		Private Action, FoundErr, ErrMsg, FilterID
		Private FilterName, ItemID, FilterObject, FilterType, FilterContent, FisString, FioString, FilterRep, Flag, PublicTf
		Private Sub Class_Initialize()
		  Set KSCMS=New CommonCls
		  Set KMCObj=New CollectCommonCls
		  Set ConnItem = KSCMS.ConnItem()
		End Sub
        Private Sub Class_Terminate()
		 Call KSCMS.CloseConnItem()
		 Call KSCMS.Closeconn
		 Set KSCMS=Nothing
		 Set KMCObj=Nothing
		End Sub
		Sub Execute()
		Action = Trim(Request("Action"))
		FilterID = Trim(Request("FilterID"))
		ItemID = 0
		FilterObject = 1
		FilterType = 1
		PublicTf = False
		Flag = True
		If FilterID <> "" Then
			Call InitiDate
		End If
		If Action = "SaveAdd" Then
		   Call Save
		Else
		   Call Main
		End If
		End Sub
		
		Sub Main()
		Response.Write "<html>"
		Response.Write "<head>"
		Response.Write "<title>采集系统</title>"
		Response.Write "<meta http-equiv=""Content-Type"" content=""text/html; charset=gb2312"">"
		Response.Write "<link rel=""stylesheet"" type=""text/css"" href=""../inc/Admin_Style.css"">"
		Response.Write "</head>"
		Response.Write "<body leftmargin=""0"" topmargin=""0"" marginwidth=""0"" marginheight=""0"" oncontextmenu=""return false"">"
		Response.Write "<table width=""100%"" border=""0"" align=""center"" cellpadding=""0"" cellspacing=""1"" class=""sortbutton"">"
		Response.Write "  <tr>"
		Response.Write "    <td  height=""22"" align=""center"" nowrap><strong>添 加 新 过 滤</strong></td>"
		Response.Write "  </tr>"
		Response.Write "</table>"
		Response.Write "<br>"
										 
		Response.Write "<form method=""post"" action=""Collect_ItemFilterAdd.asp"" name=""form1"">"
		Response.Write "<br>"
		Response.Write "<table width=""60%"" border=""0"" align=""center"" cellpadding=""0"" cellspacing=""1"" class=""border"" >"
		Response.Write "    <tr>"
		Response.Write "      <td width=""100"" height=""25"" align=""center""> 过滤名称：</td>"
		Response.Write "      <td><input name=""FilterName"" type=""text"" id=""FilterName"" value=""" & FilterName & """ size=""25"" maxlength=""30"">"
		Response.Write "        &nbsp;</td>"
		Response.Write "    </tr>"
		Response.Write "    <tr>"
		Response.Write "      <td width=""100"" height=""25"" align=""center""> 所属项目：</td>"
		Response.Write "      <td>" & KMCObj.Collect_ShowItem_Option(ItemID, ConnItem) & "      </td>"
		Response.Write "    </tr>"
		Response.Write "    <tr>"
		 Response.Write "     <td width=""100"" height=""25"" align=""center""> 过滤对象：</td>"
		 Response.Write "     <td>"
		 Response.Write "        <select name=""FilterObject"" id=""FilterObject"">"
				   
				   If FilterObject = 1 Then
					 Response.Write "<option value=""1"" selected>标题过滤</option>"
					 Response.Write "<option value=""2"">正文过滤</option>"
					Else
					 Response.Write "<option value=""1"">标题过滤</option>"
					 Response.Write "<option value=""2"" selected>正文过滤</option>"
					End If
					
		  Response.Write "       </select>      </td>"
		  Response.Write "  </tr>"
		  Response.Write "  <tr>"
		  Response.Write "    <td width=""100"" height=""25"" align=""center""> 过滤类型：</td>"
		  Response.Write "    <td>"
				 
		   Response.Write "      <select name=""FilterType"" id=""FilterType"" onchange=showset(this.value)>"
				   If FilterType = 1 Then
					 Response.Write "<option value=""1"" selected >简单替换</option>"
					 Response.Write "<option value=""2"">高级过滤</option>"
					 Else
					 Response.Write "<option value=""1"">简单替换</option>"
					 Response.Write "<option value=""2"" selected >高级过滤</option>"
					 End If
					 
		  Response.Write "       </select>      </td>"
		  Response.Write "  </tr>"
		  Response.Write "  <tr>"
		   Response.Write "   <td width=""100"" height=""25"" align=""center""> 使用状态：</td>"
		   Response.Write "   <td>"
				 If Flag = True Then
				  Response.Write "<input type=""radio"" name=""Flag"" value=""yes"" checked>启用"
				  Response.Write "<input type=""radio"" name=""Flag"" value=""no"">禁用"
				  Else
				  Response.Write "<input type=""radio"" name=""Flag"" value=""yes"">启用"
				  Response.Write "<input type=""radio"" name=""Flag"" value=""no"" checked>禁用"
				  End If
				  
		  Response.Write "    </td>"
		 Response.Write "   </tr>"
		 Response.Write "   <tr>"
		 Response.Write "     <td width=""100"" height=""25"" align=""center""> 使用范围：</td>"
		
		 Response.Write "     <td>"
				 If PublicTf = False Then
					Response.Write "<input type=""radio"" name=""PublicTf"" value=""no"" checked>私有"
					Response.Write "<input type=""radio"" name=""PublicTf"" value=""yes"">公有"
					Else
					Response.Write "<input type=""radio"" name=""PublicTf"" value=""no"">私有"
					Response.Write "<input type=""radio"" name=""PublicTf"" value=""yes"" checked>公有"
					End If
				   
		Response.Write "      </td>"
		Response.Write "    </tr>"
		Response.Write "</table>"
		Response.Write "<table width=""60%"" border=""0"" align=""center"" cellpadding=""0"" cellspacing=""1"" class=""border"" id=""FilterType1"" style=""display:"">"
		Response.Write "    <tr>"
		 Response.Write "     <td width=""100"" align=""center""> 内容：</td>"
		 Response.Write "     <td ><textarea name=""FilterContent"" cols=""49"" rows=""5"">" & FilterContent & "</textarea>"
		 Response.Write "     </td>"
		Response.Write "    </tr>"
		Response.Write "</table>"
		Response.Write "<table width=""60%"" border=""0"" align=""center"" cellpadding=""0"" cellspacing=""1"" class=""border"" id=""FilterType2"" style=""display:none"">"
		 Response.Write "   <tr>"
		 Response.Write "     <td width=""100"" align=""center""> 开始标记：</td>"
		  Response.Write "    <td><textarea name=""FisString"" cols=""49"" rows=""5"">" & FisString & "</textarea>"
				Response.Write "&nbsp;</td>"
			Response.Write "</tr>"
			Response.Write "<tr>"
			 Response.Write " <td width=""100"" align=""center""> 结束标记：</td>"
			 Response.Write " <td><textarea name=""FioString"" cols=""49"" rows=""5"">" & FioString & "</textarea>"
			 Response.Write "   &nbsp;</td>"
			Response.Write "</tr>"
		Response.Write "</table>"
		Response.Write "<table width=""60%"" border=""0"" align=""center"" cellpadding=""0"" cellspacing=""1"" class=""border"">"
		  Response.Write "  <tr id=""FilterRep"">"
			Response.Write "  <td width=""100"" align=""center""> 替换：</td>"
			Response.Write "  <td><textarea name=""FilterRep"" cols=""49"" rows=""5"">" & FilterRep & "</textarea>"
			Response.Write "  &nbsp;</td>"
		   Response.Write " </tr>"
		Response.Write "</table>"
		Response.Write "<table width=""60%"" border=""0"" align=""center"" cellpadding=""0"" cellspacing=""1"" class=""border"" >"
		  Response.Write "  <tr>"
		   Response.Write "   <td colspan=""2"" align=""center"">"
			 Response.Write "  <input type=""hidden"" value=""" & FilterID & """ name=""FilterID"">"
			 Response.Write "  <input type=""hidden"" value=""" & Request("Page") & """ name=""Page"">"
			 Response.Write "  <input name=""Action"" type=""hidden"" id=""Action"" value=""SaveAdd""></td>"
			Response.Write "</tr>"
		Response.Write "</table>"
		Response.Write "</form>"
		Response.Write "</body>"
		Response.Write "</html>"
		Response.Write "<SCRIPT language=javascript>"
		Response.Write "showset(" & FilterType & ");"
		Response.Write "function showset(num)"
		Response.Write "{"
				Response.Write "if(num!=1)"
				Response.Write "{"
					Response.Write "document.all.FilterType1.style.display = ""none"";"
					Response.Write "document.all.FilterType2.style.display = """";"
		Response.Write "        }"
		Response.Write "        else"
		Response.Write "        {"
		Response.Write "            document.all.FilterType1.style.display = """";"
		Response.Write "            document.all.FilterType2.style.display = ""none"";"
		Response.Write "        }"
		
		Response.Write "}"
		Response.Write "function CheckForm()"
		Response.Write "{"
		 Response.Write " var myform=document.form1;"
		 Response.Write " if (myform.FilterName.value=='')"
		 Response.Write " {"
		 Response.Write "    alert('请输入过滤名称');"
		 Response.Write "    myform.FilterName.focus();"
		 Response.Write "    return false;"
		 Response.Write " }"
		 Response.Write " if (myform.ItemID.value=='')"
		Response.Write "  {"
		Response.Write "     alert('请选择一个项目');"
		 Response.Write "    myform.ItemID.focus();"
		Response.Write "     return false;"
		Response.Write "  }"
		Response.Write "   myform.submit();"
		Response.Write "  return true;"
		Response.Write "}"
		Response.Write "</script>"
		End Sub
		
		Sub Save()
		Dim SqlItem, RsItem
		FilterName = Trim(Request.Form("FilterName"))
		ItemID = Trim(Request.Form("ItemID"))
		FilterObject = Request.Form("FilterObject")
		FilterType = Request.Form("FilterType")
		FilterContent = Request.Form("FilterContent")
		FisString = Request.Form("FisString")
		FioString = Request.Form("FioString")
		FilterRep = Request.Form("FilterRep")
		Flag = Request.Form("Flag")
		PublicTf = Request.Form("PublicTf")
		
		If FilterName = "" Then
		   FoundErr = True
		   ErrMsg = ErrMsg & "<br><li>过滤名称不能为空</li>"
		End If
		If ItemID = "" Then
		   FoundErr = True
		   ErrMsg = ErrMsg & "<br><li>请选择过滤所属项目</li>"
		Else
		   ItemID = CLng(ItemID)
		   If ItemID = 0 Then
			  FoundErr = True
			  ErrMsg = ErrMsg & "<br><li>请选择过滤所属项目</li>"
		   End If
		End If
		If FilterObject = "" Then
		   FoundErr = True
		   ErrMsg = ErrMsg & "<br><li>请选择过滤对象</li>"
		Else
		   FilterObject = CLng(FilterObject)
		End If
									
		If FilterType = "" Then
		   FoundErr = True
		   ErrMsg = ErrMsg & "<br><li>请选择过滤类型</li>"
		Else
		   FilterType = CLng(FilterType)
		   If FilterType = 1 Then
			  If FilterContent = "" Then
				 FoundErr = True
				 ErrMsg = ErrMsg & "<br><li>过滤的内容不能为空</li>"
			  End If
		   ElseIf FilterType = 2 Then
			  If FisString = "" Or FioString = "" Then
				 FoundErr = True
				 ErrMsg = ErrMsg & "<br><li>开始/结束标记不能为空</li>"
			  End If
		   Else
			  FoundErr = True
			  ErrMsg = ErrMsg & "<br><li>参数错误，请从有效链接进入</li>"
		   End If
		End If
		If Flag = "yes" Then
		   Flag = True
		Else
		   Flag = False
		End If
		If PublicTf = "yes" Then
		   PublicTf = True
		Else
		   PublicTf = False
		End If
										
		If FoundErr <> True Then
		   Set RsItem = Server.CreateObject("adodb.recordset")
		   If FilterID <> "" Then
			 SqlItem = "select top 1 *  From KS_Filters Where FilterID=" & FilterID
			 RsItem.Open SqlItem, ConnItem, 1, 3
			 RsItem("FilterName") = FilterName
			 RsItem("ItemID") = ItemID
			 RsItem("FilterObject") = FilterObject
			 RsItem("FilterType") = FilterType
			 If FilterType = 1 Then
			   RsItem("FilterContent") = FilterContent
			 ElseIf FilterType = 2 Then
			   RsItem("FisString") = FisString
			   RsItem("FioString") = FioString
			 End If
			 RsItem("FilterRep") = FilterRep
			 RsItem("Flag") = Flag
			 RsItem("PublicTf") = PublicTf
			 RsItem.Update
			 RsItem.Close
			 Response.Write ("<script>alert('过滤修改成功!');location.href='Collect_ItemFilters.asp?Page=" & Request("Page") & "';parent.frames['BottomFrame'].location.href='../Split.asp?OpStr=信息采集管理 >> <font color=red>过滤设置</font>&ButtonSymbol=Disabled'</script>")
		   Else
		   SqlItem = "select top 1 *  From KS_Filters"
		   RsItem.Open SqlItem, ConnItem, 1, 3
		   RsItem.AddNew
		   RsItem("FilterName") = FilterName
		   RsItem("ItemID") = ItemID
		   RsItem("FilterObject") = FilterObject
		   RsItem("FilterType") = FilterType
		   If FilterType = 1 Then
			  RsItem("FilterContent") = FilterContent
		   ElseIf FilterType = 2 Then
			  RsItem("FisString") = FisString
			  RsItem("FioString") = FioString
		   End If
		   RsItem("FilterRep") = FilterRep
		   RsItem("Flag") = Flag
		   RsItem("PublicTf") = PublicTf
		   RsItem.Update
		   RsItem.Close
		   Response.Write ("<script>if (confirm('过滤添加成功，继续添加吗?')){location.href='Collect_ItemFilterAdd.asp';}else{location.href='Collect_ItemFilters.asp';parent.frames['BottomFrame'].location.href='../Split.asp?OpStr=信息采集管理 >> <font color=red>过滤设置</font>&ButtonSymbol=Disabled'}</script>")
		   End If
		   Set RsItem = Nothing
		Else
		   Call KMCObj.WriteErrMsg(ErrMsg)
		End If
										
		End Sub
		Sub InitiDate()
		   Dim RSObj
		  Set RSObj = Server.CreateObject("Adodb.Recordset")
		  RSObj.Open "Select * From KS_Filters Where FilterID=" & FilterID, ConnItem, 1, 1
		  If Not RSObj.EOF Then
			 FilterName = RSObj("FilterName")
			 ItemID = RSObj("ItemID")
			 FilterObject = RSObj("FilterObject")
			 FilterType = RSObj("FilterType")
			 FilterContent = RSObj("FilterContent")
			 FisString = RSObj("FisString")
			 FioString = RSObj("FioString")
			 FilterRep = RSObj("FilterRep")
			 Flag = RSObj("Flag")
			 PublicTf = RSObj("PublicTf")
		  End If
		  RSObj.Close
		  Set RSObj = Nothing
		End Sub
End Class
%>
💿 文件大小 9756 K
👤 上传用户 BO__1
📂 所属分类 Java编程
🏷️ 相关标签

#shtml #ASPX #html #采集
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -