guestbook_save.asp

SK信息采集2.0功能介绍: 1.可针对任何静态网页,动态网页进行采集。包括htm,html,shtml,ASP,ASPX,JSP,PHP等。 2.增加自定文件采集.用户可采集网页中的所有文件.

<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%option explicit%>
<!--#include file="../Conn.asp"-->
<!--#include file="../SysCls/KS_CommonCls.asp"-->
<%
'===================================================================================================================
'软件名称：科汛网站管理系统
'当前版本：科汛网站管理系统 V2.2 SP2 Free
'Copyright (C) 2006-2008 Kesion.Com  All rights reserved.
'产品咨询QQ：9537636,41904294
'技术支持QQ：111394,54004407 
'程序版权：科汛网络
'程序开发：科汛网络开发组（总策划：林文仲）
'E-Mail  :[e-mail] [e-mail]
'官方网站：http://www.kesion.com  
'演示站点：http://test.kesion.com 
'郑重声明:
'    ①、免费版本请在程序首页保留版权信息，并做上本站LOGO友情连接,商业版本无此要求;
'    ②、任何个人或组织不得在授权允许的情况下删除、修改、拷贝本软件及其他副本上一切关于版权的信息；
'    ③、科汛网络保留此软件的法律追究权利
'===================================================================================================================
Dim KSCls
Set KSCls = New Guest_SaveData
KSCls.Execute()
Set KSCls = Nothing

Class Guest_SaveData
        Private KSCMS
        Private Name, Email, Subject, Oicq, Verifycode, IP, Pic, TxtHead, HomePage, Memo, ErrorMsg, a
		Private GuestNum
		Private Sub Class_Initialize()
		  Set KSCMS=New CommonCls
		End Sub
        Private Sub Class_Terminate()
		 Call KSCMS.CloseConn()
		 Set KSCMS=Nothing
		End Sub
	   
	   Public Sub Execute()
		Dim TmpIsSelfRefer,I,SplitStrArr
		GuestNum=KSCMS.GetConfig("GuestNum")
		TmpIsSelfRefer = IsSelfRefer()
			
		If TmpIsSelfRefer <> TRUE Then '外部提交的数据
			Call KSCMS.AlertHistory("数据提交错误！",-1)
		End If
		
		Dim LastLoginIP:LastLoginIP = Trim(Request.ServerVariables("HTTP_X_FORWARDED_FOR"))
			If LastLoginIP = "" Then LastLoginIP = Request.ServerVariables("REMOTE_ADDR")
			Name = KSCMS.G("Name")
			Email = KSCMS.G("Email")
			HomePage = KSCMS.G("HomePage")
			Oicq = KSCMS.ChkClng(KSCMS.G("Oicq"))
			Verifycode = KSCMS.G("Code")
			IP = LastLoginIP
			Pic = KSCMS.G("Pic")
			TxtHead = KSCMS.G("txthead")
			Subject = KSCMS.G("Subject")
			Memo = KSCMS.G("Memo")
			SplitStrArr=split(KSCMS.GetConfig("GuestSplitStr"),vbCrlf)
			For I=0 To Ubound(SplitStrArr)
			  Memo=Replace(Memo,Split(SplitStrArr(I),"=")(0),Split(SplitStrArr(I),"=")(1))
			Next
		a = CheckEnter()
		If a = True Then 
			SaveData()
			Response.Write("<script>alert('谢谢您的留言，我们会尽快给您答复！');location.href='Index.asp';</script>")
		Else
			Call KSCMS.AlertHistory(ErrorMsg,-1)
		End If
	
	End Sub
	
	Function CheckEnter()
			IF Trim(Verifycode)<>Trim(Session("Verifycode")) And KSCMS.GetConfig("GuestVerificTF")=1 then 
		   	 CheckEnter=False
			 Response.Write("<script>alert('验证码有误，请重新输入！');history.back();</script>")
			Else
				If Name="" Then
					CheckEnter=False
					ErrorMsg="你好像忘了填“昵称”！"
				Else
					If Email="" or InStr(2,Email,"@")=0 Then
						CheckEnter=False
						ErrorMsg="你的Email有问题请重新填写！"
					Else
						If Pic="" Then
							CheckEnter=False
							ErrorMsg="你的头像没选,选一个把！"
						Else
							If TxtHead="" Then
								CheckEnter=False
								ErrorMsg="你的表情没选,选一个把！"
							Else
								If Memo="" or Len(Trim(Memo)) > KSCMS.ChkClng(GuestNum) Then
									CheckEnter=False
									ErrorMsg="留言不能为空并且不能超过"& KSCMS.ChkClng(GuestNum) &"字，重新来吧！"
								Else
									CheckEnter=TRUE
								End If
							End If
						End If
					End If	   
				End If
			End If
		End Function
		
		Sub SaveData()
		    Dim SqlStr:SqlStr = "SELECT * From KS_GuestBook WHERE ID IS NULL" 
			Dim RSObj:Set RSObj=Server.CreateObject("Adodb.RecordSet")
			RSObj.Open SqlStr,Conn,1,3
			RSObj.AddNew 
			RSObj("Name") = KSCMS.HTMLEncode(Name)
			RSObj("Email") = KSCMS.HTMLEncode(Email)
			RSObj("HomePage") = KSCMS.HTMLEncode(HomePage)
			RSObj("Face") =Pic&".gif"
			RSObj("TxtHead") = "Face" &  TxtHead&".gif"
			RSObj("Subject") = KSCMS.HTMLEncode(Subject)
			RSObj("Memo") = KSCMS.HTMLEncode(Memo)
			RSObj("Oicq") = KSCMS.HTMLEncode(Oicq)        
			RSObj("GuestIP") = IP    
			RSObj("AddTime") = Now()
			RSObj.Update
			RSObj.Close
			Set RSObj = Nothing
		End sub
		
		' ============================================
		' 检测上页是否从本站提交
		' 返回:True,False
		' ============================================
		Function IsSelfRefer()
			Dim sHttp_Referer, sServer_Name
			sHttp_Referer = CStr(Request.ServerVariables("HTTP_REFERER"))
			sServer_Name = CStr(Request.ServerVariables("SERVER_NAME"))
			If Mid(sHttp_Referer, 8, Len(sServer_Name)) = sServer_Name Then
				IsSelfRefer = True
			Else
				IsSelfRefer = False
			End If
		End Function
End Class
%>