rfc2426.txt

著名的RFC文档,其中有一些文档是已经翻译成中文的的.

   value        = n-value

   n-value      = 0*4(text-value *("," text-value) ";")
                  text-value *("," text-value)
        ; Family; Given; Middle; Prefix; Suffix.
        ; Example: Public;John;Quincy,Adams;Reverend Dr. III

   ;For name="NICKNAME"
   param        = text-param
        ; Text parameters allowed



Dawson & Howes              Standards Track                    [Page 30]

RFC 2426              vCard MIME Directory Profile        September 1998


   value        = text-list

   ;For name="PHOTO"
   param        = img-inline-param
        ; Only image parameters allowed

   param        =/ img-refer-param
        ; Only image parameters allowed

   value        = img-inline-value
        ; Value and parameter MUST match

   value        =/ img-refer-value
        ; Value and parameter MUST match

   ;For name="BDAY"
   param        = ("VALUE" "=" "date")
        ; Only value parameter allowed

   param        =/ ("VALUE" "=" "date-time")
        ; Only value parameter allowed

   value        = date-value
        ; Value MUST match value type

   value        =/ date-time-value
        ; Value MUST match value type

   ;For name="ADR"
   param        = adr-param / text-param
        ; Only adr and text parameters allowed

   value        = adr-value

   ;For name="LABEL"
   param        = adr-param / text-param
        ; Only adr and text parameters allowed

   value        = text-value

   ;For name="TEL"
   param        = tel-param
        ; Only tel parameters allowed

   value        = phone-number-value

   tel-param    = "TYPE" "=" tel-type *("," tel-type)




Dawson & Howes              Standards Track                    [Page 31]

RFC 2426              vCard MIME Directory Profile        September 1998


   tel-type     = "HOME" / "WORK" / "PREF" / "VOICE" / "FAX" / "MSG"
                / "CELL" / "PAGER" / "BBS" / "MODEM" / "CAR" / "ISDN"
                / "VIDEO" / "PCS" / iana-token / x-name
        ; Values are case insensitive

   ;For name="EMAIL"
   param        = email-param
        ; Only email parameters allowed

   value        = text-value

   email-param  = "TYPE" "=" email-type ["," "PREF"]
        ; Value is case insensitive

   email-type   = "INTERNET" / "X400" / iana-token / "X-" word
        ; Values are case insensitive

   ;For name="MAILER"
   param        = text-param
        ; Only text parameters allowed

   value        = text-value

   ;For name="TZ"
   param        = ""
        ; No parameters allowed

   value        = utc-offset-value

   ;For name="GEO"
   param        = ""
        ; No parameters allowed

   value        = float-value ";" float-value

   ;For name="TITLE"
   param        = text-param
        ; Only text parameters allowed

   value        = text-value

   ;For name="ROLE"
   param        = text-param
        ; Only text parameters allowed

   value        = text-value

   ;For name="LOGO"



Dawson & Howes              Standards Track                    [Page 32]

RFC 2426              vCard MIME Directory Profile        September 1998


   param        = img-inline-param / img-refer-param
        ; Only image parameters allowed

   value        = img-inline-value / img-refer-value
        ; Value and parameter MUST match

   ;For name="AGENT"
   param        = agent-inline-param

   param        =/ agent-refer-param

   value        = agent-inline-value
        ; Value and parameter MUST match

   value        =/ agent-refer-value
        ; Value and parameter MUST match

   agent-inline-param = ""
        ; No parameters allowed

   agent-refer-param = "VALUE" "=" "uri"
        ; Only value parameter allowed

   agent-inline-value = text-value
        ; Value MUST be a valid vCard object

   agent-refer-value = uri
        ; URI MUST refer to image content of given type

   ;For name="ORG"

   param        = text-param
        ; Only text parameters allowed

   value        = org-value

   org-value    = *(text-value ";") text-value
        ; First is Organization Name, remainder are Organization Units.

   ;For name="CATEGORIES"
   param        = text-param
        ; Only text parameters allowed

   value        = text-list

   ;For name="NOTE"
   param        = text-param
        ; Only text parameters allowed



Dawson & Howes              Standards Track                    [Page 33]

RFC 2426              vCard MIME Directory Profile        September 1998


   value        = text-value

   ;For name="PRODID"
   param        = ""
        ; No parameters allowed

   value        = text-value

   ;For name="REV"
   param        = ["VALUE" =" "date-time"]
        ; Only value parameters allowed. Values are case insensitive.

   param        =/ "VALUE" =" "date"
        ; Only value parameters allowed. Values are case insensitive.

   value        = date-time-value

   value        =/ date-value

   ;For name="SORT-STRING"
   param        = text-param
        ; Only text parameters allowed

   value        = text-value

   ;For name="SOUND"
   param        = snd-inline-param
        ; Only sound parameters allowed

   param        =/ snd-refer-param
        ; Only sound parameters allowed

   value        = snd-line-value
        ; Value MUST match value type

   value        =/ snd-refer-value
        ; Value MUST match value type

   snd-inline-value     = binary-value CRLF
        ; Value MUST be "b" encoded audio content

   snd-inline-param     = ("VALUE" "=" "binary"])
                        / ("ENCODING" "=" "b")
                        / ("TYPE" "=" *SAFE-CHAR)
        ; Value MUST be an IANA registered audio type

   snd-refer-value      = uri
        ; URI MUST refer to audio content of given type



Dawson & Howes              Standards Track                    [Page 34]

RFC 2426              vCard MIME Directory Profile        September 1998


   snd-refer-param      = ("VALUE" "=" "uri")
                        / ("TYPE" "=" word)
        ; Value MUST be an IANA registered audio type

   ;For name="UID"
   param        = ""
        ; No parameters allowed

   value        = text-value

   ;For name="URL"
   param        = ""
        ; No parameters allowed

   value        = uri

   ;For name="VERSION"
   ;This type MUST be included in a vCard object.
   param        = ""
        ; No parameters allowed

   value        = text-value
        ; Value MUST be "3.0"

   ;For name="CLASS"
   param        = ""
        ; No parameters allowed

   value        = "PUBLIC" / "PRIVATE" / "CONFIDENTIAL"
                / iana-token / x-name
        ; Value are case insensitive

   ;For name="KEY"
   param        = key-txt-param
        ; Only value and type parameters allowed

   param        =/ key-bin-param
        ; Only value and type parameters allowed

   value        = text-value

   value        =/ binary-value

   key-txt-param = "TYPE" "=" keytype

   key-bin-param = ("TYPE" "=" keytype)
                 / ("ENCODING" "=" "b")
        ; Value MUST be a "b" encoded key or certificate



Dawson & Howes              Standards Track                    [Page 35]

RFC 2426              vCard MIME Directory Profile        September 1998


   keytype      = "X509" / "PGP" / iana-token / x-name
        ; Values are case insensitive

   ;For name="X-" non-standard type
   param        = text-param / (x-name "=" param-value)
        ; Only text or non-standard parameters allowed

   value        = text-value

   ;*******************************************
   ; vCard Commonly Used Parameter Definition
   ;*******************************************

   text-param   = ("VALUE" "=" "ptext")
                / ("LANGUAGE" "=" langval)
                / (x-name "=" param-value)

   langval      = <a language string as defined in RFC 1766>

   img-inline-value     = binary-value
        ;Value MUST be "b" encoded image content

   img-inline-param

   img-inline-param     = ("VALUE" "=" "binary")
                        / ("ENCODING" "=" "b")
                        / ("TYPE" "=" param-value
        ;TYPE value MUST be an IANA registered image type

   img-refer-value = uri
        ;URI MUST refer to image content of given type

   img-refer-param      = ("VALUE" "=" "uri")
                        / ("TYPE" "=" param-value)
        ;TYPE value MUST be an IANA registered image type

   adr-param    = ("TYPE" "=" adr-type *("," adr-type))
                / (text-param)

   adr-type     = "dom" / "intl" / "postal" / "parcel" / "home"
                / "work" / "pref" / iana-type / x-name

   adr-value    = 0*6(text-value ";") text-value
        ; PO Box, Extended Address, Street, Locality, Region, Postal
        ; Code, Country Name






Dawson & Howes              Standards Track                    [Page 36]

RFC 2426              vCard MIME Directory Profile        September 1998


   ;*******************************************
   ; vCard Type Value Definition
   ;*******************************************

   text-value-list      = 1*text-value *("," 1*text-value)

   text-value   = *(SAFE-CHAR / ":" / DQUOTE / ESCAPED-CHAR)

   ESCAPED-CHAR = "\\" / "\;" / "\," / "\n" / "\N")
        ; \\ encodes \, \n or \N encodes newline
        ; \; encodes ;, \, encodes ,

   binary-value = <A "b" encoded text value as defined in [RFC 2047]>

   date-value   = <A single date value as defined in [MIME-DIR]>

   time-value   = <A single time value as defined in [MIME-DIR]>

   date-time-value = <A single date-time value as defined in [MIME-DIR]

   float-value  = <A single float value as defined in [MIME-DIR]>

   phone-number-value = <A single text  value as defined in [CCITT
                         E.163] and [CCITT X.121]>

   uri-value    = <A uri value as defined in [MIME-DIR]>

   utc-offset-value = ("+" / "-") time-hour ":" time-minute
   time-hour    = 2DIGIT                ;00-23
   time-minute  = 2DIGIT                ;00-59

5.  Differences From vCard v2.1

   This specification has been reviewed by the IETF community. The
   review process introduced a number of differences from the [VCARD]
   version 2.1. These differences require that vCard objects conforming
   to this specification have a different version number than a vCard
   conforming to [VCARD]. The differences include the following:

        . The QUOTED-PRINTABLE inline encoding has been eliminated.
          Only the "B" encoding of [RFC 2047] is an allowed value for
          the ENCODING parameter.

        . The method for specifying CRLF character sequences in text
          type values has been changed. The CRLF character sequence in
          a text type value is specified with the backslash character
          sequence "\n" or "\N".




Dawson & Howes              Standards Track                    [Page 37]

RFC 2426              vCard MIME Directory Profile        September 1998


        . Any COMMA or SEMICOLON in a text type value must be backslash
          escaped.

        . VERSION value corresponding to th