adminlist.asp

一个asp写的论坛源代码,论坛所需要的功能都有

<!-- #include file="conn.asp" -->
<!-- #include file="INC/Const.asp" -->
<%
team.Headers("管理团队")

dim admintime,counter
dim mycont
Dim Forumid,x1,x2

admintime=15		'定义日期
X1="<a href=adminlist.asp>管理团队</A>"
X2=""
team.MenuTitle
MasterList

Sub MasterList
	Dim RS,UsTmp,GroupTmp
	Set Rs=Team.Execute("Select ID,Bbsname,Moderated From BBSconfig Order By Id Desc")
	If Not Rs.Eof Then
		GroupTmp=Rs.GetRows(-1)
	End If
	Rs.Close:Set Rs=Nothing

	Set Rs=Team.Execute("Select Username,UserGroupID,userface,honor,posttopic,postrevert,goodtopic,levelname,regtime,userface,Landtime From [User] Where UserGroupID >=10 Order By UserGroupID Desc")
	If Not Rs.Eof Then
		UsTmp=Rs.GetRows(-1)
	End If
	Rs.Close:Set Rs=Nothing

	Dim i,Usermaster
	team.UserconFig()
	With Response
		.Write "<table width=98%  border=0 cellpadding=0 cellspacing=5 class=a6 align=center><tr><td align=center><table cellpadding='3' cellspacing='1' border='0' align='center' width='"&team.wid&"' class='a2'>"
		.Write "<tr class=a1>"
		.Write "<td align=center><b>论坛管理团队列表</B></td></tr>"
		For i=0 To Ubound(UsTmp,2) 
			Usermaster=Split(UsTmp(7,i),"||")
 			.Write "<tr Class=a4><td align=center>"
			.Write "<table border='0' cellpadding='0' cellspacing='3' cellspacing='0' width='100%'>"
			.Write "<tr><td width='20%'>"
			If InStr(team.OnLineList,UsTmp(0,i)&"|")=0 Then
				.Write "<Span Style='filter:gray;HEIGHT:100px;WIDTH:100px;'><img Src="&UsTmp(9,i)&" border=0 alt='离线' onload=""javascript:if(this.width>120)this.width=120;"" onerror=""javascript:this.src=images/face/error.gif""></span>"
			Else
				.Write "<img Src="&UsTmp(9,i)&" border=0 alt='在线' onload=""javascript:if(this.width>120)this.width=120;"">"
			End If
			.Write "</td><td width='50%'>用户名称: <b><a href=Profile.asp?username="& UsTmp(0,i)&">"& UsTmp(0,i)&" </a></b> - <a href=message.asp?menu=post&incept="& UsTmp(0,i)&"  alt='发送短信' target=_blank>[PM]</a>"
			.Write "<BR />注册日期: "&UsTmp(8,i)
			.Write "<BR />上次登陆: "&UsTmp(10,i)
			.Write "<BR />发贴总数: "&UsTmp(4,i)+UsTmp(5,i)
			.Write "<BR />精华帖子: "&UsTmp(6,i)
			If isNull(UsTmp(3,i)) Then
				.Write "<BR />个人头衔: 暂无"
			Else
				.Write "<BR />个人头衔: "&UsTmp(3,i)
			End If
			.Write "<BR />管理级别: <Span Style='"&Usermaster(2)&"'>"&Usermaster(0)&"</span>"
			.Write "</td><td valign=top>缺勤状况: " & Datediff("d",UsTmp(10,i),date()) &" 天"
			.Write "<BR />管理板块: <BR />"
			
			Dim ii,Memtp,iii
			For ii=0 To Ubound(GroupTmp,2)
				If Not isNull(GroupTmp(2,ii)) Then
					Memtp=Split(GroupTmp(2,ii),"|")
					For iii=0 to Ubound(Memtp)
						If Instr(UsTmp(0,i),Memtp(iii))>0 Then
							.Write " <a href=SHOWForum.asp?forumid="&GroupTmp(0,ii)&">『"&GroupTmp(1,ii)&"</a>』<br />"
						End If
					Next
				End If
			Next
			.Write "</td></tr></table>"
			.Write "</td></tr>"
		Next
		.Write "<tr><td Class=a3 align=center>"
		.Write "□注意: 超过 "&admintime&" 天未登陆的版主将被取消资格!"
		.Write "</td></tr></table>"
		.Write "</td></tr></table>"
	End With
End Sub
team.htmlend
%>