configure.in

a useful spiking neural networks simulator

dnl ######################################################################
dnl
dnl   $Id: configure.in,v 1.6 2003/05/08 05:05:41 t Exp $
dnl   Copyright (c) 2000, Makino Takaki
dnl
dnl   Name: configure.in
dnl   Purpose: Script for autoconf
dnl
dnl ######################################################################


dnl Process this file with autoconf to produce a configure script.


dnl ######################################################################
AC_INIT(src/func.cpp)
AM_INIT_AUTOMAKE(punnets, 1.0a)

AC_CANONICAL_HOST

if test "$CYGWIN" = yes; then
  AC_DEFINE(USE_CYGWIN, 1, [Defined in CYGWIN environment])
fi

CPPFLAGS=" -I/usr/local/include "


dnl ######################################################################
dnl   Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AC_PROG_CXX
AC_PROG_CXXCPP
AC_PATH_PROG(DOXYGEN, doxygen$EXEEXT, nocommand)

if test "$DOXYGEN" != nocommand; then
	AC_SUBST(DOXYOUTPUT, "\$(builddir)/html/index.html")
else
	AC_SUBST(DOXYOUTPUT, "")
fi


dnl ########################################
dnl   The following programs should be
dnl   found with c++ compiler.
AC_LANG_CPLUSPLUS
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB


dnl ######################################################################
dnl   Checks for libraries.
dnl ########################################
dnl   The following libraries should be
dnl   found with c++ compiler.
AC_LANG_CPLUSPLUS


dnl ######################################################################
dnl   Checks for header files.
dnl ########################################
dnl   The following libraries should be
dnl   found with c++ compiler.
AC_HEADER_STDC
AC_CHECK_HEADERS(vector map string,,[AC_ERROR([Mandatory header file is missing])])
AC_CHECK_HEADERS(math.h hash_map ext/hash_map)


dnl ########################################
dnl   The following characteristics should
dnl   be detected with c++ compiler
AC_LANG_CPLUSPLUS
AC_TYPE_SIZE_T

CXXFLAGS_TMP="$CXXFLAGS"

CXXFLAGS_ADD=""
AC_SUBST(CXXFLAGS_ADD)

CXXFLAGS=-fstrict-aliasing
AC_CACHE_CHECK(whether $CXX accepts -fstrict-aliasing,
	ac_cv_prog_cxx_strict_aliasing,
[AC_TRY_COMPILE([#include <iostream.h>],[{ cout << "hello, world"; }], 
ac_cv_prog_cxx_strict_aliasing=yes, ac_cv_prog_cxx_strict_aliasing=no)])

if test "$ac_cv_prog_cxx_strict_aliasing" = yes; then
  CXXFLAGS_ADD="$CXXFLAGS_ADD -fstrict-aliasing"
fi

CXXFLAGS=-ffast-math
AC_CACHE_CHECK(whether $CXX accepts -ffast-math,
	ac_cv_prog_cxx_fastmath,
[AC_TRY_COMPILE([#include <math.h>],[{ double d = sqrt(3.0)*4.0; return (int)d; }], 
ac_cv_prog_cxx_fastmath=yes, ac_cv_prog_cxx_fastmath=no)])

if test "$ac_cv_prog_cxx_fastmath" = yes; then
  CXXFLAGS_ADD="$CXXFLAGS_ADD -ffast-math"
fi

CXXFLAGS=-fomit-frame-pointer
AC_CACHE_CHECK(whether $CXX accepts -fomit-frame-pointer,
	ac_cv_prog_cxx_omitfp,
[AC_TRY_COMPILE([#include <math.h>],[{ double d = sqrt(3.0)*4.0; return (int)d; }], 
ac_cv_prog_cxx_omitfp=yes, ac_cv_prog_cxx_omitfp=no)])

if test "$ac_cv_prog_cxx_omitfp" = yes; then
  CXXFLAGS_ADD="$CXXFLAGS_ADD -fomit-frame-pointer"
fi

CXXFLAGS="-W -Wall"
AC_CACHE_CHECK(whether $CXX accepts -W -Wall,
	ac_cv_prog_cxx_wall,
[AC_TRY_COMPILE([#include <iostream>],[{ std::cout << "hello, world"; }], 
ac_cv_prog_cxx_wall=yes, ac_cv_prog_cxx_wall=no)])

if test "$ac_cv_prog_cxx_wall" = yes; then
  CXXFLAGS_ADD="$CXXFLAGS_ADD -W -Wall"
fi

CXXFLAGS="$CXXFLAGS_TMP$CXXFLAGS_ADD"

dnl ######################################################################
dnl   Checks for compiling options.
AC_ARG_ENABLE(prof, [ --enable-prof		enable profiling (no or 0-5) [default 1]],, enable_prof=1)
AC_MSG_CHECKING(whether to enable profiling)
if test "$enable_prof" = no; then
  AC_MSG_RESULT(no)
elif test 0 -le $enable_prof -a $enable_prof -le 5; then
  AC_MSG_RESULT($enable_prof)
  AC_DEFINE_UNQUOTED(PROFILE, $enable_prof, [Profiling level])
else
  AC_MSG_RESULT($enable_prof)
  AC_WARN(profiling value is invalid)
fi

subdirs=""
if test -d ${srcdir}/maklib -o -d ./maklib; then
	subdirs="maklib $(subdirs)"
	LDFLAGS=-L$(builddir)/maklib
else
    LDFLAGS=-L/usr/local/lib
    AC_CHECK_HEADERS(mak/maxmin.h,,[AC_ERROR(maklib is necessary)])
    AC_CHECK_LIB(mak,main,,[AC_ERROR(maklib is necessary)])
fi

AC_SUBST(SUBDIRS, $subdirs)

dnl ######################################################################
dnl    Finish...
AC_PREFIX_DEFAULT(/usr/local)
AM_CONFIG_HEADER(include/punnets/config_punnets.h)
AC_CONFIG_SUBDIRS(maklib)
AC_OUTPUT([Makefile include/Makefile include/punnets/Makefile src/Makefile punnets.doxygen])