email_config.asp

使用Asp+Access+FSO+Jmail+Servu开发

<%
Dim SendMail

Sub Jmail(email,topic,mailbody)
	on error resume next
	dim JMail
	Set JMail=Server.CreateObject("JMail.Message")
	'JMail.silent=true
	JMail.Logging=True
	JMail.Charset="gb2312"
	JMail.MailServerUserName = smtpname '您的邮件服务器登录名
	JMail.MailServerPassword = smtppass '您的邮件服务器登录密码
	JMail.ContentType = "text/html"
	JMail.Priority = 1
	JMail.From = siteemail
	JMail.FromName = site
	JMail.AddRecipient email
	JMail.Subject=topic
	JMail.Body=mailbody
	JMail.Send (smtpserver) '您的邮件服务器地址
	Set JMail=nothing
	SendMail="OK"
	If err then SendMail="False"
end sub
	
sub Cdonts(email,topic,mailbody)
	on error resume next
	dim  objCDOMail
	Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
	objCDOMail.From =mail_from
	objCDOMail.To =email
	objCDOMail.Subject =topic
	objCDOMail.BodyFormat = 0 
	objCDOMail.MailFormat = 0 
	objCDOMail.Body =mailbody
	objCDOMail.Send
	Set objCDOMail = Nothing
	SendMail="OK"
	If err then SendMail="False"
end sub

sub aspemail(email,topic,mailbody)
	on error resume next
	dim Mailer
	Set Mailer=Server.CreateObject("Persits.MailSender") 
	Mailer.Charset = "gb2312"
	Mailer.IsHTML = True
	Mailer.username = smtpname	'服务器上有效的用户名
	Mailer.password = smtppass	'服务器上有效的密码
	Mailer.Priority = 1
	Mailer.Host = smtpserver   '您的邮件服务器地址
	Mailer.Port = 25 ' 该项可选.端口25是默认值
	Mailer.From = siteemail
	Mailer.FromName = site ' 该项可选
	Mailer.AddAddress email,email
	Mailer.Subject = topic
	Mailer.Body = mailbody
	Mailer.Send
	SendMail="OK"
	If err then SendMail="False"
end sub
%>