bc50.bat

CSLIB, a C++ database library.

@echo off
::
::  This batch file compiles a Windows NT console verion
::  of the EXAMPLE program, using the Borland C++ 5.0
::  compiler.
::
::  It assumes the directory trees of both the compiler
::  and CSLIB haven't been changed from their defaults.
::


::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::: Do some drive mappings   :::::::::::::::::::::::::::::::::::::::::::
::: THIS HAS TO BE EDITED!!  :::::::::::::::::::::::::::::::::::::::::::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::


::: Make drive 'J' points to the root directory of Borland C++ :::::::::
REM  EDIT THIS LINE!
subst j: c:\usr\bc50

::: Make drive 'K' points to the root directory of CSLIB :::::::::::::::
REM  EDIT THIS LINE!
subst k: e:\cslib22


::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::: Sanity checks ::::::::::::::::::::::::::::::::::::::::::::::::::::::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::


if exist j:\bin\bcc32.exe goto check2
echo.
echo ERROR: Drive 'J' doesn't seem to point to the Borland 5.0 directory.
echo Please edit BC50.BAT.
echo.
goto done

:check2
if exist k:\lib\bc50\cscnfe.lib goto ok
echo.
echo ERROR: Drive 'K' doesn't seem to point to the CSLIB directory.
echo Please edit BC50.BAT.
echo.
goto done



::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::: Use CSDBGEN to generate DEMODB.CPP	::::::::::::::::::::::::::::::::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:OK
k:\utils\nt\csdbgen demodb.def



::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::: Compiler Options and Configuration :::::::::::::::::::::::::::::::::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::



set SOURCE1=demodb

REM Compiler options.
set COPT=-N -f -O2 -k -c

set CINC=-Ik:\include;j:\include
set LOPT=-Lj:\lib;k:\lib\bc50  -c -x
set LLIB=cscnfe.lib bidsf.lib import32.lib cw32.lib
set LOBJ=c0x32.obj


j:\bin\bcc32   %COPT% %CINC% %SOURCE1%.cpp



:: Compiling the LIST executable
set SOURCE1=list

j:\bin\bcc32   %COPT% %CINC% %SOURCE1%.cpp
j:\bin\tlink32 %LOPT% %LOBJ% demodb.obj %SOURCE1%.obj, %SOURCE1%.exe,, %LLIB%


:: Compiling the LOAD executable
set SOURCE1=load

j:\bin\bcc32   %COPT% %CINC% %SOURCE1%.cpp
j:\bin\tlink32 %LOPT% %LOBJ% demodb.obj %SOURCE1%.obj, %SOURCE1%.exe,, %LLIB%



::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::: Un-substituting the drives :::::::::::::::::::::::::::::::::::::::::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:done

subst k: /D >null
subst j: /D >null