form1.frm

draw a chart with MS Chart control

VERSION 5.00
Object = "{65E121D4-0C60-11D2-A9FC-0000F8754DA1}#2.0#0"; "MSCHRT20.OCX"
Begin VB.Form Form1 
   Caption         =   "Form1"
   ClientHeight    =   5040
   ClientLeft      =   1095
   ClientTop       =   825
   ClientWidth     =   7200
   LinkTopic       =   "Form1"
   PaletteMode     =   1  'UseZOrder
   ScaleHeight     =   5040
   ScaleWidth      =   7200
   Begin MSChart20Lib.MSChart Chart1 
      Height          =   4335
      Left            =   360
      OleObjectBlob   =   "FORM1.frx":0000
      TabIndex        =   0
      Top             =   120
      Width           =   6255
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Private Values() As Single
Private NumPoints As Integer
Private NumYs As Integer

Private Sub LoadData()
Dim fnum As Integer
Dim fname As String
Dim pt_num As Integer
Dim val_num As Integer
Dim X As Single

    ' Open the file.
    fnum = FreeFile
    fname = App.Path
    If Right$(fname, 1) <> "\" Then fname = fname & "\"
    fname = fname & "points.dat"
    Open fname For Input As #fnum

    ' Read the number of values.
    Input #fnum, NumPoints, NumYs
    ReDim Values(1 To NumPoints, 1 To 2 * NumYs)

    ' Read the data.
    For pt_num = 1 To NumPoints
        Input #fnum, X
        For val_num = 0 To NumYs - 1
            Values(pt_num, 2 * val_num + 1) = X
            Input #fnum, Values(pt_num, 2 * val_num + 2)
        Next val_num
    Next pt_num
    
    Close #fnum
End Sub
Private Sub MakeData()
Const NUM_POINTS = 40
Dim fnum As Integer
Dim fname As String
Dim i As Integer
Dim Y1 As Single
Dim Y2 As Single
Dim Y3 As Single

    ' Open the file.
    fnum = FreeFile
    fname = App.Path
    If Right$(fname, 1) <> "\" Then fname = fname & "\"
    fname = fname & "points.dat"
    Open fname For Output As #fnum

    ' Write the number of points.
    Write #fnum, NUM_POINTS
    
    ' Write the number of Y values.
    Write #fnum, 3
    
    ' Write the data.
    For i = 1 To NUM_POINTS
        Y1 = Sqr(i) * 5
        Y2 = i / 2 + 5 * Sin(i / 3)
        Y3 = i * i / 50
        Write #fnum, i * 100, Y1 * 100, Y2 * 100, Y3 * 100
    Next i
    Close #fnum
End Sub

Private Sub Form_Load()
Const MAKING_DATA = False

    If MAKING_DATA Then
        MakeData
        Unload Me
    Else
        LoadData
    
        ' Send the data to the chart.
        Chart1.ChartType = VtChChartType2dXY
        Chart1.RowCount = NumPoints
        Chart1.ColumnCount = 2 * NumYs
        Chart1.ChartData = Values
    End If
End Sub