linkcmds

RTEMS (Real-Time Executive for Multiprocessor Systems) is a free open source real-time operating sys

/*
 *  This file contains directives for the GNU linker which are specific
 *  to the Cyclone CVME960/CVME961 boards.
 *
 *  COPYRIGHT (c) 1989-1999.
 *  On-Line Applications Research Corporation (OAR).
 *
 *  The license and distribution terms for this file may be
 *  found in the file LICENSE in this distribution or at
 *  http://www.rtems.com/license/LICENSE.
 *
 *  $Id: linkcmds,v 1.12.2.1 2003/09/04 18:44:11 joel Exp $
 */

MEMORY
        {
            ram : org = 0x0, l = 1M
        }

SECTIONS
{
        .text 0x10000 :
        {
            text_start = . ;
            _text_start = . ;
            *(.text)
	. = ALIGN (16);

	/*
	 * Special FreeBSD sysctl sections.
	 */
	. = ALIGN (16);
	__start_set_sysctl_set = .;
	*(set_sysctl_*);
	__stop_set_sysctl_set = ABSOLUTE(.);
	*(set_domain_*);
	*(set_pseudo_*);

	*(.eh_fram)
        *(.gnu.linkonce.t*)

	. = ALIGN (16);

	/*
	 * C++ constructors
	 */
	__CTOR_LIST__ = .;
	LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
	*(.ctors)
	LONG(0)
	__CTOR_END__ = .;
	__DTOR_LIST__ = .;
	LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
	*(.dtors)
	LONG(0)
	__DTOR_END__ = .;

        _rodata_start = . ;
        *(.rodata*)
        *(.gnu.linkonce.r*)
        _erodata = ALIGN( 0x10 ) ;
        etext = ALIGN( 0x10 ) ;
/*            _etext = .; -- conflicts */
        }
        .data ADDR( .text ) + SIZEOF( .text ):
        {
            data_start = . ;
            _data_start = .;
            *(.data)
            edata = ALIGN( 0x10 ) ;
/*            _edata = .; -- conflicts */
        }
        .bss ADDR( .data ) + SIZEOF( .data ):
        {
            bss_start = . ;
            _bss_start = . ;
            *(.bss)
            *(COMMON)
            end = . ;
            _end = . ;
        }
}