configure.ac

RTEMS (Real-Time Executive for Multiprocessor Systems) is a free open source real-time operating sys

## Process this file with autoconf to produce a configure script.
## 
## $Id: configure.ac,v 1.6.2.3 2003/08/20 13:40:56 ralf Exp $

AC_PREREQ(2.57)
AC_INIT([rtems-c-src-lib-libbsp-m68k-mvme167],[_RTEMS_VERSION],[[e-mail]])
AC_CONFIG_SRCDIR([bsp_specs])
RTEMS_TOP(../../../../../..)

RTEMS_CANONICAL_TARGET_CPU
AM_INIT_AUTOMAKE([no-define foreign 1.7.2])
RTEMS_BSP_CONFIGURE

RTEMS_PROG_CC_FOR_TARGET([-ansi -fasm])
RTEMS_CANONICALIZE_TOOLS

RTEMS_CHECK_NETWORKING 
AM_CONDITIONAL(HAS_NETWORKING,test "$HAS_NETWORKING" = "yes")

# HACK: Propagate #define mvme167 into bspopts.h
# Used inside ../mvme162/include/mvme16x_hw.h
AC_DEFINE_UNQUOTED([mvme167],[1],
[If building the mvme167 BSP])

RTEMS_BSPOPTS_SET([CD2401_INT_LEVEL],[*],[1])
RTEMS_BSPOPTS_HELP([CD2401_INT_LEVEL],
[Interrupt level for the CD2401(when CD2401_IO_MODE == 1).])

RTEMS_BSPOPTS_SET([CD2401_IO_MODE],[*],[0])
RTEMS_BSPOPTS_HELP([CD2401_IO_MODE],
[0 for polled I/O, 1 for interrupt-driven.])

RTEMS_BSPOPTS_SET([CD2401_USE_TERMIOS],[*],[0])
RTEMS_BSPOPTS_HELP([CD2401_USE_TERMIOS],
[1 for using termios based console.])

RTEMS_BSPOPTS_SET([CONSOLE_MINOR],[*],[1])
RTEMS_BSPOPTS_HELP([CONSOLE_MINOR],
[Port to use for the RTEMS console.
      0 - /dev/tty0, Serial Port 1/Console on the MVME712M.
      1 - /dev/tty1, Serial Port 2/TTY01 on the MVME712M.
      2 - /dev/tty2, Serial Port 3 on the MVME712M.
      3 - /dev/tty3, Serial Port 4 on the MVME712M.])

RTEMS_BSPOPTS_SET([PRINTK_MINOR],[*],[1])
RTEMS_BSPOPTS_HELP([PRINTK_MINOR],
[Port to use for printk debugging output.
      0 - /dev/tty0, Serial Port 1/Console on the MVME712M.
      1 - /dev/tty1, Serial Port 2/TTY01 on the MVME712M.
      2 - /dev/tty2, Serial Port 3 on the MVME712M.
      3 - /dev/tty3, Serial Port 4 on the MVME712M.])

# Explicitly list all Makefiles here
AC_CONFIG_FILES([Makefile
clock/Makefile
console/Makefile
fatal/Makefile
include/Makefile
network/Makefile
start/Makefile
startup/Makefile
timer/Makefile
wrapup/Makefile])
AC_OUTPUT