aclocal.m4

RTEMS (Real-Time Executive for Multiprocessor Systems) is a free open source real-time operating sys

[ifelse([$1], [TRUE],  [AC_FATAL([$0: invalid condition: $1])],
        [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
AC_SUBST([$1_TRUE])
AC_SUBST([$1_FALSE])
if $2; then
  $1_TRUE=
  $1_FALSE='#'
else
  $1_TRUE='#'
  $1_FALSE=
fi
AC_CONFIG_COMMANDS_PRE(
[if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then
  AC_MSG_ERROR([conditional "$1" was never defined.
Usually this means the macro was only invoked conditionally.])
fi])])

dnl
dnl $Id: canonical-target-name.m4,v 1.1.2.2 2004/08/18 07:26:52 ralf Exp $
dnl

dnl canonicalize target cpu
dnl NOTE: Most rtems targets do not fullfil autoconf's
dnl target naming conventions "processor-vendor-os"
dnl Therefore autoconf's AC_CANONICAL_TARGET will fail for them
dnl and we have to fix it for rtems ourselves 

AC_DEFUN([RTEMS_CANONICAL_TARGET_CPU],
[
AC_CANONICAL_TARGET
AC_MSG_CHECKING(rtems target cpu)
case "${target}" in
  # hpux unix port should go here
  i[[34567]]86-*linux*)		# unix "simulator" port
	RTEMS_CPU=unix
	;;
  i[[34567]]86-*freebsd*) 	# unix "simulator" port
	RTEMS_CPU=unix
	;;
  i[[34567]]86-pc-cygwin*) 	# Cygwin is just enough unix like :)
	RTEMS_CPU=unix
	;;
  no_cpu-*rtems*)
        RTEMS_CPU=no_cpu
	;;
  sparc-sun-solaris*)           # unix "simulator" port
	RTEMS_CPU=unix
	;;
  tic4x-*rtems*)          	# gcc changed the name
	RTEMS_CPU=c4x
	;;
  *) 
	RTEMS_CPU=`echo $target | sed 's%^\([[^-]]*\)-\(.*\)$%\1%'`
	;;
esac
AC_SUBST(RTEMS_CPU)
AC_MSG_RESULT($RTEMS_CPU)
])

# Add --enable-maintainer-mode option to configure.
# From Jim Meyering

# Copyright 1996, 1998, 2000, 2001, 2002  Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.

# serial 2

AC_DEFUN([AM_MAINTAINER_MODE],
[AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  dnl maintainer-mode is disabled by default
  AC_ARG_ENABLE(maintainer-mode,
[  --enable-maintainer-mode enable make rules and dependencies not useful
                          (and sometimes confusing) to the casual installer],
      USE_MAINTAINER_MODE=$enableval,
      USE_MAINTAINER_MODE=no)
  AC_MSG_RESULT([$USE_MAINTAINER_MODE])
  AM_CONDITIONAL(MAINTAINER_MODE, [test $USE_MAINTAINER_MODE = yes])
  MAINT=$MAINTAINER_MODE_TRUE
  AC_SUBST(MAINT)dnl
]
)

AU_DEFUN([jm_MAINTAINER_MODE], [AM_MAINTAINER_MODE])

dnl $Id: env-rtemscpu.m4,v 1.5.2.6 2004/08/18 07:26:52 ralf Exp $

AC_DEFUN([RTEMS_ENV_RTEMSCPU],
[
  AC_REQUIRE([RTEMS_ENABLE_MULTILIB])

  AS_IF([test x"$multilib" = x"yes"],
  [
    AS_IF([test -n "$with_multisubdir"],
      [MULTIBUILDTOP=`echo "/$with_multisubdir" | sed 's,/[[^\\/]]*,../,g'`])
    AC_SUBST(MULTIBUILDTOP)
 
    AS_IF([test -n "$with_multisubdir"],
      [MULTISUBDIR="/$with_multisubdir"])
    AC_SUBST(MULTISUBDIR)
 
    PROJECT_INCLUDE="\$(PROJECT_ROOT)/lib/include"
    project_libdir="\$(PROJECT_ROOT)/lib\$(MULTISUBDIR)"
 
    includedir="\${exec_prefix}/lib/include"
    libdir="${libdir}\$(MULTISUBDIR)"
  ],
  [
    AC_ARG_VAR([CPU_CFLAGS],[])
    AC_ARG_VAR([CFLAGS_OPTIMIZE_V],
      [CFLAGS for building the optimized variant])
    AC_ARG_VAR([CFLAGS_DEBUG_V],
      [CFLAGS for building the debugging variant])
    AC_ARG_VAR([CFLAGS_PROFILE_V],
      [CFLAGS for building the profiled variant])
 
    AC_ARG_VAR([RTEMS_BSP],[RTEMS_BSP to build])
    AC_MSG_CHECKING([for RTEMS_BSP])
    AC_CACHE_VAL(rtems_cv_RTEMS_BSP,[
      test -n "${RTEMS_BSP}" && rtems_cv_RTEMS_BSP="$RTEMS_BSP"
    ])
    AS_IF([test -z "$rtems_cv_RTEMS_BSP"],[
      AC_MSG_ERROR([Missing RTEMS_BSP])
    ])
    RTEMS_BSP="$rtems_cv_RTEMS_BSP"
    AC_MSG_RESULT(${RTEMS_BSP})
    AC_SUBST(RTEMS_BSP)
 
    PROJECT_INCLUDE="\$(PROJECT_ROOT)/$RTEMS_BSP/lib/include"
    project_libdir="${PROJECT_ROOT}/$RTEMS_BSP/lib"   

    includedir="\${exec_prefix}/${RTEMS_BSP}/lib/include"
    libdir="\${exec_prefix}/${RTEMS_BSP}/lib"

    RTEMS_ENABLE_BARE
    AC_SUBST(BARE_CPU_MODEL)
    AC_SUBST(BARE_CPU_CFLAGS)
  ])

  AC_SUBST(project_libdir)
  AC_SUBST(PROJECT_INCLUDE)
 
  AM_CONDITIONAL([MULTILIB],[test x"$multilib" = x"yes"])
])

dnl This provides configure definitions used for multilib support

dnl parts of these macros are derived from newlib-1.8.2's multilib support

AC_DEFUN([RTEMS_ENABLE_MULTILIB],
[
AC_ARG_ENABLE(multilib,
AC_HELP_STRING([--enable-multilib],
[build many library versions (default=no)]),
[case "${enableval}" in
  yes) multilib=yes ;;
  no)  multilib=no ;;
  *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
 esac], [multilib=no])dnl

AM_CONDITIONAL(MULTILIB,test x"${multilib}" = x"yes")
])

AC_DEFUN([RTEMS_ENABLE_BARE],
[
AC_ARG_ENABLE(bare-cpu-cflags,
AC_HELP_STRING([--enable-bare-cpu-cflags],[specify a particular cpu cflag (bare bsp specific)]),
[case "${enableval}" in
  no) BARE_CPU_CFLAGS="" ;;
  *)    BARE_CPU_CFLAGS="${enableval}" ;;
esac],
[BARE_CPU_CFLAGS=""])

AC_ARG_ENABLE(bare-cpu-model,
AC_HELP_STRING([--enable-bare-cpu-model],[specify a particular cpu model (bare bsp specific)]),
[case "${enableval}" in
  no)   BARE_CPU_MODEL="" ;;
  *)    BARE_CPU_MODEL="${enableval}" ;;
esac],
[BARE_CPU_MODEL=""])
])


dnl $Id: check-cpu.m4,v 1.3.2.1 2004/08/18 07:26:52 ralf Exp $

dnl check if RTEMS support a cpu
AC_DEFUN([RTEMS_CHECK_CPU],
[dnl
AC_REQUIRE([RTEMS_TOP])
AC_REQUIRE([RTEMS_CANONICAL_TARGET_CPU])

# Is this a supported CPU?
AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
if test -d "$srcdir/$RTEMS_TOPdir/cpukit/score/cpu/$RTEMS_CPU"; then
  AC_MSG_RESULT(yes)
else
  AC_MSG_ERROR(no)
fi
])dnl


dnl $Id: canonical-host.m4,v 1.1.2.1 2004/08/18 07:26:52 ralf Exp $

AC_DEFUN([RTEMS_CANONICAL_HOST],
[dnl
AC_REQUIRE([AC_CANONICAL_HOST])
RTEMS_HOST=$host_os
case "${target}" in
  # hpux unix port should go here
  i[[34567]]86-*linux*)          # unix "simulator" port
        RTEMS_HOST=Linux
	;;
  i[[34567]]86-*freebsd*)         # unix "simulator" port
        RTEMS_HOST=FreeBSD
	;;
  i[[34567]]86-pc-cygwin*) 	# Cygwin is just enough unix like :)
        RTEMS_HOST=Cygwin
	;;
  sparc-sun-solaris*)           # unix "simulator" port
        RTEMS_HOST=Solaris
	;;
  *) 
	;;
esac
AC_SUBST(RTEMS_HOST)
])dnl

dnl
dnl $Id: prog-cc.m4,v 1.4.2.3 2004/08/18 07:26:52 ralf Exp $
dnl 
dnl Check for target gcc
dnl

AC_DEFUN([RTEMS_PROG_CC],
[
AC_BEFORE([$0], [AC_PROG_CPP])dnl
AC_BEFORE([$0], [AC_PROG_CC])dnl
AC_BEFORE([$0], [RTEMS_CANONICALIZE_TOOLS])dnl

_RTEMS_FLAGS([CFLAGS],
  ["\$(CPU_CFLAGS) \$(RTEMS_CFLAGS_\$(VARIANT_V)_V) \$(CFLAGS_\$(VARIANT_V)_V) -g"])

RTEMS_CHECK_TOOL(CC,gcc)
test -z "$CC" && \
  AC_MSG_ERROR([no acceptable cc found in \$PATH])
AC_PROG_CC
AC_PROG_CPP

AM_CONDITIONAL(RTEMS_USE_GCC,test x"$GCC" = x"yes")
])

AC_DEFUN([RTEMS_PROG_CC_FOR_TARGET],
[
dnl check target cc
RTEMS_PROG_CC
dnl check if the compiler supports -isystem
RTEMS_GCC_ISYSTEM
dnl check if the target compiler may use --pipe
RTEMS_GCC_PIPE
test "$rtems_cv_gcc_pipe" = "yes" && CC="$CC --pipe"

if test "$GCC" = yes; then
RTEMS_CFLAGS="$RTEMS_CFLAGS -Wall"
m4_if([$1],,[],[RTEMS_CFLAGS="$RTEMS_CFLAGS $1"])
fi

AS_IF([test x"$rtems_cv_gcc_isystem" = x"yes"],[
  RTEMS_CPPFLAGS="-isystem \$(PROJECT_INCLUDE)"],[
  RTEMS_CPPFLAGS="-I\$(PROJECT_INCLUDE)"
])
AC_SUBST(RTEMS_CPPFLAGS)

])

dnl
dnl $Id: canonicalize-tools.m4,v 1.3.2.1 2004/08/18 07:26:52 ralf Exp $
dnl
dnl Set target tools
dnl

AC_DEFUN([RTEMS_CANONICALIZE_TOOLS],
[AC_REQUIRE([RTEMS_PROG_CC])dnl

dnl FIXME: What shall be done if these tools are not available?
  RTEMS_CHECK_TOOL(AR,ar,no)

dnl special treatment of ranlib
  RTEMS_CHECK_TOOL(RANLIB,ranlib,:)
])

dnl $Id: check-tool.m4,v 1.1.2.1 2004/08/18 07:26:52 ralf Exp $

dnl RTEMS_CHECK_TOOL(VARIABLE, PROG-TO-CHECK-FOR[, VALUE-IF-NOT-FOUND [, PATH]])
AC_DEFUN([RTEMS_CHECK_TOOL],
[
  AS_IF([test "x$build_alias" != "x$host_alias"],
    [rtems_tool_prefix=${ac_tool_prefix}])
  AC_CHECK_PROG($1, ${rtems_tool_prefix}$2, ${rtems_tool_prefix}$2, $3, $4)
])


AC_DEFUN([_RTEMS_FLAGS],[
AS_IF([test -n "[$]{$1}"],
  [RTEMS_$1=[$]{$1}],
  [RTEMS_$1=$2])
AC_SUBST([RTEMS_$1])
])

dnl
dnl $Id: gcc-isystem.m4,v 1.1.2.2 2004/08/18 07:26:52 ralf Exp $
dnl
dnl Check whether the gcc accepts -isystem
dnl

AC_DEFUN([RTEMS_GCC_ISYSTEM],
[AC_REQUIRE([RTEMS_PROG_CC])
AC_CACHE_CHECK(whether $CC accepts -isystem,rtems_cv_gcc_isystem,
[
rtems_cv_gcc_isystem=no
if test x"$GCC" = x"yes"; then
cat << EOF > conftest.h
int conftest123();
EOF
cat << EOF > conftest.c
#include <conftest.h>
int conftest123() {}
EOF
  if test -z "`${CC} -isystem./ -c conftest.c 2>&1`";then
    rtems_cv_gcc_isystem=yes
  fi
fi
rm -f conftest*
])])

dnl
dnl $Id: gcc-pipe.m4,v 1.1.2.1 2004/08/18 07:26:52 ralf Exp $
dnl
dnl Check whether the target compiler accepts -pipe
dnl

AC_DEFUN([RTEMS_GCC_PIPE],
[AC_REQUIRE([RTEMS_PROG_CC]) 
AC_REQUIRE([AC_CANONICAL_HOST])
AC_CACHE_CHECK(whether $CC accepts --pipe,rtems_cv_gcc_pipe,
[
rtems_cv_gcc_pipe=no
if test x"$GCC" = x"yes"; then
    echo 'void f(){}' >conftest.c
    if test -z "`${CC} --pipe -c conftest.c 2>&1`";then
      rtems_cv_gcc_pipe=yes
    fi
    rm -f conftest*
fi
])
])


AC_DEFUN([RTEMS_PROG_CCAS],
[
AC_REQUIRE([RTEMS_PROG_CC])
AC_SUBST(CCAS,["$CC \$(GCCSPECS)"])
AC_SUBST(CCASFLAGS,["-DASM \$(CFLAGS) \$(INCLUDES)"])
])

dnl $Id: check-newlib.m4,v 1.2.2.1 2004/08/18 07:26:52 ralf Exp $

AC_DEFUN([RTEMS_CHECK_NEWLIB],
[dnl
AC_REQUIRE([RTEMS_PROG_CC_FOR_TARGET])dnl
AC_REQUIRE([RTEMS_CANONICALIZE_TOOLS])dnl
AC_CACHE_CHECK([for RTEMS newlib],
  rtems_cv_use_newlib,
  [
dnl some versions of newlib provide not_required_by_rtems
    AC_LINK_IFELSE(
      [AC_LANG_PROGRAM([[extern void not_required_by_rtems() ;]], 
        [[not_required_by_rtems()]])],
      [rtems_cv_use_newlib="yes"],[])

dnl some versions of newlib provide rtems_provides_crt0()
    AS_IF([test -z "$rtems_cv_use_newlib"],
      [AC_LINK_IFELSE(
         [AC_LANG_PROGRAM([[extern void rtems_provides_crt0() ;]],
           [[rtems_provides_crt0()]])],
         [rtems_cv_use_newlib="yes"],[rtems_cv_use_newlib="no"])
    ])
  ])
  RTEMS_USE_NEWLIB="$rtems_cv_use_newlib"
  AC_SUBST(RTEMS_USE_NEWLIB)

  AS_IF([test x"${RTEMS_USE_NEWLIB}" = x"yes"],
    [ AC_DEFINE_UNQUOTED(RTEMS_NEWLIB,1,[if using newlib])]
  )
])