📄 imdbsamp1b.asp

📁 《Window2000编程技术内幕》的源代码
💻 ASP
字号:
<%@ LANGUAGE = "VBScript" %>

<HTML>

<HEAD>
<TITLE><%= request.form("cboProviders")%> Statistics and Data</TITLE>
</HEAD>

<!!!Collect parameters via VBScript and retrieve data via ADO>

<%

'''Set script timeout to 10 minutes

Server.ScriptTimeout = 600

'''Declare variables

dim provider_name, dsn_name, table_name
dim sort_records, sort_field, sort_order
dim filter_records, filter_value1, filter_value2, filter_field
dim p1, p2, cn, rs, i, time1, time2

'''Set variables

provider_name = request.form("cboProviders")

p1 = instr(1, request.form("cboTableDSNs"), "TableDSN=") + len("TableDSN=")
p2 = instr(p1, request.form("cboTableDSNs"), ";")
if p2 = 0 then
	dsn_name = mid(request.form("cboTableDSNs"), p1)
else
	dsn_name = mid(request.form("cboTableDSNs"), p1, p2 - p1)
end if

p1 = instr(1, request.form("cboTableDSNs"), "Table=") + len("Table=")
p2 = instr(p1, request.form("cboTableDSNs"), ";")
if p2 = 0 then
	table_name = mid(request.form("cboTableDSNs"), p1)
else
	table_name = mid(request.form("cboTableDSNs"), p1, p2 - p1)
end if


if request.form("chksortrecords") = "on" then
	sort_records = True
else
	sort_records = False
end if

sort_order = request.form("cbosort")

if request.form("chkFilterRecords") = "on" then
	filter_records = True
else
	filter_records = False
end if

filter_value1 = request.form("txtFilter1")
filter_value2 = request.form("txtFilter2")

sort_field = 0
filter_field = 0

'''Start of ADO code

set cn = Server.CreateObject("ADODB.Connection")
set rs = Server.CreateObject("ADODB.Recordset")

time1 = now
%>
<BR>Provider: <%=provider_name%>
<BR>Connection string: <%=dsn_name%>
<%
cn.Provider = provider_name
'cn.ConnectionString = dsn_name
cn.ConnectionString = "Pubs"
cn.CursorLocation = 1  ' adUseNone
cn.Open

Set rs.ActiveConnection = cn
rs.Source = table_name

rs.Open , , 3, 3, 2	'adOpenDynamic and adLockOptimitic and adCmdTable

If sort_records Then
	rs.Sort = rs.Fields(sort_field).Name & " " & sort_order
End If

If filter_records Then
	rs.Filter = rs.Fields(filter_field).Name & " >= '" & filter_value1 & "' AND " & rs.Fields(filter_field).Name & " <= '" & filter_value2 & "'"
End If

time2 = now

%>

<!!!Display statistics and data>

<CENTER>

<TABLE BORDER>

<! Statistics >

<CAPTION ALIGN=TOP>
<%= request.form("cboTableDSNs")%>
<BR>

</CAPTION>

<! Data >

<% if request.form("chkdisplayrecords") = "on" then %>
<% for i = 0 to rs.fields.count - 1 %>
<TH> <STRONG> <%= rs.fields(i).name %> </STRONG> </TH>
<% next %>

<% do until rs.eof %>
<TR>
<% for i = 0 to rs.fields.count - 1 %>
<TD> <%= rs.fields(i).value %> </TD>
<% next %>
</TR>
<% rs.movenext %>
<% loop %>
<% end if %>

</TABLE>

</CENTER>

<%

''' Close ADO recordsets and connections
rs.close
cn.close

Set rs = Nothing
Set cn = Nothing

%>

</HTML>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -