shell_top.bat.txt

ansys55的批处理源码

/prep7
!注意：简支板的模型必须用壳单元，不能用实体建模，它是无厚度的，建成一块有厚度的板是错误的，会产生很大的偏差
!目前四个角上的节点只能通过编号选择，不过如果单元等分数发生变化，则节点号会随着变化；所以改变等分数时，程序相应部分要改变。
lengthx=1.5     ! x方向长度
lengthy=0.3     !y方向长度
lengthz=0.005
div=30          !单元等分数
nmodes=15       !分析的模态阶数
!
ET,1,SHELL63
R,1,lengthz, , , , , ,
!
DENS,1,2770         ! (Rho) density  
EX,1,71e9
NUXY,1,0.33
!
K,1,0,0,0,  
K,2,lengthx,lengthy,0,  
BLC4,0,0,lengthx,lengthy
!
LESIZE,ALL, , ,div,1,1   
CM,_Y,AREA                !以下8行皆为对面积的网格化，批处理，无需理解。
ASEL, , , ,       1 
CM,_Y1,AREA 
CHKMSH,'AREA'   
CMSEL,S,_Y    
AMESH,_Y1   
CMDEL,_Y
CMDEL,_Y1   
CMDEL,_Y2  
!
LSEL,S, , ,       2             !area 4 faces to area 6
LSEL,A, , ,       4 
NSLL,S,1
D,ALL,UX,,,,,UY,UZ,rotx,rotz    ! Constrain all displacements to zero at the walls  
!
LSEL,S, , ,       1             !area 5 faces to area 7
LSEL,A, , ,       3 
NSLL,S,1
D,ALL,UX,,,,,UY,UZ,roty,rotz    ! Constrain all displacements to zero at the walls  
!
LSEL,S, , ,       1             ! select crossecting lines and get the points of the corners 
NSLL,S,1
LSEL,S, , ,       2
LSEL,A, , ,       4 
NSLL,R,1
!DDELE,all,all,,
DDELE,all,rotx
DDELE,all,roty
!
LSEL,S, , ,       3 
NSLL,S,1
LSEL,S, , ,       2
LSEL,A, , ,       4 
NSLL,R,1
!DDELE,all,all,,
DDELE,all,rotx
DDELE,all,roty
!
nsel,all
esel,all
!
FINISH                ! begin to solve  
/SOLU   
!*  
ANTYPE,2
!*  
MODOPT,LANB,nmodes    !nmodes为赋值变量，模态阶数
EQSLV,SPAR  
MXPAND,nmodes, , ,0 
LUMPM,0 
PSTRES,0
!*  
MODOPT,LANB,nmodes,0,100000000, ,OFF, ,0
/STAT,SOLU  
SOLVE