chap8.asm

Motorola 6808嵌入式接口设计开发原程序

; Chapter 8 6808 assembly language programs
; Jonathan W. Valvano
; This software accompanies the book,
; Real Time Embedded Systems published by Brooks Cole
;
; Program 8.24. A double circular linked list used to control the stepper motor.
;MC68HC705 or MC68HC708 
;Linked list stored in EEPROM
LL:  
S10:  dc.b 10    ;Output pattern
      dc.b S9-LL ;Next if CW 
      dc.b S6-LL ;Next if CCW
S9:   dc.b 9    
      dc.b S10-LL 
      dc.b S5-LL 
S5:   dc.b 5    
      dc.b S9-LL 
      dc.b S6-LL  
S6:   dc.b 6   
      dc.b S5-LL  
      dc.b S10-LL      
;Global variables stored in RAM
POS:  ds   1   ;0<=POS<=199
PT:   ds   1   ;to current state

; Program 8.25. Helper functions used to control the stepper motor.
; MC68HC705 or MC68HC708 
goal: ds  1    ;desired position
;Reg A=desired 0<=RegA<=199
SEEK: sta goal   ;Save desired 
      sub POS    ;Go CW or CCW?
      beq DONE   ;Skip if equal
      bhi HIGH   ;Desired>POS?
;Desired<POS
      nega       ;(POS-Desired)
      cmp #100
      blo GOCCW  ;Go CCW if
;Desired<POS and POS-Desired<100
GOCW: bsr CW     ;Reg A current
      cmp goal
      bne GOCW   ;POS=Desired?
      bra DONE
HIGH: cmp #100   ;(Desired-POS)
      blo GOCW   ;Go CW if
;Desired>POS and Desired-POS<100
GOCCW: bsr CCW   ;Reg A current 
      cmp goal	
      bne GOCCW ;POS=Desired?
DONE: rts        ;Return