📄 bas200_04.pas.svn-base

📁 这是一个功能齐全的,代码完整的ERP企业信息管理系统,现在上传和大家分享
💻 SVN-BASE
字号:
unit Bas200_04;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Bas100_01, ADODB, DB, ImgList, ActnList, ComCtrls, dxtree, dxdbtree,
  ToolWin, ExtCtrls, wwDialog, Wwlocate, Wwintl, StdCtrls, Menus;

type
  TBas200_04Form = class(TBas100_01Form)
    dxDBTreeView1: TdxDBTreeView;
    Panel2: TPanel;
    DataSource1: TDataSource;
    ADOQuery1: TADOQuery;
    Panel1: TPanel;
    Image1: TImage;
    CoolBar1: TCoolBar;
    ToolBar2: TToolBar;
    tlbFirst: TToolButton;
    tlbPrior: TToolButton;
    tlbNext: TToolButton;
    tlbLast: TToolButton;
    ToolButton1: TToolButton;
    tlbInsert: TToolButton;
    tlbUpdate: TToolButton;
    tlbDelete: TToolButton;
    ToolButton2: TToolButton;
    tlbSave: TToolButton;
    tlbCancel: TToolButton;
    ToolButton3: TToolButton;
    tlbLocate: TToolButton;
    ToolButton6: TToolButton;
    tlbExit: TToolButton;
    ActionList1: TActionList;
    ActFirst: TAction;
    ActPrior: TAction;
    ActNext: TAction;
    ActLast: TAction;
    ActInsert: TAction;
    ActUpdate: TAction;
    ActDelete: TAction;
    ActSave: TAction;
    ActCancel: TAction;
    ActLocate: TAction;
    ActExit: TAction;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure ActFirstExecute(Sender: TObject);
    procedure ActPriorExecute(Sender: TObject);
    procedure ActNextExecute(Sender: TObject);
    procedure ActLastExecute(Sender: TObject);
    procedure ActInsertExecute(Sender: TObject);
    procedure ActUpdateExecute(Sender: TObject);
    procedure ActDeleteExecute(Sender: TObject);
    procedure ActSaveExecute(Sender: TObject);
    procedure ActCancelExecute(Sender: TObject);
    procedure ActExitExecute(Sender: TObject);
    procedure ActLocateExecute(Sender: TObject);
    procedure ADOQuery1AfterScroll(DataSet: TDataSet);
  private
    procedure SetButtonState(AInsUpd:Boolean);
    { Private declarations }
  public
    { Public declarations }
  protected
    ARecordCount:Integer;
    procedure SetInterface; virtual;
    procedure InsertEvent; virtual;
    procedure UpdateEvent; virtual;
    procedure DeleteEvent; virtual;
    procedure BrowseEvent; virtual;
    procedure ReportGetValue(const ParName: String; var ParValue: Variant); virtual;
  end;

var
  Bas200_04Form: TBas200_04Form;

implementation

uses CommFun, SYSDATA;

{$R *.dfm}

//设置按钮状态
procedure TBas200_04Form.SetButtonState(AInsUpd:Boolean);
begin
  ActFirst.Enabled:=not AInsUpd;
  ActPrior.Enabled:=not AInsUpd;
  ActNext.Enabled:=not AInsUpd;
  ActLast.Enabled:=not AInsUpd;
  ActInsert.Enabled:=(ARights[2]='Y') and (not AInsUpd);
  ActUpdate.Enabled:=(ARights[3]='Y') and (not AInsUpd);
  ActDelete.Enabled:=(ARights[4]='Y') and (not AInsUpd);
  ActSave.Enabled:=AInsUpd;
  ActCancel.Enabled:=AInsUpd;
  ActLocate.Enabled:=not AInsUpd;
  ActExit.Enabled:=True;

  Panel2.Visible:=AInsUpd;
  dxDBTreeView1.Enabled:=not AInsUpd;
end;

procedure TBas200_04Form.SetInterface;
begin
  inherited;
  Image1.Picture.Bitmap.LoadFromResourceName(AImgHandle,'TOPTITL');
  ActFirst.Caption:=GetDBString('COM00005001');  //最前
  ActPrior.Caption:=GetDBString('COM00005002');  //上移
  ActNext.Caption:=GetDBString('COM00005003');  //下移
  ActLast.Caption:=GetDBString('COM00005004');  //最后
  ActInsert.Caption:=GetDBString('COM00005005');  //新增
  ActUpdate.Caption:=GetDBString('COM00005006');  //修改
  ActDelete.Caption:=GetDBString('COM00005007');  //删除
  ActSave.Caption:=GetDBString('COM00005008');  //保存
  ActCancel.Caption:=GetDBString('COM00005009');  //取消
  ActLocate.Caption:=GetDBString('COM00005011');  //查找
  ActExit.Caption:=GetDBString('COM00005015');  //退出

  ActFirst.Hint:=GetDBString('COM00005001',2);  //移到第一条记录
  ActPrior.Hint:=GetDBString('COM00005002',2);  //移到上一条记录
  ActNext.Hint:=GetDBString('COM00005003',2);  //移到下一条记录
  ActLast.Hint:=GetDBString('COM00005004',2);  //移到最后一条记录
  ActInsert.Hint:=GetDBString('COM00005005',2);  //新增一条记录
  ActUpdate.Hint:=GetDBString('COM00005006',2);  //修改当前记录
  ActDelete.Hint:=GetDBString('COM00005007',2);  //删除当前记录
  ActSave.Hint:=GetDBString('COM00005008',2);  //保存编辑的记录
  ActCancel.Hint:=GetDBString('COM00005009',2);  //取消编辑的记录
  ActLocate.Hint:=GetDBString('COM00005011',2);  //快速定位记录
  ActExit.Hint:=GetDBString('COM00005015',2);  //关闭当前窗口
end;

procedure TBas200_04Form.FormCreate(Sender: TObject);
begin
  inherited;
  //设置界面信息
  SetInterface;

  try
    ADOQuery1.Open;
  except
    ShowMsg(SYSDM.ADOC.Errors[0].Description,1);
    Close;
  end;
  SetButtonState(False);
  LoadFromReg(Self); //这行一定放在打开数据集后面，否则无效
end;

procedure TBas200_04Form.FormClose(Sender: TObject;
  var Action: TCloseAction);
begin
  if ActSave.Enabled then
  begin
    if ShowDialog('UMS10000007')=IDNO then  //数据尚未保存，现在保存吗？
      ActCancel.Execute
    else
      ActSave.Execute;
  end;
  ADOQuery1.Close;
  Action:=caFree;
  inherited;
end;

procedure TBas200_04Form.ActFirstExecute(Sender: TObject);
begin
  inherited;
//最前
  if ADOQuery1.IsEmpty then Exit;
  ADOQuery1.First;
  ActFirst.Enabled:=False;
  ActPrior.Enabled:=False;
  ActNext.Enabled:=True;
  ActLast.Enabled:=True;
end;

procedure TBas200_04Form.ActPriorExecute(Sender: TObject);
begin
  inherited;
//上移
  if ADOQuery1.IsEmpty then Exit;
  ADOQuery1.Prior;
  ActNext.Enabled:=not ADOQuery1.Eof;
  ActLast.Enabled:=not ADOQuery1.Eof;
  ActFirst.Enabled:=not ADOQuery1.Bof;
  ActPrior.Enabled:=not ADOQuery1.Bof;
end;

procedure TBas200_04Form.ActNextExecute(Sender: TObject);
begin
  inherited;
//下移
  if ADOQuery1.IsEmpty then Exit;
  ADOQuery1.Next;
  ActNext.Enabled:=not ADOQuery1.Eof;
  ActLast.Enabled:=not ADOQuery1.Eof;
  ActFirst.Enabled:=not ADOQuery1.Bof;
  ActPrior.Enabled:=not ADOQuery1.Bof;
end;

procedure TBas200_04Form.ActLastExecute(Sender: TObject);
begin
  inherited;
//最后
  if ADOQuery1.IsEmpty then Exit;
  ADOQuery1.Last;
  ActNext.Enabled:=False;
  ActLast.Enabled:=False;
  ActFirst.Enabled:=True;
  ActPrior.Enabled:=True;
end;

procedure TBas200_04Form.ActInsertExecute(Sender: TObject);
begin
  inherited;
//新增
  try
    Screen.Cursor:=crHourGlass;
    ADOQuery1.Insert;
    SetButtonState(True);
    InsertEvent;
  finally
    Screen.Cursor:=crDefault;
  end;
end;

procedure TBas200_04Form.ActUpdateExecute(Sender: TObject);
begin
  inherited;
//修改
  if ADOQuery1.IsEmpty then
  begin
    ShowMsg('UMS10000002');  //表记录为空，操作无效
    Abort;
  end;
  try
    Screen.Cursor:=crHourGlass;
    ADOQuery1.Edit;
    SetButtonState(True);
    UpdateEvent;
  finally
    Screen.Cursor:=crDefault;
  end;
end;

procedure TBas200_04Form.ActDeleteExecute(Sender: TObject);
begin
  inherited;
//删除
  if ADOQuery1.IsEmpty then
  begin
    ShowMsg('UMS10000002');  //表记录为空，操作无效
    Abort;
  end;

  if dxDBTreeView1.Selected.HasChildren then
  begin
    ShowMsg('UMS10000059');  //选中的记录含有子集，不能删除
    Abort;
  end;

  if ShowDialog('UMS10000008')=IDNO then Abort;  //确定要删除此记录吗?
  try
    Screen.Cursor:=crHourGlass;
    ADOQuery1.Delete;
    DeleteEvent;
  finally
    Screen.Cursor:=crDefault;
  end;
end;

procedure TBas200_04Form.ActSaveExecute(Sender: TObject);
begin
  inherited;
//保存
  try
    Screen.Cursor:=crHourGlass;
    try
      ADOQuery1.Post;
    except
      ShowMsg(SYSDM.ADOC.Errors[0].Description,1);
      Abort;
    end;
    SetButtonState(False);
  finally
    Screen.Cursor:=crDefault;
  end;
end;

procedure TBas200_04Form.ActCancelExecute(Sender: TObject);
begin
  inherited;
//取消
  try
    Screen.Cursor:=crHourGlass;
    ADOQuery1.CancelUpdates;
    SetButtonState(False);
  finally
    Screen.Cursor:=crDefault;
  end;
end;

procedure TBas200_04Form.ActExitExecute(Sender: TObject);
begin
  inherited;
//退出
  Close;
end;

procedure TBas200_04Form.ActLocateExecute(Sender: TObject);
begin
  inherited;
//查找
  if ADOQuery1.IsEmpty then
  begin
    ShowMsg('UMS10000002');  //表记录为空，操作无效
    Abort;
  end;
  try
    Screen.Cursor:=crHourGlass;
    LocateDialog(DataSource1);
  finally
    Screen.Cursor:=crDefault;
  end;
end;

procedure TBas200_04Form.ADOQuery1AfterScroll(DataSet: TDataSet);
begin
  inherited;
  if not Active then Exit;
  if ActSave.Enabled then Exit;
  ActNext.Enabled:=not ADOQuery1.Eof;
  ActLast.Enabled:=not ADOQuery1.Eof;
  ActFirst.Enabled:=not ADOQuery1.Bof;
  ActPrior.Enabled:=not ADOQuery1.Bof;
end;

procedure TBas200_04Form.BrowseEvent;
begin
end;

procedure TBas200_04Form.DeleteEvent;
begin
end;

procedure TBas200_04Form.InsertEvent;
begin
end;

procedure TBas200_04Form.ReportGetValue(const ParName: String;
  var ParValue: Variant);
begin
  if ParName='USENM' then ParValue:=AUserName
  else if ParName='PRNDT' then ParValue:=GetDBString('COM00006006')  //列印日期
  else if ParName='PRNNM' then ParValue:=GetDBString('COM00006007')  //列印人員
  else if ParName='REPNM' then ParValue:=AReportTitle
  else if ADOQuery1.FindField(ParName)<>nil then ParValue:=ADOQuery1.FieldByName(ParName).DisplayLabel;
end;

procedure TBas200_04Form.UpdateEvent;
begin
end;

end.
💿 文件大小 5005 K
👤 上传用户 struggle10000
📂 所属分类企业管理
🏷️ 相关标签

#ERP #代码 #企业信息 #管理系统
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -