classes.cls

这是一个国内通用的学生管理系统!包括院系,学生基本信息,照片,成绩,课程等多方面的管理系统

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Classes"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'1 Class_id  Int 院系编号
'2 Class_Name  Varchar 40  院系名称
'3 Describe  Varchar 400 院系职能描述
'4 UpperId Int 上级院系编号

Public Class_Id As Long
Public Class_Name As String
Public Describe As String
Public UpperId As Long

Public Sub Init()
  Class_Id = -1
  Class_Name = ""
  Describe = ""
  UpperId = -1
End Sub

'删除
Public Sub Delete(ByVal TmpId As Long)
  DB_Connect
  
  SqlStmt = "DELETE FROM Classes WHERE Class_Id=" + Trim(Str(TmpId))
  OdbcExt (SqlStmt)
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)

  DB_Disconnect
End Sub

Public Sub GetInfo(TmpId As Long)
  Class_Id = TmpId
  
  DB_Connect
  
  SqlStmt = "SELECT * FROM Classes WHERE Class_Id=" + Trim(Str(TmpId))
  OdbcExt (SqlStmt)
  If SQLFetch(Hstmt) <> SQL_NO_DATA_FOUND Then
    '读取院系班级名称
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 2, 1, ColVal, Len(ColVal), pcblen)
    Class_Name = TrimStr(ColVal)
    '读取院系班级描述
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 3, 1, ColVal, Len(ColVal), pcblen)
    Describe = TrimStr(ColVal)
    '读取上一级院系班级的编号
    ColVal = String(40, 0)
    Rc = SQLGetData(Hstmt, 4, 1, ColVal, Len(ColVal), pcblen)
    UpperId = Val(ColVal)
  Else
    Init
  End If
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  
  DB_Disconnect
End Sub

Public Function GetName(ByVal TmpId As Long) As String
  DB_Connect
  
  SqlStmt = "SELECT Class_Name FROM Classes WHERE Class_Id=" _
          + Trim(Str(TmpId))
  OdbcExt (SqlStmt)
  If SQLFetch(Hstmt) <> SQL_NO_DATA_FOUND Then
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 1, 1, ColVal, Len(ColVal), pcblen)
    GetName = TrimStr(ColVal)
  Else
    GetName = ""
  End If
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  
  DB_Disconnect
End Function

Public Function GetNewId() As Long
  Dim TmpId As Long
  '连接数据库
  DB_Connect
  '设置要执行的SQL语句
  SqlStmt = "SELECT Class_Id FROM Classes ORDER BY Class_Id"
  '执行SQL语句
  OdbcExt (SqlStmt)
  '读取SELECT语句返回的查询结果
  i = 1
  Do While SQLFetch(Hstmt) <> SQL_NO_DATA_FOUND
    ColVal = String(40, 0)
    Rc = SQLGetData(Hstmt, 1, 1, ColVal, Len(ColVal), pcblen)
    TmpId = Val(ColVal)
    If TmpId = i Then
      i = i + 1
    Else
      GetNewId = i
      Rc = SQLFreeStmt(Hstmt, SQL_DROP)
      DB_Disconnect
      Exit Function
    End If
  Loop
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  '断开与数据库的连接
  DB_Disconnect
  '将得到的新编号作为函数的返回值
  GetNewId = i
End Function

Public Function HaveStudent(ByVal TmpClassId As Long) As Boolean
  '连接数据库
  DB_Connect
  '设置要执行的SQL语句
  SqlStmt = "SELECT * FROM Students WHERE Class_id=" + Trim(Str(TmpClassId))
  '执行SQL语句
  OdbcExt (SqlStmt)
  '如果SQLFetch()函数返回SQL_NO_DATA_FOUND，则表示没有满足条件查询结果
  If SQLFetch(Hstmt) = SQL_NO_DATA_FOUND Then
    HaveStudent = False
  Else
    HaveStudent = True
  End If
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  '断开与数据库的连接
  DB_Disconnect
End Function

Public Function HaveSon(ByVal TmpUpperId As Long) As Boolean
  DB_Connect
  
  SqlStmt = "SELECT Class_Id FROM Classes WHERE UpperId=" _
          + Trim(Str(TmpUpperId))
  OdbcExt (SqlStmt)
  If SQLFetch(Hstmt) = SQL_NO_DATA_FOUND Then
    HaveSon = False
  Else
    HaveSon = True
  End If
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  
  DB_Disconnect
End Function

Public Function In_DB(ByVal ClassName As String) As Boolean
  DB_Connect
  
  SqlStmt = "SELECT Class_Id FROM Classes WHERE Class_Name='" + Trim(ClassName) + "'"
  OdbcExt (SqlStmt)
  If SQLFetch(Hstmt) = SQL_NO_DATA_FOUND Then
    In_DB = False
  Else
    In_DB = True
  End If
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)

  DB_Disconnect
End Function

Public Function Insert() As Long
  Dim Class_Id As Long
  '生成新的编号
  Class_Id = GetNewId
  
  DB_Connect
  SqlStmt = "INSERT INTO Classes VALUES(" + Trim(Str(Class_Id)) + ",'" _
            + Trim(Class_Name) + "','" + Trim(Describe) _
            + "'," + Trim(Str(UpperId)) + ")"
  OdbcExt (SqlStmt)
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  DB_Disconnect
  Insert = Class_Id
End Function

Public Sub Load_Class_ByUpper(UpperId As Long)
  Dim i As Integer
  '初始化院系班级数组
  Erase Arr_ClassName
  Erase Arr_ClassDescribe
  Erase Arr_ClassId
  ReDim Arr_ClassName(0)
  ReDim Arr_ClassDescribe(0)
  ReDim Arr_ClassId(0)
  
  DB_Connect
  SqlStmt = "SELECT Class_Id,Class_Name,Describe FROM Classes WHERE UpperId=" _
          + Trim(Str(UpperId)) + " ORDER BY Class_Id"
  OdbcExt (SqlStmt)
  i = 0
  Do Until SQLFetch(Hstmt) = 100
    '读取院系班级编号
    ColVal = String(40, 0)
    Rc = SQLGetData(Hstmt, 1, 1, ColVal, Len(ColVal), pcblen)
    ReDim Preserve Arr_ClassId(i + 1)
    Arr_ClassId(i) = Val(ColVal)
    '读取院系班级名称
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 2, 1, ColVal, Len(ColVal), pcblen)
    ReDim Preserve Arr_ClassName(i + 1)
    Arr_ClassName(i) = TrimStr(ColVal)
    '读取院系班级描述
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 3, 1, ColVal, Len(ColVal), pcblen)
    ReDim Preserve Arr_ClassDescribe(i + 1)
    Arr_ClassDescribe(i) = Val(ColVal)
    
    i = i + 1
  Loop
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  
  DB_Disconnect
End Sub

'更新数据
Public Sub Update(ByVal TmpId As Long)
  DB_Connect
  
  SqlStmt = "UPDATE Classes SET Class_Name='" + Trim(Class_Name) _
          + "',Describe='" + Trim(Describe) _
          + "' WHERE Class_Id=" + Trim(Str(TmpId))
  OdbcExt (SqlStmt)
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  DB_Disconnect
End Sub