idigitvecmultsub.s

Arithmetic for integers of almost unlimited size for C and C++. Developed and copyrighted by Ra

! Integer Version 2.1, RD, 3.5.93, Sparc8	idigitvecmultsub.s
!		new specification
! Integer Version 2.0, RD, 12.2.93, Sparc8	idigitvecmultsub.s

#include <config.h>

	.global	DigitVecMultSub
DigitVecMultSub:
    tst %o3
    ld [%o0], %o4   		! *paccu
    ble Lvma1
    mov 0, %g1          	! carry
    ld [%o1], %o5   		! *a
    subcc %o3, 1, %o3   	! count--
    inc 4, %o1          	! a++
    ble Lvma3
    umul %o5, %o2, %g2   	! *a * m

Lvma2:
    ld  [%o1], %o5  		! *a
    inc 4, %o1      		! a++				1

    addcc   %g2, %g1, %g2       ! carry + prod(low)
    addx    %g0, %g0, %g1       ! new carry			1

    subcc   %o4, %g2, %o4     	! *res - ...
    st  %o4, [%o0]          	! *res =			1

    rd  %y, %g3                 !   				1

    addx    %g3, %g1, %g1       ! carry += prod(high)
    inc 4, %o0      		! res++                   	1

    ld  [%o0], %o4          	! *res
    subcc   %o3, 1, %o3     	! count--
    bg  Lvma2               	! loop          		1

    umul %o5, %o2, %g2      	! *a * m        		5

Lvma3:
    addcc   %g2, %g1, %g2       ! carry + prod(low)
    addx    %g0, %g0, %g1       ! new carry			1

    subcc   %o4, %g2, %o4     	! *res - ...
    st  %o4, [%o0]          	! *res =			1


    rd  %y, %g3                 !   				1
    addx    %g3, %g1, %g1       ! carry += prod(high)

Lvma1:

    retl
    mov     %g1, %o0            ! return carry