idigitvecmultadd.s

Arithmetic for integers of almost unlimited size for C and C++. Developed and copyrighted by Ra

; Thomas Pfahler, Nov 21 1997
; DigitType  DigitVecMultAdd (res, a,   m,   l  )
;                             $26, $25, $24, $23
;      DigitType *res, *a, m;
;      int l;
;{
;      res[0..l-1] += a[0..l-1]*m;
;      return CARRY;
;} 


; IMPORTANT NOTE:
; ---------------
; This file is based on the file
;       mpn/hppa/hppa1_1/addmul_1.s  from GNU MP version 2.0.2
; and has been modified by Thomas Pfahler on Nov 21 1997.
;
;
; Modifications:
;
; - function name is now DigitVecMultAdd instead of __mpn_addmul_1
; - swapped meaning of input register r23, r24 (r23 now contains the size of
;   the arrays)
; - had to catch the special case of r23 (size of arrays) being zero
;



; ----------------------------------------------------------------------
; original comment block [START]
; ----------------------------------------------------------------------

; HP-PA-1.1 __mpn_addmul_1 -- Multiply a limb vector with a limb and
; add the result to a second limb vector.

; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.

; This file is part of the GNU MP Library.

; The GNU MP Library is free software; you can redistribute it and/or modify
; it under the terms of the GNU Library General Public License as published by
; the Free Software Foundation; either version 2 of the License, or (at your
; option) any later version.

; The GNU MP Library is distributed in the hope that it will be useful, but
; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
; License for more details.

; You should have received a copy of the GNU Library General Public License
; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
; MA 02111-1307, USA.

; ----------------------------------------------------------------------
; original comment block [END]
; ----------------------------------------------------------------------


; INPUT PARAMETERS
; res_ptr	r26
; a_ptr		r25
; b		r24
; size		r23


; ----------------------------------------------------------------------
; original comment block [START]
; ----------------------------------------------------------------------

; This runs at 11 cycles/limb on a PA7000.  With the used instructions, it
; can not become faster due to data cache contention after a store.  On the
; PA7100 it runs at 10 cycles/limb, and that can not be improved either,
; since only the xmpyu does not need the integer pipeline, so the only
; dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
; on the PA7100.

; There are some ideas described in mul_1.s that applies to this code too.

; ----------------------------------------------------------------------
; original comment block [END]
; ----------------------------------------------------------------------



	.code
	.export		DigitVecMultAdd
DigitVecMultAdd
	.proc
	.callinfo	frame=64,no_calls
	.entry

	ldo		64(%r30),%r30

	comib,>=	0,%r23, L$no_limb	; (TPf, Nov 21 1997)

	fldws,ma	4(%r25),%fr5
	stw		%r24,-16(%r30)		; move s2_limb ...	(TPf)
	addib,=		-1,%r23,L$just_one_limb	;			(TPf)
	 fldws		-16(%r30),%fr4		; ... into fr4
	add		%r0,%r0,%r0		; clear carry
	xmpyu		%fr4,%fr5,%fr6
	fldws,ma	4(%r25),%fr7
	fstds		%fr6,-16(%r30)
	xmpyu		%fr4,%fr7,%fr8
	ldw		-12(%r30),%r19		; least significant limb in product
	ldw		-16(%r30),%r28

	fstds		%fr8,-16(%r30)
	addib,=		-1,%r23,L$end		; (TPf, Nov 21 1997)
	 ldw		-12(%r30),%r1

; Main loop
L$loop	ldws		0(%r26),%r29
	fldws,ma	4(%r25),%fr5
	add		%r29,%r19,%r19
	stws,ma		%r19,4(%r26)
	addc		%r28,%r1,%r19
	xmpyu		%fr4,%fr5,%fr6
	ldw		-16(%r30),%r28
	fstds		%fr6,-16(%r30)
	addc		%r0,%r28,%r28
	addib,<>	-1,%r23,L$loop		; (TPf, Nov 21 1997)
	 ldw		-12(%r30),%r1

L$end	ldw		0(%r26),%r29
	add		%r29,%r19,%r19
	stws,ma		%r19,4(%r26)
	addc		%r28,%r1,%r19
	ldw		-16(%r30),%r28
	ldws		0(%r26),%r29
	addc		%r0,%r28,%r28
	add		%r29,%r19,%r19
	stws,ma		%r19,4(%r26)
	addc		%r0,%r28,%r28
	bv		0(%r2)
	 ldo		-64(%r30),%r30

L$just_one_limb
	xmpyu		%fr4,%fr5,%fr6
	ldw		0(%r26),%r29
	fstds		%fr6,-16(%r30)
	ldw		-12(%r30),%r1
	ldw		-16(%r30),%r28
	add		%r29,%r1,%r19
	stw		%r19,0(%r26)
	addc		%r0,%r28,%r28
	bv		0(%r2)
	 ldo		-64(%r30),%r30

L$no_limb
	ldi		0,%r28			; (TPf, Nov 21 1997)
	bv		0(%r2)			; (TPf, Nov 21 1997)
	 ldo            -64(%r30),%r30		; (TPf, Nov 21 1997)

	.exit
	.procend