modorgantip.bas

VB6.0编写的医院影像系统

Attribute VB_Name = "modOrganTip"
Option Explicit

Public Function LiverTip(frmTemplet As Form) As String

    Dim strTemp As String
    
    With frmTemplet
    
        If Val(.txtL_RDiameter.Text) >= 150 Then strTemp = strTemp & "肝肿大,"
        
        Select Case .cboL_LightSpot.Text
        
            Case "细密,后方伴声衰减"
                strTemp = strTemp & "脂肪肝,"
                
            Case "稍细密,后方伴轻度声衰减"
                strTemp = strTemp & "轻度脂肪肝,"
                
'            Case "细密,略增粗增强"
'                strTemp = strTemp & "肝损害声像图,"
                
            Case Else
            
        End Select
        
        If .cboL_LightSpot.Text = "细密,略增粗增强" And .cboL_Echo.Text = "欠均匀" And Val(.txtL_PortalVein.Text) >= 15 Then
            strTemp = strTemp & "肝硬化,门静脉增宽,"
        End If
        
        Select Case .cboL_See.Text
        
            Case "液性暗区"
                strTemp = strTemp & "肝" & .cboL_Place.Text & "囊肿,"
                
            Case "多个液性暗区"
                strTemp = strTemp & "肝" & .cboL_Place.Text & "多发囊肿,"
                
            Case "中等回声光团", "低回声光团"
                strTemp = strTemp & "肝" & .cboL_Place.Text & "实质性占位,"
                
            Case "多个中等回声光团", "多个低回声光团"
                strTemp = strTemp & "肝" & .cboL_Place.Text & "多发实质性占位,"
                
            Case "中等强回声光团"
                strTemp = strTemp & "肝" & .cboL_Place.Text & "血管瘤,"
                
            Case "多个中等强回声光团"
                strTemp = strTemp & "肝" & .cboL_Place.Text & "多发血管瘤,"
            
            Case "边缘清晰整齐的无回声区,后壁及远侧回声增强"
                strTemp = strTemp & "肝囊肿、肝包虫囊肿、肝血肿,"

            Case "边缘清晰整齐的无回声区,内有实体回声或有小囊肿"
                strTemp = strTemp & "肝包虫囊肿可能,"

            Case "散在的多个大小不等无回声区"
                strTemp = strTemp & "肝多发囊肿或脓肿,"

            Case "弥漫性大小不等无回声区"
                strTemp = strTemp & "多囊肝,"
            
            Case "边缘较厚,内侧壁不平整无回声区"
                strTemp = strTemp & "肝脓肿可能,"
            
            Case "较周围回声低的大小不等圆形回声减弱区"
                strTemp = strTemp & "原发性结节型肝癌或继发性肝癌,"
            
            Case "密集高回声区,周围呈环形无回声区"
                strTemp = strTemp & "原发性肝癌或继发性肝癌,"
            
            Case "巨大片状高回声区"
                strTemp = strTemp & "原发性巨块型肝癌,"
            
            Case "散在分布的较高回声区"
                strTemp = strTemp & "弥漫性肝癌,"
            
            Case "密集回声增强区,内有不规则无回声区"
                strTemp = strTemp & "癌瘤伴坏死、液化或有出血,"
            
            Case "局限性回声增强区,边界清楚,内有管状及句点状无回声区"
                strTemp = strTemp & "血管瘤可能,"
            
            Case "局限性圆形或稍不规则形回声增强区"
                If .cboL_Place.Text = "左叶" Then strTemp = strTemp & "血管瘤可能,"
            
            Case Else
            
        End Select
        
    End With
    
    If Right$(strTemp, 1) = "," Then
        Mid$(strTemp, Len(strTemp)) = "。"
    Else
        strTemp = "肝未见异常。"
    End If
    LiverTip = strTemp
    
End Function

Public Function GallBladderTip(frmTemplet As Form) As String

    Dim strTemp As String
    
    With frmTemplet
    
        Select Case .cboGB_Plentiful.Text
        
            Case "已切除,未显示"
                strTemp = strTemp & "胆囊已切除,"
                
            Case "萎缩,显示欠佳"
                strTemp = strTemp & "胆囊萎缩,"
                
            Case Else
            
        End Select
        
        If Val(.txtGB_WallThick.Text) >= 4 And .cboGB_Wall.Text = "毛糙" Then strTemp = strTemp & "胆囊炎,"
        If .cboGB_Wall.Text = "水肿增厚,呈双层" Then strTemp = strTemp & "胆囊壁水肿增厚,"
        
        Select Case .cboGB_InWall.Text
        
            Case "见结石回声,伴声影"
                strTemp = strTemp & "胆囊结石,"
                
            Case "见多枚结石回声,伴声影"
                strTemp = strTemp & "胆囊多发结石,"
                
            Case "见米粒大小中等回声光点,无声影"
                strTemp = strTemp & "胆囊胆固醇结晶或胆固醇息肉,"
                
            Case "见多枚米粒大小中等回声光点,无声影"
                strTemp = strTemp & "胆囊多发胆固醇结晶或多发胆固醇息肉,"
                
            Case "见黄豆大小中等回声光点,无声影"
                strTemp = strTemp & "胆囊息肉或胆固醇息肉,"
                
            Case "见多枚黄豆大小中等回声光点,无声影"
                strTemp = strTemp & "胆囊多发息肉或多发胆固醇息肉,"
                
            Case "见中等回声光团,不随体位移动", "见低回声光团,不随体位移动"
                strTemp = strTemp & "胆囊实质性占位,"
                
            Case "见散在细小飘浮光点"
                strTemp = strTemp & "胆汁郁结,"
                
            Case Else
            
        End Select
        
    End With
    
    If Right$(strTemp, 1) = "," Then
        Mid$(strTemp, Len(strTemp)) = "。"
    Else
        strTemp = "胆未见异常。"
    End If

    GallBladderTip = strTemp
    
End Function

Public Function PancreasTip(frmTemplet As Form) As String

    Dim strTemp As String
    
    With frmTemplet
    
        Select Case .cboP_See.Text
        
            Case "液性暗区"
                strTemp = strTemp & "胰" & .cboP_Place.Text & "液性占位(假性囊肿可能),"
                
            Case "低回声肿块", "中等回声肿块"
                strTemp = strTemp & "胰" & .cboP_Place.Text & "实质性占位,"
                
            Case "强回声光团"
                strTemp = strTemp & "胰" & .cboP_Place.Text & "钙化或结石,"
                
            Case Else
            
        End Select
        
    End With
    
    If Right$(strTemp, 1) = "," Then
        Mid$(strTemp, Len(strTemp)) = "。"
    Else
        strTemp = "胰未见异常。"
    End If
    PancreasTip = strTemp
    
End Function

Public Function SpleenTip(frmTemplet As Form) As String
'脾
    Dim strTemp As String
    
    With frmTemplet
        
        If Val(.txtS_Width.Text) >= 50 Then strTemp = strTemp & "脾肿大,"
        
        Select Case .cboS_See.Text
        
            Case "液性暗区", "低回声肿块", "中等回声肿块"
                strTemp = strTemp & "脾囊肿,"
                
            Case "强回声光团"
                strTemp = strTemp & "脾钙化,"
                
            Case Else
            
        End Select
      
    End With
    
    If Right$(strTemp, 1) = "," Then
        Mid$(strTemp, Len(strTemp)) = "。"
    Else
        strTemp = "脾未见异常。"
    End If
    SpleenTip = strTemp
    
End Function

Public Function BackPeritoneumTip(frmTemplet As Form) As String

    Dim strTemp As String
    
    With frmTemplet
    
        Select Case .cboBP_LymphNode.Text
        
            Case "见"
                strTemp = strTemp & "后腹膜及腹主动脉旁见肿大淋巴结,"
                
            Case "未见"
                strTemp = strTemp & "后腹膜及腹主动脉旁未见肿大淋巴结,"
            
            Case Else
            
        End Select
        
    End With
    
    If Right$(strTemp, 1) = "," Then
        Mid$(strTemp, Len(strTemp)) = "。"
    Else
        strTemp = "后腹膜未见异常。"
    End If
    BackPeritoneumTip = strTemp
    
End Function

Public Function PelvicCavityTip(frmTemplet As Form) As String

    Dim strTemp As String
    
    With frmTemplet
    
        If .cboA_See(0).Text <> "" Then strTemp = "腹腔见" & .cboA_See(0).Text
        If .cboA_See(1).Text <> "" Then strTemp = "盆腔见" & .cboA_See(1).Text
        Select Case .cboA_PelvicCavity.Text
            Case "见少量积液"
                strTemp = strTemp & "腹腔盆腔少量积液,"
            Case "见中等量积液"
                strTemp = strTemp & "腹腔盆腔中等量积液,"
            Case "见大量积液"
                strTemp = strTemp & "腹腔盆腔大量积液,"
            Case Else
        End Select
        
    End With
    
    If Right$(strTemp, 1) = "," Then
        Mid$(strTemp, Len(strTemp)) = "。"
'    Else
'        strTemp = "腹腔盆腔未见异常。"
    End If
    PelvicCavityTip = strTemp
    
End Function

Public Function KidneysTip(frmTemplet As Form) As String
'双肾
    Dim strTemp As String
    Dim i As Integer
    
    With frmTemplet
        If (Val(.txtK_B_Length(0).Text) < 80 And .txtK_B_Length(0).Text <> "" Or Val(.txtK_B_Width(0).Text) < 30 And _
                .txtK_B_Width(0).Text <> "") And (Val(.txtK_B_Length(1).Text) < 80 And .txtK_B_Length(1).Text <> "" Or _
                Val(.txtK_B_Width(1).Text) < 30 And .txtK_B_Width(1).Text <> "") Then
                
            strTemp = strTemp & "双肾萎缩,"
        End If
        For i = 0 To 1
            If Val(.txtK_B_Length(i).Text) < 80 And .txtK_B_Length(i).Text <> "" Or Val(.txtK_B_Width(i).Text) < 30 And _
                .txtK_B_Width(i).Text <> "" Then
                Select Case i
                    Case 0
                        strTemp = strTemp & "右肾萎缩,"
                    Case 1
                        strTemp = strTemp & "左肾萎缩,"
                    Case Else
                End Select
            End If
        Next
        For i = 0 To 1                                                  '控件数组
            Select Case .cboK_See(i).Text
                Case "结石回声"
                    strTemp = strTemp & .cboK_Part2(i).Text & "肾" & .cboK_Place(i).Text & "结石,"
                Case "多枚结石回声"
                    strTemp = strTemp & .cboK_Part2(i).Text & "肾" & .cboK_Place(i).Text & "多发结石,"
                Case "液性暗区", "囊肿"
                    strTemp = strTemp & .cboK_Part2(i).Text & "肾" & .cboK_Place(i).Text & "囊肿,"
                Case "多个液性暗区", "多个囊肿"
                    strTemp = strTemp & .cboK_Part2(i).Text & "肾" & .cboK_Place(i).Text & "多发囊肿,"
                Case "低回声肿块", "中等回声肿块"
                    strTemp = strTemp & .cboK_Part2(i).Text & "肾" & .cboK_Place(i).Text & "实质性占位,"
                Case Else
            End Select
        Next
    End With
    
    If Right$(strTemp, 1) = "," Then
        Mid$(strTemp, Len(strTemp)) = "。"
    Else
        strTemp = "双肾未见异常。"
    End If
    KidneysTip = strTemp
    
End Function