interpre.pl

一个编译器的源程序

/* Interpreter fuer mini-PASCAL */

:- pce_autoload(finder, library(find_file)).
:- pce_global(@finder, new(finder)).
:- consult([scanner, parser]).

interpret_programm(Datei):-
  parse_programm(Datei, Parsebaum),
  retractall(speicher(_, _)),
  interpret_anweisungen(Parsebaum), !,
  listing(speicher).
  
interpret_anweisungen([Anweisung|Anweisungen]):-
  interpret_anweisung(Anweisung),
  interpret_anweisungen(Anweisungen).
interpret_anweisungen([]).  
  
interpret_anweisung(zuweisung(Variable, Ausdruck)):-
  interpret_ausdruck(Ausdruck, Wert),
  retractall(speicher(Variable, _)),
  asserta(speicher(Variable, Wert)).

interpret_anweisung(while(Ausdruck, Anweisung)):-
  interpret_ausdruck(Ausdruck, true), !,
  interpret_anweisung(Anweisung),
  interpret_anweisung(while(Ausdruck, Anweisung)).
interpret_anweisung(while(_,_)).
   
interpret_anweisung(if(Ausdruck, Anweisung1, _Anweisung2)):-
  interpret_ausdruck(Ausdruck, true), !,
  interpret_anweisung(Anweisung1).
interpret_anweisung(if(_Ausdruck, _Anweisung1, Anweisung2)):-
  interpret_anweisung(Anweisung2).   

interpret_anweisung(begin(Anweisungen)):-
  interpret_anweisungen(Anweisungen).
  
interpret_anweisung(write(Ausdruck)):-
  interpret_ausdruck(Ausdruck, Wert),
  write(Wert), nl.

interpret_anweisung(nil).  

interpret_ausdruck(Ausdruck1 < Ausdruck2, true):-
  interpret_ausdruck(Ausdruck1, Wert1),
  interpret_ausdruck(Ausdruck2, Wert2), 
  Wert1 < Wert2.
interpret_ausdruck(_Ausdruck1 < _Ausdruck2, false).
   
interpret_ausdruck(Ausdruck1 + Ausdruck2, Wert):-
  interpret_ausdruck(Ausdruck1, Wert1),
  interpret_ausdruck(Ausdruck2, Wert2), 
  Wert is Wert1 + Wert2.
  
interpret_ausdruck(Ausdruck1 - Ausdruck2, Wert):-
  interpret_ausdruck(Ausdruck1, Wert1),
  interpret_ausdruck(Ausdruck2, Wert2),
  Wert is Wert1 - Wert2.
  
interpret_ausdruck(Ausdruck1 * Ausdruck2, Wert):-
  interpret_ausdruck(Ausdruck1, Wert1),
  interpret_ausdruck(Ausdruck2, Wert2),
  Wert is Wert1 * Wert2.
   
interpret_ausdruck(Ausdruck1 / Ausdruck2, Wert):-
  interpret_ausdruck(Ausdruck1, Wert1),
  interpret_ausdruck(Ausdruck2, Wert2),
  Wert is Wert1 / Wert2.
  
interpret_ausdruck(- Ausdruck, Wert):-
  interpret_ausdruck(Ausdruck, Wert1), !,
  Wert is - Wert1.
  
interpret_ausdruck(Zahl, Zahl):-
  integer(Zahl), !.
  
interpret_ausdruck(Variable, Wert):-
  speicher(Variable, Wert), !.

interpret_ausdruck(Variable, _):-
  atom(Variable),
  write('Laufzeitfehler: Zugriff auf undefinierte Variable '),
  write(Variable), nl, fail.