bunny.bas

smallbasic for linux

4465 IF N$ <> "MIRRO" THEN PRINT "There's either no point or you don't have the object.": GOSUB 800: GOTO 109
4470 IF R <> 24 THEN PRINT "There's either no point or you don't have the object.": GOSUB 800: GOTO 109
4480 IF BRMI THEN PRINT "It's already broken!": GOSUB 800: GOTO 109
4485 BRMI = -1: PRINT "The mirror breaks into little pieces, revealing a passage to the east.": SCORE = SCORE + 8: GOSUB 300: MA(24, 2) = 25: GOTO 100
4490 IF V$ <> "GIVE" THEN 4520
4492 IF W1$ = "TO" THEN W1$ = N$: N$ = W2$
4495 IF N$ <> "BUNNY" THEN 4510
4498 IF R <> 25 THEN PRINT "I don't see a bunny--do you?": GOSUB 800: GOTO 109
4499 IF DBUN THEN PRINT "I don't see a bunny--do you?": GOSUB 800: GOTO 109
4500 N$ = W1$: GOSUB 1000: IF FL = 0 THEN PRINT "You don't have that!": GOSUB 800: GOTO 109
4502 IF OB(I) <> -1 THEN PRINT "You don't have that!": GOSUB 800: GOTO 109
4505 IF N$ <> "CARRO" THEN PRINT "The bunny refuses your offer.": GOSUB 800: GOTO 109
4507 IF NOT CASO THEN PRINT "The bunny gobbles up the carrot but is not satisfied.": OB(0) = 0: GOTO 100
4509 IF CASO THEN PRINT "The bunny gobbles the carrot up, makes a startled gasp, and dies.  The bunny    disappears into a black fog.": SCORE = SCORE + 10: GOSUB 300: DBUN = -1: GOTO 100
4510 PRINT "I'm not sure it will accept your offer.": GOSUB 800: GOTO 109
4520 IF V$ <> "SIT" THEN 4540
4530 IF N$ = "ON" THEN N$ = W1$
4532 IF N$ <> "THRON" THEN PRINT "That probably won't work.": GOSUB 800: GOTO 109
4534 IF R <> 25 THEN PRINT "That probably won't work.": GOSUB 800: GOTO 109
4535 IF STHR THEN PRINT "You sit on the throne and you get blown away by a....hold it....that was anotheradventure.  Nothing happens so you stand up again.": GOTO 100
4538 PRINT "As you sit on the throne, a passage opens to the east!  Since the throne is     uncomfortable, you stand up again.": SCORE = SCORE + 2: STHR = -1: GOSUB 300: MA(25, 2) = 100: GOTO 100
4540 IF V$ = "BURN" THEN V$ = "LIGHT": GOTO 2000
4542 IF V$ = "NORTH" THEN V$ = "N": GOTO 2000
4544 IF V$ = "SOUTH" THEN V$ = "S": GOTO 2000
4546 IF V$ = "EAST" THEN V$ = "E": GOTO 2000
4547 IF V$ = "WEST" THEN V$ = "W": GOTO 2000
4548 IF V$ = "UP" THEN V$ = "U": GOTO 2000
4549 IF V$ = "DOWN" THEN V$ = "D": GOTO 2000
4550 IF V$ <> "UNWEA" THEN 4565
4555 IF N$ <> "CROSS" THEN PRINT "That doesn't make sense!": GOSUB 800: GOTO 109
4556 IF NOT WEAC THEN PRINT "You're not wearing it!": GOSUB 800: GOTO 109
4560 PRINT "You slide the cross off your neck.": WEAC = 0: GOTO 100
4565 IF V$ = "DESTR" AND N$ = "MIRRO" THEN V$ = "BREAK": GOTO 2000
4570 IF V$ <> "DESTR" AND V$ <> "KILL" AND V$ <> "ATTAC" THEN 4590
4575 IF N$ = "SKELE" AND R = 9 THEN PRINT "The skeleton repels your attack.": GOTO 100
4580 IF N$ = "VAMPI" AND VAMP THEN PRINT "The vampire ignores your attack.": GOTO 100
4585 IF N$ = "OOZE" AND NOT DGRE AND R = 19 THEN PRINT "The ooze lets out a splatter with killing force.": GOTO 820
4588 IF N$ = "BUNNY" AND NOT DBUN AND R = 25 THEN PRINT "The bunny bites you in defense.": GOTO 820
4589 PRINT "That's not important to this adventure.": GOSUB 800: GOTO 109
4590 IF V$ = "TALK" THEN PRINT "That won't do much.": GOSUB 800: GOTO 109
4595 IF V$ <> "DRINK" AND V$ <> "SIP" THEN 4620
4600 IF N$ <> "WATER" THEN PRINT "That won't do much.": GOSUB 800: GOTO 109
4605 IF R = 3 OR R = 6 THEN 4615
4608 IF OB(2) = -1 OR OB(2) = R THEN IF BUCK THEN 4615
4610 PRINT "That won't do much.": GOSUB 800: GOTO 109
4615 PRINT "You sip the water, and feel very sick.  You lungs turn inside out, your breath  stops, and you fall on the floor, dead.": GOTO 820
4620 IF V$ = "SCORE" THEN GOSUB 25420: GOSUB 800: GOTO 108
10000 PRINT "Sorry, but I don't know that verb.  When the programmer thought of it, he was   either asleep, out of it, ticked off at the world, or out to lunch.": GOSUB 800: GOTO 109
25000 IF NR = 0 THEN RETURN
25030 FOR I = 1 TO NR
25040 FOR J = 0 TO ND - 1
25050 READ MA(I, J): NEXT: NEXT: RETURN
25100 DATA 0,4,0,0,0,0: 'ROOM 1
25110 DATA 0,0,3,0,0,0: 'ROOM 2
25120 DATA 0,200,0,2,0,0: 'ROOM 3
25130 DATA 1,8,5,0,0,201: 'ROOM 4
25140 DATA 0,8,6,4,0,0: 'ROOM 5
25150 DATA 200,9,10,5,0,0: 'ROOM 6
25160 DATA 0,11,0,0,240,0: 'ROOM 7
25170 DATA 5,0,9,4,0,0: 'ROOM 8
25180 DATA 6,0,10,8,0,314: 'ROOM 9
25190 DATA 6,0,0,9,0,0: 'ROOM 10
25200 DATA 7,0,0,0,0,0: 'ROOM 11
25210 DATA 0,0,0,0,0,0: 'ROOM 12
25220 DATA 16,12,17,17,0,0: 'ROOM 13
25230 DATA 0,0,15,0,9,0: 'ROOM 14
25240 DATA 15,19,15,14,0,0: 'ROOM 15
25250 DATA 13,22,20,21,0,0: 'ROOM 16
25260 DATA 13,20,16,16,0,0: 'ROOM 17
25270 DATA 0,0,19,17,0,0: 'ROOM 18
25280 DATA 15,0,0,203,0,0: 'ROOM 19
25290 DATA 13,17,17,16,0,0: 'ROOM 20
25300 DATA 16,23,13,20,0,0: 'ROOM 21
25310 DATA 17,21,20,16,0,0: 'ROOM 22
25320 DATA 21,26,0,0,0,0: 'ROOM 23
25330 DATA 0,0,0,23,0,0: 'ROOM 24
25340 DATA 0,0,0,24,0,0: 'ROOM 25
25350 DATA 23,27,0,0,0,0: 'ROOM 26
25360 DATA 26,0,0,0,0,0: 'ROOM 27
25400 PRINT "You go through the tunnel and end up outside the graveyard.  When you realize   where you are, you hurry along the path back into town, overcome with joy,"
25405 PRINT "shouting the news.  People rush out of their houses to greet you with a hero's  welcome."
25410 GOSUB 25420: GOTO 3440
25420 PRINT "You have scored"; SCORE; "out of 60 points."
25422 IF SCORE < 11 THEN RANK$ = "Novice Adventurer": GOTO 25490
25430 IF SCORE < 21 THEN RANK$ = "Graveyard Explorer": GOTO 25490
25440 IF SCORE < 31 THEN RANK$ = "Adventurer": GOTO 25490
25450 IF SCORE < 41 THEN RANK$ = "Monster Basher": GOTO 25490
25460 IF SCORE < 51 THEN RANK$ = "Expert Adventurer": GOTO 25490
25470 IF SCORE < 60 THEN RANK$ = "Exterminator": GOTO 25490
25480 RANK$ = "Bunny Slayer"
25490 PRINT "You have reached the rank of "; RANK$; ".": RETURN
26000 IF NO = 0 THEN RETURN
26010 FOR I = 0 TO NO - 1
26020 READ OB$(I), O2$(I), OB(I): NEXT: RETURN
26100 DATA "a carrot",CARRO,0
26110 DATA "a lamp",LAMP,2
26120 DATA "a bucket",BUCKE,11
26130 DATA "a silver cross",CROSS,0
26140 DATA "a torch",TORCH,14
26150 DATA "a key",KEY,18
26160 DATA "a scrap of paper",PAPER,8
26170 DATA "a quill pen",PEN,-1
26180 DATA "an apple",APPLE,-1
27000 CC$ = CHR$(34)
27010 PRINT "    The voice still echoes in your head.  " + CC$ + "Remember--if the bunny is not dead bymidnight, the countryside will be ruled by evil."; CC$
27020 PRINT "    You shiver as you think of the people dead in the street with bite marks on their neck.  The cattle dead by the hundreds.  The stories of a rampaging"
27030 PRINT "vampire bunny.  A chill runs up your spine."
27040 PRINT "    And lastly, you remember the strangeness of the graveyard the last time you saw it.  The misty fog surrounding it.  And now you're in the graveyard, alone,"
27050 PRINT "armed only with your apple and your trusty quill pen."
27052 FOR I = 1 TO 4
27054 LOCATE 10, 24: PRINT "The Night of the Vampire Bunnies"
27055 LOCATE 10, 24: PRINT SPACE$(40): NEXT
27056 LOCATE 10, 24: PRINT "The Night of the Vampire Bunnies"
27058 LOCATE 14, 31: PRINT "Made by Jason Dyer"
27060 LOCATE 24, 28: PRINT "Press any key to continue";
27070 I$ = INKEY$: IF I$ = "" THEN 27070
27080 CLS : RETURN
40000 LO$ = "At Coffin": PRINT LO$
40010 PRINT "You are at a coffin in a graveyard, with walls to the north, east, and west.  A": MES$ = "blue mist hangs over the graveyard.  "
40015 IF VAMP THEN PRINT MES$ + "The coffin is open with a vampire in it!": RETURN
40020 IF OCOF THEN PRINT MES$ + "The coffin is open." ELSE PRINT MES$ + "The coffin is closed."
40030 IF NOT OCOF THEN RETURN
40040 FOR I = 0 TO 8: IF OB(I) = .1 THEN PRINT "There is "; OB$(I); " in the coffin."
40050 NEXT: RETURN
40060 LO$ = "Graveyard": PRINT LO$
40070 PRINT "You are in a graveyard surrounded by walls.  There is fog here so dense you can barely see 2 meters in front of you.  A hole in the east wall allows exit from  this gloomy place.": RETURN
40080 LO$ = "Graveyard": PRINT LO$: IF NOT JRI THEN JRI = -1: SCORE = SCORE + 3: GOSUB 300
40090 PRINT "You are in a graveyard with a stream to the south.  Walls surround the other    directions, but a hole in the west wall allows passage.  It is very cool here.": RETURN
40100 LO$ = "Graveyard": PRINT LO$
40110 PRINT "You are in a dark graveyard.  A wall covered with moss is to the west, a coffin is in sight to the north, and an empty well lies in the middle of all the fog.": IF ROPE THEN PRINT "A rope leads down the damp well."
40120 RETURN
40140 LO$ = "Carrot Field": PRINT LO$
40150 PRINT "You are in a carrot field in the middle of a graveyard.  Fog is all around you. A wall is to the north, too high to climb.": RETURN
40160 LO$ = "Graveyard": PRINT LO$
40170 PRINT "You are in a foggy graveyard.  A stream is to the north, a field can be seen to the west, and all the rest only fog can be seen.  The stream looks shallow      enough to cross.": RETURN
40180 LO$ = "Bottom of Well": PRINT LO$: IF NOT WELL THEN WELL = -1: SCORE = SCORE + 5: GOSUB 300
40190 PRINT "You are at the bottom of an empty well.  The surrounding cracks are rather big, and a crevice to the south is big enough for you to go through.  A rope hangs   down allowing you to climb up.": RETURN
40200 LO$ = "Graveyard": PRINT LO$
40205 IF PLEV THEN PRINT "You are in a walled graveyard.  A black wall is to the south.  A gaping hole is in the middle of all the gravestones.": RETURN
40210 PRINT "You are in a walled graveyard.  A black wall is to the south.  Many tombstones  are in this area--so many, in fact, you have to climb over some of them.": RETURN
40220 LO$ = "At Hole": PRINT LO$
40230 PRINT "You are in a gloomy graveyard, with a wall to the south, and plenty of fog all  around you.  A large hole surrounded by gravestones leads down into gloom."
40240 IF WEAC THEN PRINT "A skeleton that was guarding the hole faces toward you, but when he sees the    cross you are wearing, recoils in terror.": RETURN
40245 PRINT "A skeleton that was guarding the hole faces towards you, and holds his stand,   not allowing you to you into the hole.": RETURN
40250 LO$ = "Graveyard": PRINT LO$
40260 PRINT "You are at the corner of a walled graveyard.  Walls connect to the south and    east, and mist hangs over the sky like a prowler.  A chill runs through your    back.": RETURN
40270 LO$ = "Crevice": PRINT LO$
40280 PRINT "You are in a large crevice in a well.  Small amounts of water trickle down the  sides.  Exit can be reached to the north.": RETURN
40290 LO$ = "Maze": PRINT "You have a nervousness about this passage, but you trudge on, and end up gettingkilled in a cave-in.": R = 13: FFF = -1: RETURN
40300 LO$ = "Maze": PRINT "You are in a dark maze.": RETURN
40310 LO$ = "Dark Tunnel": PRINT LO$
40320 PRINT "You are in a very dark tunnel.  The tunnel heads to the east, while a hole in   the ceiling allows exit from the darkness.": RETURN
40330 LO$ = "Dark Tunnel": PRINT LO$
40340 PRINT "You are in a tunnel of extreme darkness.  You can barely make out exits to all  directions except up and down.": RETURN
40350 LO$ = "Maze": PRINT "You are in a damp maze.": RETURN
40360 LO$ = "Maze": PRINT "You are in a dank maze.": RETURN
40370 LO$ = "Long Corridor": PRINT LO$
40375 IF NOT SCORELONG THEN SCORELONG = -1: SCORE = SCORE + 5: GOSUB 300
40380 PRINT "You are in a very long tunnel streaching endlessly to the east and west.  Your  feet ache as you walk down it.": RETURN
40390 LO$ = "Slimy Room": PRINT LO$
40400 PRINT "You are in a medium-size room covered with slime from ceiling to floor.  Your   feet stick to the slippery ground.": IF NOT DGRE THEN PRINT "Some grey ooze guards the westward corridor."
40405 RETURN
40410 LO$ = "Maze": PRINT "You are in a dreary maze.": RETURN
40420 LO$ = "Maze": PRINT "You are in a maze.": RETURN
40430 LO$ = "Maze": PRINT "You are in a devlish maze.": RETURN
40440 LO$ = "Torch Room": PRINT LO$
40445 PRINT "You are in a large marble room with torchholders everywhere.  However, pretty": IF BCOB THEN PRINT "much all of them are empty.  You can leave to the north, south, or east.": RETURN
40447 PRINT "much all of them are empty.  You can leave to then south and north, but the eastpassage is blocked by cobwebs.": RETURN
40450 LO$ = "Dead End": PRINT LO$
40460 IF BRMI THEN PRINT "You are in a seeminly dead end, with the only exit to the west, but a shattered mirror shows a passage to the east.": RETURN
40465 PRINT "You are in a dead end, with a large mirror covering the east wall, and an exit  to the west.": RETURN
40470 LO$ = "Bunny Room": PRINT LO$
40472 IF NOT DBUN THEN PRINT "You are in a large chamber that is sparsely furnished except for a throne boltedto the east wall.  Sitting next to the throne is a bunny which looks very much"
40475 IF NOT DBUN THEN PRINT "like the vampire bunny you are looking for.  A passage exits west from this veryunfriendly place.": RETURN
40480 IF NOT STHR THEN PRINT "You are in a large chamber that is sparsely furnished except for a throne boltedto the east wall.  A passage exits west from this barren place.": RETURN
40485 PRINT "You are in a large chamber that is sparsely furnished except for a throne boltedto the east wall.  Two passages allow exit -- one to the east, one to the west.": RETURN
40490 LO$ = "Cramped Corridor": PRINT LO$
40500 PRINT "You are in a very cramped corridor going north/south.  A lever is set into the  west wall.  The lever seems to be pretty worn from use.": RETURN
40510 LO$ = "Sandy Room": PRINT LO$
40520 IF NOT PLEV THEN PRINT "You are in a extremely sandy room with the only exit going north.  You feel a   little nervous that the ceiling will cave in on you.": RETURN
40530 PRINT "You are in a very sandy room with an exit to the north and a hole in the roof.  You feel a little nervous that the ceiling will cave in on you.": RETURN