configure.in

db.* (pronounced dee-be star) is an advanced, high performance, small footprint embedded database fo

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.57)
AC_INIT(db.star, 2.1, [e-mail])
AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_SYSTEM

AM_INIT_AUTOMAKE([foreign])
AM_MAINTAINER_MODE
AC_CONFIG_SRCDIR([include/db.star.h])
AM_CONFIG_HEADER([include/psp_config.h])
dnl AC_ARG_PROGRAM

# Checks for programs.
AC_PROG_CC
AC_PROG_LN_S
AM_PROG_LIBTOOL
AC_PROG_GCC_TRADITIONAL
AM_PROG_LEX
AC_PROG_YACC

AC_SUBST(LIBTOOL_DEPS)

AC_ARG_ENABLE(debug,
    AS_HELP_STRING([--enable-debug], [turn on debugging]),
    [case ${enableval} in
        yes) debug=true;;
        no) debug=false;;
        *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug);;
     esac],
     [debug=false])

AM_CONDITIONAL(DEBUG, test x$debug = xtrue)

AC_ARG_ENABLE(threads,
    AS_HELP_STRING([--disable-threads], [turn off thread support]),
    [case ${enableval} in
        yes) thread=true;;
        no) thread=false;;
        *) AC_MSG_ERROR(bad value ${enableval} for --enable-thread);;
     esac],
     [thread=true])

AM_CONDITIONAL(THREAD, test x$thread = xtrue)

# Checks for libraries.
if test x$thread = xtrue; then
    AC_CHECK_LIB([pthread], [pthread_create], [], [thread=false])
fi

AC_ARG_ENABLE(console,
    AS_HELP_STRING([--disable-console], [turn off console utilities support]),
    [case ${enableval} in
        yes) console=true;;
        no) console=false;;
        *) AC_MSG_ERROR(bad value ${enableval} for --enable-console);;
     esac],
     [console=true])

# Checks for header files.
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([fcntl.h limits.h mntent.h stddef.h stdlib.h])
AC_CHECK_HEADERS([string.h sys/file.h sys/time.h termio.h unistd.h])
AC_CHECK_HEADERS([values.h wchar.h wctype.h])


# Check for terminal io library
dnl TODO: build console tools only if terminal library is found
if test x$console = xtrue; then

termlibs=
AC_CHECK_HEADERS([termcap.h],[termlibs="$termlibs termcap"])
AC_CHECK_HEADERS([ncurses.h],[termlibs="$termlibs ncurses"])

console=false
for lib in $termlibs; do
    AC_CHECK_LIB([$lib],[tgoto],[AC_SUBST(TERMLIB,[-l$lib]) console=true; break])
done

fi

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
AC_STRUCT_TM

# Checks for library functions.
AC_FUNC_CLOSEDIR_VOID
AC_FUNC_FORK
AC_FUNC_GETMNTENT
dnl AC_FUNC_MALLOC/AC_FUNC_REALLOC causes to redefined malloc as
dnl rpl_malloc/rpl_realloc on uCLibc
dnl AC_FUNC_MALLOC
dnl AC_FUNC_REALLOC
AC_FUNC_MEMCMP
AC_FUNC_SELECT_ARGTYPES
AC_FUNC_SETVBUF_REVERSED
AC_TYPE_SIGNAL
AC_FUNC_STAT
AC_FUNC_VPRINTF

AC_CHECK_FUNCS([alarm clock_gettime getcwd getmntent gettimeofday])
AC_CHECK_FUNCS([memmove memset strchr strerror strrchr])

AC_CONFIG_FILES([Makefile
                 psp/Makefile
                 runtime/Makefile
                 include/Makefile
                 dbedit/Makefile
                 dal/Makefile
                 dbimp/Makefile
                 ida/Makefile
                 lm/Makefile
                 utility/Makefile
                 docs/Makefile
                 db.ecos/Makefile
                 test/Makefile
                 examples/Makefile
                 examples/bom/Makefile
                 examples/sales/Makefile
                 examples/tims/Makefile
                 db.star.spec])

AC_CONFIG_FILES([db.ecos/make-package.sh],[chmod +x db.ecos/make-package.sh])

AC_ARG_ENABLE(net,
    AS_HELP_STRING([--disable-net], [turn off network support for lock manager]),
    [case ${enableval} in
        yes) net=true;;
        no) net=false;;
        *) AC_MSG_ERROR(bad value ${enableval} for --enable-net);;
     esac],
     [net=true])

if test x$net = xtrue; then
    AC_CHECK_HEADERS([arpa/inet.h netdb.h netinet/in.h sys/socket.h],
        [],
        [net=false; break])
fi

if test x$net = xtrue; then
    AC_CHECK_FUNCS([gethostbyname gethostname inet_ntoa select socket],
        [],
        [net=false; break])
fi

if test x$net = xtrue; then
    AC_DEFINE(PSP_NET_SUPPORT,[],[Enables network protocol support])
    psp_objects="$psp_objects psptcpux.lo"
fi

AC_ARG_ENABLE(stdio,
    AS_HELP_STRING([--disable-stdio], [turn off FILE support in psp]),
    [case ${enableval} in
        yes) stdio=true;;
        no) stdio=false;;
        *) AC_MSG_ERROR(bad value ${enableval} for --enable-stdio);;
     esac],
     [stdio=true])

if test x$stdio = xtrue; then
    AC_DEFINE(PSP_STDIO_SUPPORT,[],[define to enable PSP stdio support])
fi

case "$host" in
    *ecos*) psp_objects="$psp_objects pspecos.lo" ;;
    *) psp_objects="$psp_objects psplinux.lo" ;;
esac

if test x$thread = xtrue ; then
    psp_objects="$psp_objects pspposix.lo"
    AC_DEFINE(PSP_THREAD_SUPPORT,[],[Enables thread and mutex support in PSP])
else
    psp_objects="$psp_objects pspnosync.lo"
fi

AC_SUBST([psp_objects])

if test x$console = xtrue; then
console_tools="console ida"
else
console_tools=""
fi

dnl Create tools subset
AC_ARG_ENABLE(tools,
    AS_HELP_STRING([--enable-tools=LIST], [list of utility programs to build]),
    [tools=${enableval}],
    [tools="dbedit lm dal dbimp $console_tools datdump \
dbcheck dbclrlb dbexp dchain ddlp initdb keybuild \
keydump keypack lmclear lmping prdbd"])

DBEDIT=
LM=
DDLP_TOOL=
DAL=
DBIMP=
IDA=
CONSOLE=
DATDUMP=
DBCHECK=
DBCLRLB=
DBEXP=
DCHAIN=
INITDB=
KEYBUILD=
KEYDUMP=
KEYPACK=
LMCLEAR=
LMPING=
PRDBD=

for i in $tools; do
    case $i in
    dbedit) DBEDIT=dbedit;;
    lm) LM=lm;;
    ddlp) DDLP_TOOL=ddlp;;
    dal) DAL=dal;;
    dbimp) DBIMP=dbimp;;
    ida) IDA=ida;;
    console) CONSOLE=console;;
    datdump) DATDUMP=datdump;;
    dbcheck) DBCHECK=dbcheck;;
    dbclrlb) DBCLRLB=dbclrlb;;
    dbexp) DBEXP=dbexp;;
    dchain) DCHAIN=dchain;;
    initdb) INITDB=initdb;;
    keybuild) KEYBUILD=keybuild;;
    keydump) KEYDUMP=keydump;;
    keypack) KEYPACK=keypack;;
    lmclear) LMCLEAR=lmclear;;
    lmping) LMPING=lmping;;
    prdbd) PRDBD=prdbd;;
    esac
done

AC_SUBST(DBEDIT)
AC_SUBST(LM)
AC_SUBST(DDLP_TOOL)
AC_SUBST(DAL)
AC_SUBST(DBIMP)
AC_SUBST(IDA)
AC_SUBST(CONSOLE)
AC_SUBST(DATDUMP)
AC_SUBST(DBCHECK)
AC_SUBST(DBCLRLB)
AC_SUBST(DBEXP)
AC_SUBST(DCHAIN)
AC_SUBST(INITDB)
AC_SUBST(KEYBUILD)
AC_SUBST(KEYDUMP)
AC_SUBST(KEYPACK)
AC_SUBST(LMCLEAR)
AC_SUBST(LMPING)
AC_SUBST(PRDBD)

dnl Option to build example programs
AC_ARG_ENABLE(examples,
    AS_HELP_STRING([--enable-examples=LIST], [list of examples to build]),
    [examples=${enableval}],
    [examples="bom sales tims"])

BOM=
SALES=
TIMS=

for i in $examples; do
    case $i in
    bom) BOM=bom;;
    sales) SALES=sales;;
    tims) TIMS=tims;;
    esac
done

AC_SUBST(BOM)
AC_SUBST(SALES)
AC_SUBST(TIMS)

#AC_ARG_VAR(DDLP, [Location of native ddlp utility (use when cross-compiling)])

dnl propogate package version
function subst_version()
{
    LIB_VERSION=$1
    LIB_REVISION=$2
    
    AC_SUBST(LIB_VERSION)
    AC_SUBST(LIB_REVISION)
}

subst_version ${PACKAGE_VERSION//./ }

AC_OUTPUT

echo ""
echo "db.* build configuration"
echo ""
echo "    target: $target"
echo "    host: $host"
echo "    build: $build"
echo "    package version: $PACKAGE_VERSION"
echo "    lib version: $LIB_VERSION"
echo "    lib revision: $LIB_REVISION"
echo "    build tools: $tools"
echo "    build examples: $examples"