printfun.bas

一个VB小程序,能够进行大数的计算,可以作为学习的参考

Attribute VB_Name = "PrintFun"
Attribute VB_Description = "Printfunctions outside bignumVB.dll"
'Author : Sjoerd.J.Schaper - [e-mail]
'URL    : http://largeint.sourceforge.net/index.html
'Date   : 03-16-2005
'Code   : Visual Basic for Windows 5.0
Option Explicit
Public Const dbCrLf = vbCrLf + vbCrLf
Public Data As String
Public WrkD As String
Public Key As Boolean
Public Lognr As Integer
Public tim As Double

'Numerical <-> string conversion
Function Cvl(g As String) As Long
Dim k As Integer
   k = Len(g)
   If k < 4 Then g = g + String$(4 - k, Chr$(0))
   CpMem Cvl, ByVal g, 4
End Function

Function Mkl(c As Long) As String
   Mkl = String$(4, Chr$(0))
   CpMem ByVal Mkl, c, 4
End Function

'Printfunctions
Sub Printf(ByVal f As String, ByVal g As String, _
 ByVal h As String, ByVal sw As Integer)
Dim s As String
   Select Case sw
   Case 0
      Data = f & g & h
   Case 1
      Data = Data & f & g & h
   Case 2
      Data = Data & f & g & h & vbCrLf
   Case Else
      s = "  [" & LEN(g) & "]"
      Data = Data & f & g & h & s & vbCrLf
   End Select
End Sub

Sub Printn(ByVal p As Long, ByVal f As String, _
 ByVal h As String, ByVal sw As Integer)
Dim k As Integer, g As String
   k = Decf(p)
   g = String$(k, "0")
   CnvSt g
   Printf f, g, h, sw
End Sub

Sub Printr(ByVal p As Long, ByVal q As Long, _
 ByVal r As Long, ByVal f As String, ByVal h As String)
Dim k As Integer, lx As Integer, g As String
   lx = Getl(r)
   Divd p, q, r: k = Decf(r)
   g = String$(k, "0"): CnvSt g
   If Isf(p, 0) Then
      Printf f, g, "", 0
   Else
      Printf f, g, "", 0
      g = String$(lx, "0")
      Ratdec g, p, q
      If Len(h) = 0 Then
         h = "  [" & lx & "]"
      End If
      Printf ".", g, h, 1
   End If
End Sub

Sub Prints(ByVal f As String, ByVal sw As Integer)
   Select Case sw
   Case 0
      Data = f
   Case 1
      Data = Data & f
   Case Else
      Data = Data & f & vbCrLf
   End Select
End Sub