frmuserdistributeform.frm

本人用VB 6.0和ACCESS编写的水费管理系统

VERSION 5.00
Object = "{5E9E78A0-531B-11CF-91F6-C2863C385E30}#1.0#0"; "MSFLXGRD.OCX"
Begin VB.Form frmUserDistributeForm 
   Caption         =   "用户分布表"
   ClientHeight    =   4590
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   7365
   Icon            =   "frmUserDistributeForm.frx":0000
   LinkTopic       =   "Form1"
   LockControls    =   -1  'True
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   4590
   ScaleWidth      =   7365
   StartUpPosition =   2  '屏幕中心
   Begin VB.CommandButton cmdPrint 
      Caption         =   "打印(&P)"
      Default         =   -1  'True
      Height          =   375
      Left            =   2055
      TabIndex        =   1
      Top             =   4080
      Width           =   1095
   End
   Begin VB.CommandButton cmdExit 
      Cancel          =   -1  'True
      Caption         =   "退出(&X)"
      Height          =   375
      Left            =   4215
      TabIndex        =   2
      Top             =   4080
      Width           =   1095
   End
   Begin MSFlexGridLib.MSFlexGrid MSFlexGrid1 
      Height          =   3615
      Left            =   195
      TabIndex        =   0
      Top             =   195
      Width           =   6975
      _ExtentX        =   12303
      _ExtentY        =   6376
      _Version        =   393216
      Cols            =   7
      FixedCols       =   0
   End
End
Attribute VB_Name = "frmUserDistributeForm"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Dim UserCount(RegionNumber, 6) As Long

Private Sub cmdExit_Click()
Unload Me
End Sub

Private Sub cmdPrint_Click()
    Me.PrintForm
    Printer.EndDoc
End Sub

Private Sub Form_Load()
    '给数组赋零值
    Dim i As Integer, j As Integer
    For i = 1 To RegionNumber
        For j = 1 To 6
            UserCount(i, j) = 0
        Next j
    Next i
    '读数据库并给数值赋值
    Dim strStyle As String, intStyle As Integer
    Dim db As Database, rs As Recordset
    Set db = Workspaces(0).OpenDatabase(App.Path & "\用户档案.mdb", False, True)
    Set rs = db.OpenRecordset("用户档案")
    rs.MoveFirst
    Do While Not rs.EOF
        i = rs.Fields("分区")
        strStyle = rs.Fields("户型")
        intStyle = Val(Right(strStyle, 2))
        j = intStyle
        UserCount(i, j) = UserCount(i, j) + 1
        rs.MoveNext
    Loop
    rs.Close
    db.Close
    Set rs = Nothing
    Set db = Nothing
    For i = 1 To RegionNumber
        For j = 1 To 5
            UserCount(i, 6) = UserCount(i, 6) + UserCount(i, j)
        Next j
    Next i
    MSFlexGrid1.Rows = RegionNumber + 1   '网格行数
    '定义网格各列列宽
    MSFlexGrid1.ColWidth(0) = 800: MSFlexGrid1.ColWidth(1) = 1000
    MSFlexGrid1.ColWidth(2) = 1000: MSFlexGrid1.ColWidth(3) = 1000
    MSFlexGrid1.ColWidth(4) = 1000: MSFlexGrid1.ColWidth(5) = 1000
    MSFlexGrid1.ColWidth(6) = 1000
    '在网格第一行上定义标题
    MSFlexGrid1.Row = 0
    MSFlexGrid1.Col = 0: MSFlexGrid1.Text = "分区号"
    MSFlexGrid1.Col = 1: MSFlexGrid1.Text = "居民总数"
    MSFlexGrid1.Col = 2: MSFlexGrid1.Text = "事业总数"
    MSFlexGrid1.Col = 3: MSFlexGrid1.Text = "工业总数"
    MSFlexGrid1.Col = 4: MSFlexGrid1.Text = "商业总数"
    MSFlexGrid1.Col = 5: MSFlexGrid1.Text = "特种总数"
    MSFlexGrid1.Col = 6: MSFlexGrid1.Text = "总户数"
    For i = 1 To RegionNumber
        MSFlexGrid1.Row = i: MSFlexGrid1.Col = 0
        MSFlexGrid1.RowHeight(i) = 250
        MSFlexGrid1.Text = i
        For j = 1 To 6
            MSFlexGrid1.Col = j
            MSFlexGrid1.Text = UserCount(i, j)
        Next j
    Next i
End Sub