chadoutils.pas

双色球矩阵计算程序

unit CHADOUtils;

interface
uses Windows, Messages, SysUtils, Forms, Variants, Classes, ADODB, ComObj, ActiveX;

function OpenSQL(query: TADOQuery; sql: string): Boolean;
function ExecSQL(query: TADOQuery; sql: string): Integer;

function GetTempPathFileName():string;
function CreateAccessFile(FileName:String;PassWord:string=''):boolean;
function CompactDatabase(AFileName,APassWord:string):boolean;
function ChangeDatabasePassword(AFileName,AOldPassWord,ANewPassWord:string):boolean;

function FieldCopy(queryDst, querySrc: TADOQuery): Boolean;

Const
 SConnectionString = 'Provider=Microsoft.Jet.OLEDB.4.0;Data Source=%s;'
                               +'Jet OLEDB:Database Password=%s;';

implementation

function OpenSQL(query: TADOQuery; sql: string): Boolean;
begin
  query.Close;
  query.SQL.Text := sql;
  query.Open;
  result := query.Eof;
end;

function ExecSQL(query: TADOQuery; sql: string): Integer;
begin
  query.Close;
  query.SQL.Text := sql;
  Result := query.ExecSQL;
end;

//=============================================================================
// Procedure: GetTempPathFileName
// Author   : ysai
// Date     : 2003-01-27
// Arguments: (None)
// Result   : string
//=============================================================================
function GetTempPathFileName():string;
//取得临时文件名
var
 SPath,SFile:array [0..254] of char;
begin
 GetTempPath(254,SPath);
 GetTempFileName(SPath,'~SM',0,SFile);
 result:=SFile;
 DeleteFile(PChar(result));
end;

//=============================================================================
// Procedure: CreateAccessFile
// Author   : ysai
// Date     : 2003-01-27
// Arguments: FileName:String;PassWord:string=''
// Result   : boolean
//=============================================================================
function CreateAccessFile(FileName:String;PassWord:string=''):boolean;
//建立Access文件，如果文件存在则失败
var
 STempFileName:string;
 vCatalog:OleVariant;
begin
 STempFileName:=GetTempPathFileName;
 try
   vCatalog:=CreateOleObject('ADOX.Catalog');
   vCatalog.Create(format(SConnectionString,[STempFileName,PassWord]));
   result:=CopyFile(PChar(STempFileName),PChar(FileName),True);
   DeleteFile(STempFileName);
 except
   result:=false;
 end;
end;

//=============================================================================
// Procedure: CompactDatabase
// Author   : ysai
// Date     : 2003-01-27
// Arguments: AFileName,APassWord:string
// Result   : boolean
//=============================================================================
function CompactDatabase(AFileName,APassWord:string):boolean;
//压缩与修复数据库,覆盖源文件
var
 STempFileName:string;
 vJE:OleVariant;
begin
 STempFileName:=GetTempPathFileName;
 try
   vJE:=CreateOleObject('JRO.JetEngine');
   vJE.CompactDatabase(format(SConnectionString,[AFileName,APassWord]),
       format(SConnectionString,[STempFileName,APassWord]));
   result:=CopyFile(PChar(STempFileName),PChar(AFileName),false);
   DeleteFile(STempFileName);
 except
   result:=false;
 end;
end;

//=============================================================================
// Procedure: ChangeDatabasePassword
// Author   : ysai
// Date     : 2003-01-27
// Arguments: AFileName,AOldPassWord,ANewPassWord:string
// Result   : boolean
//=============================================================================
function ChangeDatabasePassword(AFileName,AOldPassWord,ANewPassWord:string):boolean;
//修改ACCESS数据库密码
var
 STempFileName:string;
 vJE:OleVariant;
begin
 STempFileName:=GetTempPathFileName;
 try
   vJE:=CreateOleObject('JRO.JetEngine');
   vJE.CompactDatabase(format(SConnectionString,[AFileName,AOldPassWord]),
       format(SConnectionString,[STempFileName,ANewPassWord]));
   result:=CopyFile(PChar(STempFileName),PChar(AFileName),false);
   DeleteFile(STempFileName);
 except
   result:=false;
 end;
end;

function FieldCopy(queryDst, querySrc: TADOQuery): Boolean;
var
  i: Integer;
begin
  if queryDst.FieldCount <> querySrc.FieldCount then
    Result := False
  else begin
    for i:=0 to queryDst.FieldCount-1 do
      queryDst.Fields[i].Value := querySrc.Fields[i].Value;
    Result := True;
  end;
end;

end.