eval.dld

一个外国牛人做的ucos2向mcf5307的移植

/* ----------------------------------------------------------------------
 *	This describes the Eval board memory map.
 * ---------------------------------------------------------------------- */
MEMORY
{
    sdram: org=0x00000000, len=0x00800000    /* 8Mb SDRAM */
    sram:  org=0x00800000, len=0x00001000    /* 4Kb internal SRAM */
    sim:   org=0x10000000, len=0x00000400    /* 1Kb internal registers */
    cs2:   org=0xfe400000, len=0x00200000    /* 2Mb CS2 (SRAM on eval brd) */
    cs3:   org=0xfe600000, len=0x00200000    /* 2Mb CS3 (Ethernet on eval brd) */
    cs4:   org=0xfe800000, len=0x00200000    /* 2Mb CS4  */
    cs5:   org=0xfea00000, len=0x00200000    /* 2Mb CS5  */
    cs6:   org=0xfec00000, len=0x00200000    /* 2Mb CS6  */
    cs7:   org=0xfee00000, len=0x00200000    /* 2Mb CS7  */
    flash: org=0xffe00000, len=0x00100000    /* 1Mb CS0 FLASH */
}

SECTIONS
{
	GROUP 0x00020000 : {
	    .text (TEXT)   : {
		*(.text) *(.rodata) *(.init) *(.fini) *(.eini)
		. = (.+15) & ~15;
	    }
	    .sdata2 (TEXT) : {}
	    .data  (DATA) LOAD(ADDR(.sdata2)+SIZEOF(.sdata2)) : {}
	    .sdata (DATA) LOAD(ADDR(.sdata2)+SIZEOF(.sdata2)+SIZEOF(.data)) : {}
	    .sbss  (BSS) : {}
	    .bss   (BSS) : {}
	} >sdram
}

__HEAP_START	= ADDR(.bss)+SIZEOF(.bss);
__SP_INIT	= ADDR(sdram)+SIZEOF(sdram);
__HEAP_END	= ADDR(sdram)+SIZEOF(sdram)-0x1000;
__SP_END	= ADDR(sdram)+SIZEOF(sdram)-0x1000;
__DATA_ROM	= ADDR(.sdata2)+SIZEOF(.sdata2);
__DATA_RAM	= ADDR(.data);
__DATA_END	= ADDR(.sdata)+SIZEOF(.sdata);
__BSS_START	= ADDR(.sbss);
__BSS_END	= ADDR(.bss)+SIZEOF(.bss);

/*
 *  Some targets use an extra underscore in front of identifiers
 */
___HEAP_START	= __HEAP_START;
___HEAP_END	= __HEAP_END;
___SP_INIT	= __SP_INIT;
___SP_END	= __SP_END;
___DATA_ROM	= __DATA_ROM;
___DATA_RAM	= __DATA_RAM;
___DATA_END	= __DATA_END;
___BSS_START	= __BSS_START;
___BSS_END	= __BSS_END;


/*
 *  Some identifiers for locating special memory map boundaries
 */

___SDRAM_START = ADDR(sdram);
___SDRAM_END   = ADDR(sdram)+SIZEOF(sdram);
___MBAR        = ADDR(sim);