📄 ylktst.asm
字号:
;
HTHG35C:
CMP (RMPTMP),0X2F ; CMP WITH 47C
JR CC,HTHG47C
CMP (LWFNSEC),0X78 ; 2MINS
JR CC,HTHG47C
HTLWFN:
SET (FLAG4).FANON
CALL LOWFAN
JR HTFLW3
;
HTCLRFN:
TEST (P7).6 ; TEST IF CMP ON OFF
JR F,HTFLFCM
CALL FANCLR
JR HTFLW3
;
HTFLFCM:
CMP (FLFMMS),0X7D ; 1S
JR CS,HTFFLF
CLR (FLFMMS)
INC (FLFSEC)
CMP (FLFMIN),0X1D ; 29MINS
JR CC,FLFH29M
CMP (FLFSEC),0X3C ; 1MIN
JR CS,HTFFLF
CLR (FLFSEC)
INC (FLFMIN)
JR HTFFLF
;
FLFH29M:
CMP (FLFSEC),0X3A ; 58 SECONDS
JR CS,HTFFLF
SET (FLAG6).SWJWRN
JP ALTOMN
;
HTFFLF:
CMP (MMS),0X3E ; FOR FANGLENGFENG
JR GT,HTPWFLS
CLR (P0).3 ; FOR FLF FLASH
JR HTFLFCF
HTPWFLS:
SET (P0).3
HTFLFCF:
CALL FANCLR
JR HTTOALL
;
HTHG47C:
LD (LWFNSEC),0X78
CALL FRMFAN
HTFLW3:
CLR (FLFSEC) ; CLEAR SWJWRN CNT
CLR (FLFMIN)
NOP
CLR (P0).3 ; SET THE POWER LED
HTTOALL:
JP ALLMOD
;
;********************* COOL MOD ***********************************
COOLMD:
NOP
TEST (FLAG2).ISHTFLG
JR T,CLNFTH
CALL CMPCLS
CALL FANCLR2
CALL STPRST
;
CLNFTH:
CLR (FLAG2).ISHTFLG
CLR (FLAG3).GJFLG
SET (FLAG3).ISCOOL
CLR (FLAG4).ISCHSH
CLR (FLAG3).CHSFLG
CLR (FLAG6).CSSTP
CLR (FLAG3).HTFCHS
CLR (HTCMIN)
CLR (HTCMSEC)
CLR (FLAG2).CSISEND
CLR (FLAG5).HTHI62
CALL VALCLR ; CLOSE THE VALVE
TEST (FLAG3).FLDFLG
JR F,IFFLD
CMP (RMPVAL),0X3B ; CMP WITH -2C
JR GT,CLRMPH1
CLR (FLDSEC)
CLR (FLDMIN)
IFFLD:
SET (FLAG3).FLDFLG
CMP (FLDMIN),0X4 ; IF <= -2C 4MINS
JR CC,CLFLDDD
CMP (FLDSEC),0X3C ; 1 MIN
JR CS,CLNOFLD
CLR (FLDSEC)
INC (FLDMIN)
JR CLNOFLD
;
CLFLDDD:
CALL CMPCLS
CMP (RMPTMP),0X7 ; IF >= 7C
JR CC,CLRMPH1
LD (FLDMIN),0X4 ; ON THE FLD SWICTH
CLFLW2Z:
JR CLFLW2
CLRMPH1:
CLR (FLDSEC)
CLR (FLDMIN)
CLR (FLAG3).FLDFLG
CLNOFLD:
TEST (FLAG4).ISTEST ; IF TEST THEN RMTMP NO EFFECT
JR F,ATCLN5M
CALL FPRTMP
LD W,(PRSTMP)
ADD W,0X2 ; Tprset + 2C
LD A,(RMTMP)
CMP A,W
JR CS,CLFLW1
ATCLN5M:
CALL FCMPON
JR CLFLW2
;
CLFLW1:
CALL FPRTMP
LD A,(RMTMP)
CMP A,(PRSTMP)
JR CC,CLONOFF
NOP
CALL CMPCLS
JR CLFLW2
;
CLONOFF:
NOP
CLFLW2:
CALL FRMFAN
CLR (P0).3 ; SET THE POWER LED
CLTOALL:
JP ALLMOD
;
;**************** SONG FENG MOD **********************
SFMD:
TEST (FLAG2).ISHTFLG
JR T,SFNFTH
CALL CMPCLS
CALL FANCLR2
CALL STPRST
;
SFNFTH:
CLR (FLAG2).ISHTFLG
CLR (FLAG3).CHSFLG
CLR (FLAG3).ISCOOL
CLR (FLAG3).FLDFLG
CLR (FLDSEC)
CLR (FLDMIN)
CLR (FLAG3).GJFLG
CLR (FLAG4).ISCHSH
CLR (FLAG6).CSSTP
CLR (FLAG3).HTFCHS
CLR (HTCMIN)
CLR (HTCMSEC)
CLR (FLAG2).CSISEND
CLR (FLAG5).HTHI62
CALL VALCLR
CALL CMPCLS
CALL FRMFAN
CLR (P0).3 ; SET THE POWER LED
JP ALLMOD
;
CSTOCL:
JP COOLMD
;
;*********************** CHU SHI MOD ****************************
CHSHMD:
NOP
TEST (FLAG2).ISHTFLG
JR T,CSNFTH
CALL CMPCLS
CALL FANCLR2
CALL STPRST
;
CSNFTH:
TEST (FLAG4).ISTEST ; IF TEST THEN TO CHSH
JR F,CSISTST
CALL FPRTMP
LD A,(RMTMP)
CMP A,(PRSTMP)
JR GT,CSTOCL
CSISTST:
CLR (FLAG2).ISHTFLG
CLR (FLAG3).GJFLG
CLR (FLAG3).ISCOOL
CLR (FLAG3).FLDFLG
CLR (FLDSEC)
CLR (FLDMIN)
CALL VALCLR
CLR (FLAG3).HTFCHS
CLR (HTCMIN)
CLR (HTCMSEC)
CLR (FLAG2).CSISEND
CLR (FLAG5).HTHI62
TEST (FLAG4).ISCHSH
JR F,CSHVFLG
SET (FLAG4).ISCHSH
CLR (CMPSEC)
CLR (CMPMIN)
CSHVFLG:
CLR (P0).3 ; SET THE POWER LED
CMP (RMTMP),0XF ; IF RMTMP < 15C THEN
JR CS,CHSHSTP
LD (CSOFFM),6
LD (CSONM),1
CALL FRCHSH
JP ALLMOD
;
CHSHSTP:
CALL CMPCLS1
TEST (P7).6 ; TEST THE CMP
JR F,CSTPNCFN
CLR (FLAG3).CHSFLG
CALL FANCLR
CSTPNCFN:
JP ALLMOD
;
;********************************************************
FRCHSH:
TEST (FLAG3).CHSFLG
JR T,CHSH11
CALL CMPCLS
LD A,(OFFMIN)
CMP A,1
JR CC,CSFNCLR
CMP (OFFSEC),0X1E ; DELAY 30S
JR CS,CHSFLW1
CSFNCLR:
CALL FANCLR
CMP A,(CSOFFM)
JR CS,CHSFLW1
CHSH11:
CLR (FLAG3).CHSFLG
CALL FCMPON
SET (FLAG4).FANON
CALL LOWFAN
LD A,(CMPMIN)
CMP A,(CSONM)
JR CS,CHSFLW1
SET (FLAG3).CHSFLG
CHSFLW1:
RET
;
;****************** FOR TEST RUN ****************************
FTSTCMP:
SET (FLAG4).TSTRUN
CLR (P0).3 ; LIGHT THE RUN LED
CMP (TSTMIN),0X5
JR CC,TSTH5MN
LD (FANMOD),0X31 ; MAKE MOD IS COOL FAN IS HIGH SWING
CLR (FLAG2).ISHTFLG
TEST (FLAG3).ISCOOL
JR F,TSTHVCL
SET (FLAG3).ISCOOL
CALL STPRST
TSTHVCL:
CALL FCMPON
CALL VALCLR
SET (FLAG4).FANON
CALL HIGFAN
JR TSTTALL
;
TSTH5MN:
CMP (TSTMIN),0X8
JR CC,TSTH8MN
CALL CMPCLS
CALL VALCLR
CALL FANCLR
CALL TMLEDOFF
JP ALLMOD
;
TSTH8MN:
CMP (TSTMIN),0XD ; CMP 13MINS
JR CC,TSTH13M
TEST (FLAG2).ISDLFLG
JR F,TSTISDL
TEST (FLAG2).ISHTFLG
JR F,TSTHVHT
SET (FLAG2).ISHTFLG
CALL STPRST
TSTHVHT:
CLR (FLAG3).ISCOOL
CALL FCMPON
SET (FLAG4).FANON
CALL HIGFAN
JR TSTTALL
;
TSTISDL:
LD (TSTMIN),0XD ; THE DL SWITCH
TSTH13M:
CMP (TSTMIN),0X10 ;
JR CS,TSTLW16
CLR (TSTMIN)
JR TSTTALL
;
TSTLW16:
CLR (FLAG2).ISHTFLG
CALL TMLEDOFF
CALL VALCLR
CALL CMPCLS
CALL FANCLR
TSTTALL:
JP ALLMOD
;
;******************* FOR CLEAR THE FAN *********************
FANCLR:
CLR (FLAG4).FKERR ; CLEAR FKERR
CLR (IFFK)
FANCLR2:
CLR (FLAG4).FANON
LDW (WJTSBF),0XD00
CLR (FLAG6).HGFN
CLR (FLAG6).MDFN
CLR (FLAG6).LWFN
CLR (LWFNSEC)
RET
;
;******************** FOR STEP MOTOR RESET ***************
STPRST:
CLR (STPNUM)
CLR (STPNUM2)
CLR (FDRMMS)
CLR (FDRSEC)
CLR (FDRMIN)
CLR (FLAG2).STPCLS
CLR (FLAG2).RSTSTP
SET (FLAG2).STPFKJ ; IF NOT SF MOD THEN DINGWEI
RET
;****************** FOR COMPRESSOR CLOSED **************
CMPCLS1:
CMP (CMPMIN),0X1
JR CS,CCLS2
;
CMPCLS:
TEST (P7).6 ; TEST THE CMP
JR T,CCLS
CLR (P7).6 ; CLR THE CMP
SET (FLAG1).DLY3M
SET (FLAG3).VDLY
CLR (P7).5 ; CLEAR OUTFAN
CCLS:
CLR (P7).5 ; CLEAR OUTFAN
RET
;
FHTCCLS:
TEST (P7).6 ; TEST THE CMP
JR T,CCLS2
CLR (P7).6 ; CLR THE CMP
SET (FLAG1).DLY3M
SET (FLAG3).VDLY
CCLS2:
RET
;
;***************** FOR CLEAR THE VALVE ***************
VALCLR:
TEST (FLAG3).VDLY
JR F,VNTCLR
TEST (P7).6 ; TEST THE CMP
JR F,VNTCLR
CLR (P7).4
VNTCLR:
RET
;******************** FOR STEP MOTOR GJ ********************
PSTFGJ:
SET (FLAG2).RSTSTP
SET (FLAG2).STPCLS
CLR (FLAG2).STPFKJ
CLR (STPNUM)
CLR (STPNUM2)
RET
;
;******************** FOR ROOM FAN SPEED *****************
FRMFAN:
LD (WDTCR2),0X4E ; Clears the watchdog counter
SET (FLAG4).FANON
TEST (SLPDSF).7 ; TEST IF SLEEP
JR F,FANSLP
TEST (FANMOD).3 ; TEST THE F.P
JR F,HGFANZ
LD A,(FANMOD)
AND A,0XE0
CMP A,0X60
JR EQ,LWFANZ
CMP A,0X40
JR EQ,MDFANZ
CMP A,0X20
JR EQ,HGFANZ
TEST (FLAG2).ISHTFLG
JR T,FFANCL
CALL FPRTMP
LD A,(PRSTMP)
SUB A,(RMTMP)
JR CS,LWFANZ
CMP A,6
JR CC,HGFANZ
CMP A,5 ;
JR CC,HTIFMHF
CMP A,3
JR CC,MDFANZ
CMP A,2
JR CC,HTIFMLF
JP LOWFAN
;
HTIFMHF:
TEST (FLAG6).HGFN
JR F,HGFANZ
MDFANZ:
JP MIDFAN
;
HTIFMLF:
TEST (FLAG6).HGFN
JR F,MDFANZ
TEST (FLAG6).MDFN
JR F,MDFANZ
LWFANZ:
JP LOWFAN
;
HGFANZ:
JP HIGFAN
;
FANSLP:
JP LOWFAN
;
FFANCL:
TEST (FLAG4).ISCHSH
JR F,LWFANZ
CALL FPRTMP
LD A,(RMTMP)
SUB A,(PRSTMP)
JR CS,LWFANZ
CMP A,0X6
JR CC,HIGFAN
CMP A,0X5
JR CC,CLIFMHF
CMP A,0X3
JR CC,MIDFAN
CMP A,0X2
JR CS,LOWFAN
TEST (FLAG6).MDFN
JR F,MIDFAN
TEST (FLAG6).HGFN
JR F,MIDFAN
JP LOWFAN
;
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -