configure.ac

Cryptmount是对Linux系统下的文件系统以及用户设备、文档等进行加密的系统.

dnl autoconf script for cryptmount
dnl $Revision: 125 $, $Date: 2006-09-22 20:39:18 +0100 (Fri, 22 Sep 2006) $
dnl RW Penney, November 2005

dnl run 'aclocal; autoconf; automake -a -c -i; ./configure; make'

AC_INIT(cryptmount, 1.1.1, [e-mail])
AC_PREREQ(2.59)
AC_REVISION($Revision: 125 $)

SYSPATH="/sbin:/bin:/usr/sbin:/usr/bin"
etcdir="${sysconfdir}/cryptmount"
DFLT_CIPHER="aes"

AM_INIT_AUTOMAKE([no-dependencies])

AC_GNU_SOURCE
AC_PROG_CC
AC_PROG_MAKE_SET
AC_PROG_INSTALL
AC_SYS_LARGEFILE


AC_SEARCH_LIBS(dm_task_create, devmapper,
    [AC_DEFINE(HAVE_LIBDEVMAP,[1],
        [Define to 1 if you have libdevmapper header files])],
    [AC_MSG_ERROR([libdevmapper-devel package is needed to build cryptmount])])

AC_STDC_HEADERS
AC_CHECK_HEADERS([errno.h getopt.h mntent.h linux/loop.h])

AC_CHECK_FUNCS([ioctl memset mknod open strncpy syslog])

AC_C_CONST


dnl --------
dnl support OpenSSL encryption of keys
dnl
AC_ARG_WITH([openssl],
    AS_HELP_STRING([--with-openssl],
        [support OpenSSL-encryption of keys (default is YES)]),
    [openssl="$withval"], [openssl="yes"])
if test "x$openssl" = "xyes"; then
    AC_SEARCH_LIBS(OpenSSL_add_all_ciphers, ssl,
	[AC_DEFINE(HAVE_OPENSSL, [1],
            [Define to 1 if you have OpenSSL header files])],
        [AC_MSG_ERROR([cannot find OpenSSL header files])])
else
    AC_DEFINE(HAVE_OPENSSL, [0],
            [Define to 1 to enable OpenSSL support])
fi


dnl --------
dnl support libgcrypt encryption of keys
dnl
AC_ARG_WITH([libgcrypt],
    AS_HELP_STRING([--with-libgcrypt],
        [support libgcrypt-encryption of keys (default is NO)]),
    [libgcrypt="$withval"], [libgcrypt="no"])
if test "x$libgcrypt" = "xyes"; then
    AC_SEARCH_LIBS(gcry_cipher_open, gcrypt,
	[AC_DEFINE(HAVE_LIBGCRYPT, [1],
            [Define to 1 if you have libgcrypt header files])],
        [AC_MSG_ERROR([cannot find libgcrypt header files])])
else
    AC_DEFINE(HAVE_LIBGCRYPT, [0],
            [Define to 1 to enable libgcrypt support])
fi


dnl --------
dnl delegation of mount/umount functionality
dnl
AC_ARG_ENABLE([delegation],
    AS_HELP_STRING([--enable-delegation],
    	[delegate (un)mounting to /bin/(u)mount (default is YES)]),
    [delegation="$enableval"], [delegation="yes"])
if test "x$delegation" = "xyes"; then
    dfltERSATZ=0;
else
    dlftERSATZ=1;
fi

AC_CHECK_PROG([ERSATZ_MOUNT], [mount], [${dfltERSATZ}], [1], ${SYSPATH})
AC_PATH_PROG([PATH_MOUNT], [mount], [NOTHING], ${SYSPATH})
AC_CHECK_PROG([ERSATZ_UMOUNT], [umount], [${dfltERSATZ}], [1], ${SYSPATH})
AC_PATH_PROG([PATH_UMOUNT], [umount], [NOTHING], ${SYSPATH})

dnl --------
dnl crypt-swap support
dnl
AC_ARG_ENABLE([cswap],
    AS_HELP_STRING([--enable-swap],
        [enable crypto-swap support (default is YES)]),
    [cswap="$enableval"], [cswap="yes"])
if test "x$cswap" = "xyes"; then
    dfltSWAP=1;
    AC_SEARCH_LIBS(swapon, c, [],
        [AC_MSG_ERROR([swapon() system-call is needed for crypto-swap])])
else
    dfltSWAP=0;
fi
AC_CHECK_PROG([WITH_CSWAP], [mkswap], [${dfltSWAP}], [0], ${SYSPATH})
AC_PATH_PROG([PATH_MKSWAP], [mkswap], [NOTHING], ${SYSPATH})


dnl --------
dnl automatic filesystem checking
dnl
AC_ARG_ENABLE([fsck],
    AS_HELP_STRING([--enable-fsck],
    	[check filesystems before mounting (default is YES)]),
    [fsck="$enableval"], [fsck="yes"])
if test "x$fsck" = "xyes"; then
    dfltFSCK=1;
else
    dfltFSCK=0;
fi
AC_CHECK_PROG([WITH_FSCK], [fsck], [${dfltFSCK}], [0], ${SYSPATH})
AC_PATH_PROG([PATH_FSCK], [fsck], [NOTHING], ${SYSPATH})


dnl --------
dnl internationalization
dnl
AM_GNU_GETTEXT_VERSION([0.14.4])
AM_GNU_GETTEXT([external])


dnl --------
dnl argv[0] switches of default mode
dnl
AC_ARG_ENABLE([argv0switch],
    AS_HELP_STRING([--enable-argv0switch],
       [default action given by progname (default is NO)]),
    [argv0switch="$enableval"], [argv0switch="no"])
if test "x$argv0switch" = "xyes"; then
    AC_DEFINE(WITH_ARGV0, 1, [use program-name to alter default action])
fi


dnl --------
dnl substitute variables for location of configuration files etc
dnl
AC_SUBST(etcdir)
AC_SUBST(DFLT_CIPHER)

AC_CONFIG_FILES([
    Makefile
    delegates.h
    man/Makefile
    man/fr/Makefile
    po/Makefile.in
])

AC_CONFIG_HEADERS([config.h])

AC_OUTPUT


dnl --------
dnl configuration-summary messages
dnl
eval msg_conf="$etcdir"
if test "$ERSATZ_MOUNT" -ne 0; then msg_mount="(internal)"; else msg_mount="$PATH_MOUNT"; fi
if test "$ERSATZ_UMOUNT" -ne 0; then msg_umount="(internal)"; else msg_umount="$PATH_UMOUNT"; fi
if test "$WITH_FSCK" -ne 0; then msg_fsck="$PATH_FSCK"; else msg_fsck="(disabled)"; fi
AC_MSG_NOTICE([

    cryptmount-$PACKAGE_VERSION is now configured with:

	Source location:		$srcdir
	Installation prefix:		$prefix
	Configuration directory:	$msg_conf
	Filesystem mounting:		$msg_mount
	Filesystem unmounting:		$msg_umount
	Filesystem checking:		$msg_fsck
	Crypto-swap support:		$cswap
	OpenSSL support:		$openssl
	libgcrypt support:		$libgcrypt

])