_bld.bat

RTL8139 网卡驱动源码 for WinCE.net CEPC

@echo off
rem *************************************************************************
rem                              File _BLD.BAT
rem
rem                       SYDNCRead.sys build procedure
rem
rem                     Copyright (c) SYDNC, 1998-2003.
rem                           All rights reserved.
rem
rem *************************************************************************
rem 

echo ******************************************************************************
echo **********                                                          **********
echo **********                   SYDNCRead.sys Builder                  **********
echo **********                                                          **********
echo **********             Copyright (c) SYDNC, 1998-2003.              **********
echo **********                                                          **********
echo ******************************************************************************
echo:

rem 
rem ########## Do we need help? ################################################

if "%1" == "help"  goto help
if "%1" == "HELP"  goto help

if "%1" == "/help" goto help
if "%1" == "/HELP" goto help

if "%1" == "-help" goto help
if "%1" == "-HELP" goto help

if "%1" == "h"     goto help
if "%1" == "H"     goto help

if "%1" == "/h"    goto help
if "%1" == "/H"    goto help

if "%1" == "-h"    goto help
if "%1" == "-H"    goto help

if "%1" == "?"     goto help
if "%1" == "/?"    goto help
if "%1" == "-?"    goto help

goto HelpDone
:Help
rem 
rem ########## Print help screen? ##############################################

:HELP
echo:
echo    Syntax: _BLD [Option]
echo:
echo    _BLD.BAT build by default release version of FUNCDRV.SYS
echo:
echo    Option: checked - Build checked version
echo            help    - Print this help text
echo:
pause
goto End

:HelpDone


rem 
rem ********************  Check Windows 2000 DDK presence ********************

if "%CWSDK_WIN2KDDK_PATH%" == "" goto Error

rem 
rem ************************ Set MSVC environment ****************************

if "%CWSDK_MSVC32_PATH%" == "" goto SetEnv

call "%CWSDK_MSVC32_PATH%\BIN\VCVARS32.BAT"

rem 
rem ******************************* Build ************************************

:SetEnv

if exist objfre\i386\*.res del objfre\i386\*.res
if exist objchk\i386\*.res del objchk\i386\*.res

if "%OS%" == "Windows_NT" goto BuildNt
rem call %CWSDK_WIN2KDDK_PATH%\BIN\SETENV.BAT %CWSDK_WIN2KDDK_PATH% %1 >NUL
set BASEDIR=%CWSDK_WIN2KDDK_PATH%
set PATH="%CWSDK_WIN2KDDK_PATH%\BIN";%PATH%
set LIB="%CWSDK_WIN2KDDK_PATH%\LIB";%LIB%
set INCLUDE="%CWSDK_WIN2KDDK_PATH%\INC";%INCLUDE%
set NTMAKEENV=%CWSDK_WIN2KDDK_PATH%\BIN
set BUILD_MAKE_PROGRAM=nmake.exe
set BUILD_DEFAULT=-ei -nmake -i
set PROCESSOR_ARCHITECTURE=x86
set CPU=i386
set BUILD_DEFAULT_TARGETS=-386
set BUILD_ALT_DIR=fre
set NTDEBUG=ntsdnodbg
if "%1" == "CHECKED" goto BldChecked0
if "%1" == "checked" goto BldChecked0
goto BldChecked1
:BldChecked0
set BUILD_ALT_DIR=chk
set NTDEBUG=ntsd
:BldChecked1
set NTDBGFILES=1
set NTDEBUGTYPE=windbg
set NEW_CRTS=1
set SDK_INC_PATH=%CWSDK_WIN2KDDK_PATH%\inc
set DDK_INC_PATH=%CWSDK_WIN2KDDK_PATH%\inc\ddk
set WDM_INC_PATH=%CWSDK_WIN2KDDK_PATH%\inc\ddk\wdm
set CRT_INC_PATH=%CWSDK_WIN2KDDK_PATH%\inc
set OAK_INC_PATH=%CWSDK_WIN2KDDK_PATH%\inc
set SDK_LIB_DEST=%CWSDK_WIN2KDDK_PATH%\libfre
set DDK_LIB_DEST=%CWSDK_WIN2KDDK_PATH%\libfre
set SDK_LIB_PATH=%CWSDK_WIN2KDDK_PATH%\libfre\*
set DDK_LIB_PATH=%CWSDK_WIN2KDDK_PATH%\libfre\*
set CRT_LIB_PATH=%CWSDK_WIN2KDDK_PATH%\libfre\*

build -z

goto End

:BuildNt
pushd .
set OLD_MSDEVDIR=%MSDEVDIR%
set MSDEVDIR=%MSVCDIR%
call %CWSDK_WIN2KDDK_PATH%\BIN\SETENV.BAT %CWSDK_WIN2KDDK_PATH% %1 >NUL
set MSDEVDIR=%OLD_MSDEVDIR%
set OLD_MSDEVDIR=
set BUILD_ALT_DIR=fre
set NTDEBUG=ntsdnodbg
if "%1" == "CHECKED" goto BldChecked2
if "%1" == "checked" goto BldChecked2
goto BldChecked3
:BldChecked2
set BUILD_ALT_DIR=chk
set NTDEBUG=ntsd
:BldChecked3
popd

build -z

goto End

rem 
rem ****************************** Report error ******************************

:Error

echo ==============================================================
echo CWSDK_WIN2KDDK_PATH variable not defined. You should define it
echo to process building.
echo ==============================================================

:End